[gentoo-commits] gentoo-x86 commit in net-dns/dnsmasq: ChangeLog dnsmasq-2.55.ebuild dnsmasq-2.51.ebuild dnsmasq-2.50.ebuild

[gentoo-commits] gentoo-x86 commit in net-dns/dnsmasq: ChangeLog dnsmasq-2.55.ebuild dnsmasq-2.51.ebuild dnsmasq-2.50.ebuild

[Patrick McLean (chutzpah)]

chutzpah    10/06/10 00:06:40

  Modified:             ChangeLog
  Added:                dnsmasq-2.55.ebuild
  Removed:              dnsmasq-2.51.ebuild dnsmasq-2.50.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.197                net-dns/dnsmasq/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/dnsmasq/ChangeLog?rev=1.197&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/dnsmasq/ChangeLog?rev=1.197&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/dnsmasq/ChangeLog?r1=1.196&r2=1.197

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/dnsmasq/ChangeLog,v
retrieving revision 1.196
retrieving revision 1.197
diff -u -r1.196 -r1.197
--- ChangeLog	24 May 2010 18:53:22 -0000	1.196
+++ ChangeLog	10 Jun 2010 00:06:40 -0000	1.197
@@ -1,6 +1,12 @@
 # ChangeLog for net-dns/dnsmasq
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/dnsmasq/ChangeLog,v 1.196 2010/05/24 18:53:22 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/dnsmasq/ChangeLog,v 1.197 2010/06/10 00:06:40 chutzpah Exp $
+
+*dnsmasq-2.55 (10 Jun 2010)
+
+  10 Jun 2010; Patrick McLean <chutzpah@gentoo.org> -dnsmasq-2.50.ebuild,
+  -dnsmasq-2.51.ebuild, +dnsmasq-2.55.ebuild:
+  Version bump.
 
   24 May 2010; Pacho Ramos <pacho@gentoo.org> dnsmasq-2.52.ebuild:
   stable amd64, bug 316715



1.1                  net-dns/dnsmasq/dnsmasq-2.55.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/dnsmasq/dnsmasq-2.55.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/dnsmasq/dnsmasq-2.55.ebuild?rev=1.1&content-type=text/plain

Index: dnsmasq-2.55.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/dnsmasq/dnsmasq-2.55.ebuild,v 1.1 2010/06/10 00:06:40 chutzpah Exp $

EAPI=2

inherit eutils toolchain-funcs flag-o-matic

MY_P="${P/_/}"
MY_PV="${PV/_/}"
DESCRIPTION="Small forwarding DNS server"
HOMEPAGE="http://www.thekelleys.org.uk/dnsmasq/"
SRC_URI="http://www.thekelleys.org.uk/dnsmasq/${MY_P}.tar.lzma"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="dbus +dhcp ipv6 nls tftp"

RDEPEND="dbus? ( sys-apps/dbus )
	nls? (
		sys-devel/gettext
		net-dns/libidn
	)"

DEPEND="${RDEPEND}
	|| ( app-arch/xz-utils app-arch/lzma-utils )"

S="${WORKDIR}/${PN}-${MY_PV}"

src_prepare() {
	sed -i '/^AWK/s:nawk:gawk:' Makefile #214865

	# dnsmasq on FreeBSD wants the config file in a silly location, this fixes
	epatch "${FILESDIR}/${PN}-2.47-fbsd-config.patch"
}

src_configure() {
	use tftp || append-flags -DNO_TFTP
	use dhcp || append-flags -DNO_DHCP
	use ipv6 || append-flags -DNO_IPV6
	use dbus && sed -i '$ a #define HAVE_DBUS' src/config.h
}

src_compile() {
	emake \
		PREFIX=/usr \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		all$(use nls && echo "-i18n") || die
}

src_install() {
	emake \
		PREFIX=/usr \
		MANDIR=/usr/share/man \
		DESTDIR="${D}" \
		install$(use nls && echo "-i18n") || die

	dodoc CHANGELOG FAQ
	dohtml *.html

	newinitd "${FILESDIR}"/dnsmasq-init dnsmasq
	newconfd "${FILESDIR}"/dnsmasq.confd dnsmasq
	insinto /etc
	newins dnsmasq.conf.example dnsmasq.conf

	if use dbus ; then
		insinto /etc/dbus-1/system.d
		doins dbus/dnsmasq.conf
	fi
}