[gentoo-commits] gentoo-x86 commit in dev-util/devhelp: ChangeLog devhelp-2.30.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-util/devhelp: ChangeLog devhelp-2.30.0.ebuild

[Pacho Ramos (pacho)]

pacho       10/06/18 12:52:38

  Modified:             ChangeLog
  Added:                devhelp-2.30.0.ebuild
  Log:
  Version bump
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.108                dev-util/devhelp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/devhelp/ChangeLog?rev=1.108&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/devhelp/ChangeLog?rev=1.108&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/devhelp/ChangeLog?r1=1.107&r2=1.108

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/devhelp/ChangeLog,v
retrieving revision 1.107
retrieving revision 1.108
diff -u -r1.107 -r1.108
--- ChangeLog	23 May 2010 18:18:12 -0000	1.107
+++ ChangeLog	18 Jun 2010 12:52:38 -0000	1.108
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/devhelp
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/ChangeLog,v 1.107 2010/05/23 18:18:12 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/ChangeLog,v 1.108 2010/06/18 12:52:38 pacho Exp $
+
+*devhelp-2.30.0 (18 Jun 2010)
+
+  18 Jun 2010; Pacho Ramos <pacho@gentoo.org> +devhelp-2.30.0.ebuild:
+  Version bump for Gnome 2.30
 
   23 May 2010; Raúl Porcel <armin76@gentoo.org> devhelp-0.23-r1.ebuild:
   sparc stable



1.1                  dev-util/devhelp/devhelp-2.30.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/devhelp/devhelp-2.30.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/devhelp/devhelp-2.30.0.ebuild?rev=1.1&content-type=text/plain

Index: devhelp-2.30.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/devhelp-2.30.0.ebuild,v 1.1 2010/06/18 12:52:38 pacho Exp $

EAPI="2"
GCONF_DEBUG="no"

inherit eutils toolchain-funcs gnome2 python

DESCRIPTION="An API documentation browser for GNOME 2"
HOMEPAGE="http://live.gnome.org/devhelp"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-fbsd"
IUSE=""

RDEPEND=">=gnome-base/gconf-2.6
	>=x11-libs/gtk+-2.10
	>=dev-libs/glib-2.10
	>=x11-libs/libwnck-2.10
	>=net-libs/webkit-gtk-1.1.13
	>=dev-libs/libunique-1"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/intltool-0.40
	>=dev-util/pkgconfig-0.9"

DOCS="AUTHORS ChangeLog NEWS README"

pkg_setup() {
	# ICC is crazy, silence warnings (bug #154010)
	if [[ $(tc-getCC) == "icc" ]] ; then
		G2CONF="${G2CONF} --with-compile-warnings=no"
	fi
}

src_prepare() {
	gnome2_src_prepare

	# disable pyc compiling
	rm py-compile
	ln -s $(type -P true) py-compile

	# Fix intltoolize broken file, see upstream #577133
	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
		|| die "sed 1 failed"

	# Fix build with older libunique, bug #286890
	sed -e 's/-DG.*_SINGLE_INCLUDES//' \
		-e 's/-DG.*_DEPRECATED//' \
		-i src/Makefile.am src/Makefile.in || die "sed 2 failed"
}

src_install() {
	gnome2_src_install
	# Internal library, punt .la file
	find "${D}" -name "*.la" -delete || die "remove of la files failed"
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_need_rebuild
	python_mod_optimize /usr/$(get_libdir)/gedit-2/plugins/devhelp
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup /usr/$(get_libdir)/gedit-2/plugins/devhelp
}