[gentoo-commits] gentoo-x86 commit in net-fs/openafs-kernel: metadata.xml ChangeLog openafs-kernel-1.4.12.1.ebuild

[gentoo-commits] gentoo-x86 commit in net-fs/openafs-kernel: metadata.xml ChangeLog openafs-kernel-1.4.12.1.ebuild

[Mike Frysinger (vapier)]

vapier      10/06/21 23:09:58

  Modified:             metadata.xml ChangeLog
  Added:                openafs-kernel-1.4.12.1.ebuild
  Log:
  Version bump #310627 by William Throwe.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  net-fs/openafs-kernel/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs-kernel/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs-kernel/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs-kernel/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/openafs-kernel/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	7 Oct 2005 14:14:30 -0000	1.3
+++ metadata.xml	21 Jun 2010 23:09:58 -0000	1.4
@@ -6,4 +6,8 @@
   	<email>stefaan@gentoo.org</email>
 	<name>Stefaan De Roeck</name>
 </maintainer>
+<maintainer>
+	<email>andrej.filipcic@ijs.si</email>
+	<name>Andrej Filipcic</name>
+</maintainer>
 </pkgmetadata>



1.122                net-fs/openafs-kernel/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs-kernel/ChangeLog?rev=1.122&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs-kernel/ChangeLog?rev=1.122&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs-kernel/ChangeLog?r1=1.121&r2=1.122

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/openafs-kernel/ChangeLog,v
retrieving revision 1.121
retrieving revision 1.122
diff -u -r1.121 -r1.122
--- ChangeLog	6 Feb 2010 10:51:10 -0000	1.121
+++ ChangeLog	21 Jun 2010 23:09:58 -0000	1.122
@@ -1,6 +1,12 @@
 # ChangeLog for net-fs/openafs-kernel
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs-kernel/ChangeLog,v 1.121 2010/02/06 10:51:10 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs-kernel/ChangeLog,v 1.122 2010/06/21 23:09:58 vapier Exp $
+
+*openafs-kernel-1.4.12.1 (21 Jun 2010)
+
+  21 Jun 2010; Mike Frysinger <vapier@gentoo.org>
+  +openafs-kernel-1.4.12.1.ebuild, metadata.xml:
+  Version bump #310627 by William Throwe.
 
   06 Feb 2010; Ulrich Mueller <ulm@gentoo.org> openafs-kernel-1.4.6.ebuild,
   openafs-kernel-1.4.6_p20080222.ebuild, openafs-kernel-1.4.7.ebuild,



1.1                  net-fs/openafs-kernel/openafs-kernel-1.4.12.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs-kernel/openafs-kernel-1.4.12.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/openafs-kernel/openafs-kernel-1.4.12.1.ebuild?rev=1.1&content-type=text/plain

Index: openafs-kernel-1.4.12.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs-kernel/openafs-kernel-1.4.12.1.ebuild,v 1.1 2010/06/21 23:09:58 vapier Exp $

EAPI="2"

inherit eutils autotools linux-mod versionator toolchain-funcs

PATCHVER=0.16
MY_PN=${PN/-kernel}
MY_P=${MY_PN}-${PV}
MY_PV=$(get_version_component_range 1-3)
PVER="1"
DESCRIPTION="The OpenAFS distributed file system kernel module"
HOMEPAGE="http://www.openafs.org/"
SRC_URI="http://openafs.org/dl/${MY_PV}/${MY_P}-src.tar.bz2
	mirror://gentoo/${MY_P}-patches-${PVER}.tar.bz2"

LICENSE="IBM BSD openafs-krb5-a APSL-2 sun-rpc"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE=""

S=${WORKDIR}/${MY_P}

CONFIG_CHECK="!DEBUG_RODATA ~!AFS_FS"
ERROR_DEBUG_RODATA="OpenAFS is incompatible with linux' CONFIG_DEBUG_RODATA option"
ERROR_AFS_FS="OpenAFS conflicts with the in-kernel AFS-support.  Make sure not to load both at the same time!"

pkg_setup() {
	linux-mod_pkg_setup
}

src_prepare() {
	EPATCH_EXCLUDE="012_all_kbuild.patch" \
	EPATCH_SUFFIX="patch" \
	epatch "${WORKDIR}"/gentoo/patches

	# packaging is f-ed up, so we can't run automake (i.e. eautoreconf)
	sed -i '/^a/s:^:e:' regen.sh
	skipman=1
	. regen.sh
}

src_configure() {
	ARCH="$(tc-arch-kernel)" \
	econf \
		--with-linux-kernel-headers=${KV_DIR} \
		--with-linux-kernel-build=${KV_OUT_DIR}
}

src_compile() {
	ARCH="$(tc-arch-kernel)" emake -j1 only_libafs || die
}

src_install() {
	MOD_SRCDIR=$(expr "${S}"/src/libafs/MODLOAD-*)
	[ -f "${MOD_SRCDIR}"/libafs.${KV_OBJ} ] || die "Couldn't find compiled kernel module"

	MODULE_NAMES='libafs(fs/openafs:$MOD_SRCDIR)'

	linux-mod_src_install
}