[gentoo-commits] gentoo-x86 commit in sys-cluster/cluster-glue: cluster-glue-1.0.5.ebuild ChangeLog metadata.xml

[gentoo-commits] gentoo-x86 commit in sys-cluster/cluster-glue: cluster-glue-1.0.5.ebuild ChangeLog metadata.xml

[Kacper Kowalik (xarthisius)]

xarthisius    10/06/20 21:29:19

  Added:                cluster-glue-1.0.5.ebuild ChangeLog metadata.xml
  Log:
  Initial import. Ebuild written by Tomáš Chvátal <scarabeus@gentoo.org>
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  sys-cluster/cluster-glue/cluster-glue-1.0.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/cluster-glue-1.0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/cluster-glue-1.0.5.ebuild?rev=1.1&content-type=text/plain

Index: cluster-glue-1.0.5.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/cluster-glue/cluster-glue-1.0.5.ebuild,v 1.1 2010/06/20 21:29:18 xarthisius Exp $

EAPI="2"

MY_P="${P/cluster-}"
inherit autotools multilib eutils base

DESCRIPTION="Library pack for Heartbeat / Pacemaker"
HOMEPAGE="http://www.linux-ha.org/wiki/Cluster_Glue"
SRC_URI="http://hg.linux-ha.org/glue/archive/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

RDEPEND="app-arch/bzip2
	net-libs/libnet:1.1
	net-misc/curl
	net-misc/iputils
	|| ( net-misc/netkit-telnetd net-misc/telnet-bsd )
	dev-libs/libxml2"
DEPEND="${RDEPEND}
	doc? (
		dev-libs/libxslt
		app-text/docbook-xsl-stylesheets
		)"

S="${WORKDIR}/Reusable-Cluster-Components-${MY_P}"

PATCHES=(
	"${FILESDIR}/${PV}-docs.patch"
	"${FILESDIR}/${PV}-respect_cflags.patch"
)

src_prepare() {
	base_src_prepare
	eautoreconf
}

src_configure() {
	local myopts

	use doc && myopts=" --enable-doc"
	econf \
		--disable-static \
		--disable-fatal-warnings \
		--disable-dependency-tracking \
		--docdir=/usr/share/doc/${PF} \
		--enable-libnet \
		--localstatedir=/var \
		--sysconfdir=/var \
		${myopts} \
		--with-group-id=65 --with-ccmuser-id=65 \
		--with-daemon-user=hacluster --with-daemon-group=haclient
}

src_install() {
	base_src_install

	dodir /var/lib/heartbeat/cores
	dodir /var/lib/heartbeat/lrm

	keepdir /var/lib/heartbeat/cores
	keepdir /var/lib/heartbeat/lrm

	# init.d file
	cp "${FILESDIR}"/heartbeat-logd.init "${T}/" || die
	sed -i \
		-e "s:%libdir%:$(get_libdir):" \
		"${T}/heartbeat-logd.init" || die
	newinitd "${T}/heartbeat-logd.init" heartbeat-logd || die
	rm "${D}"/etc/init.d/logd
}

pkg_preinst() {
	# check for cluster group, if it doesn't exist make it
	groupadd -g 65 haclient
	# check for cluster user, if it doesn't exist make it
	useradd -u 65 -g haclient -s /dev/null -d /var/lib/heartbeat hacluster
}

pkg_postinst() {
	chown -R hacluster:haclient /var/lib/heartbeat/cores
	chown -R hacluster:haclient /var/lib/heartbeat/lrm
}



1.1                  sys-cluster/cluster-glue/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sys-cluster/cluster-glue
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/cluster-glue/ChangeLog,v 1.1 2010/06/20 21:29:19 xarthisius Exp $

*cluster-glue-1.0.5 (20 Jun 2010)

  20 Jun 2010; Kacper Kowalik <xarthisius@gentoo.org>
  +files/1.0.5-docs.patch, +cluster-glue-1.0.5.ebuild,
  +files/1.0.5-respect_cflags.patch, +files/heartbeat-logd.init,
  +metadata.xml:
  Initial import. Ebuild written by Tomáš Chvátal <scarabeus@gentoo.org>




1.1                  sys-cluster/cluster-glue/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/cluster-glue/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>ha-cluster</herd>
	<longdescription>Cluster Glue is a set of libraries, tools and utilities suitable for the Heartbeat/Pacemaker cluster stack.</longdescription>
</pkgmetadata>