[gentoo-commits] gentoo-x86 commit in sci-libs/superlu: superlu-4.0-r1.ebuild ChangeLog metadata.xml

[gentoo-commits] gentoo-x86 commit in sci-libs/superlu: superlu-4.0-r1.ebuild ChangeLog metadata.xml

[Justin Lecher (jlec)]

jlec        10/06/09 08:18:58

  Added:                superlu-4.0-r1.ebuild ChangeLog metadata.xml
  Log:
  Moved from sci overlay to tree
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  sci-libs/superlu/superlu-4.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/superlu/superlu-4.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/superlu/superlu-4.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: superlu-4.0-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/superlu/superlu-4.0-r1.ebuild,v 1.1 2010/06/09 08:18:58 jlec Exp $

EAPI="2"

inherit autotools eutils toolchain-funcs

MY_PN=SuperLU

DESCRIPTION="Sparse LU factorization library"
HOMEPAGE="http://crd.lbl.gov/~xiaoye/SuperLU/"
SRC_URI="${HOMEPAGE}/${PN}_${PV}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples static-libs test"

RDEPEND="virtual/blas"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	test? ( app-shells/tcsh )"

S="${WORKDIR}/${MY_PN}_${PV}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-autotools.patch
	epatch "${FILESDIR}"/${PN}-examples.patch
	epatch "${FILESDIR}"/${PV}-test.patch
	eautoreconf
}

src_configure() {
	econf \
		--with-blas="$(pkg-config --libs blas)" \
		$(use_enable static-libs static)
}

src_test() {
	cd TESTING/MATGEN
	emake -j1 \
		FORTRAN="$(tc-getFC)" \
		LOADER="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		FFLAGS="${FFLAGS}" \
		LOADOPTS="${LDFLAGS}" \
		SUPERLULIB="../SRC/.libs/libsuperlu.a" \
		BLASLIB="$(pkg-config --libs blas)" \
		CC="$(tc-getCC)" \
		|| die "emake matrix generation failed"
	cd ..
	emake -j1 \
		CC="$(tc-getCC)" \
		FORTRAN="$(tc-getFC)" \
		LOADER="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		FFLAGS="${FFLAGS}" \
		LOADOPTS="${LDFLAGS}" \
		SUPERLULIB="../SRC/.libs/libsuperlu.so" \
		BLASLIB="$(pkg-config --libs blas)" \
		|| die "emake test failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	insinto /usr/include/${PN}
	doins SRC/*.h || die

	dodoc README
	use doc && newdoc INSTALL/ug.ps userguide.ps
	if use examples; then
		insinto /usr/share/doc/${PF}
		newins -r EXAMPLE examples
	fi
}



1.1                  sci-libs/superlu/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/superlu/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/superlu/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sci-libs/superlu
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/superlu/ChangeLog,v 1.1 2010/06/09 08:18:58 jlec Exp $

*superlu-4.0-r1 (09 Jun 2010)

  09 Jun 2010; Justin Lecher <jlec@gentoo.org> +files/4.0-test.patch,
  +superlu-4.0-r1.ebuild, +files/superlu-4.0-autotools.patch,
  +files/superlu-examples.patch, +metadata.xml:
  Moved from sci overlay to tree




1.1                  sci-libs/superlu/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/superlu/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/superlu/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>sci</herd>
<longdescription lang="en">
  SuperLU is a general purpose library for the direct solution of large,
  sparse, nonsymmetric systems of linear equations on high performance
  machines. The library is written in C and is callable from either C or
  Fortran. The library routines will perform an LU decomposition with
  partial pivoting and triangular system solves through forward and back
  substitution. The LU factorization routines can handle non-square
  matrices but the triangular solves are performed only for square
  matrices. The matrix columns may be preordered (before factorization)
  either through library or user supplied routines. This preordering for
  sparsity is completely separate from the factorization. Working
  precision iterative refinement subroutines are provided for improved
  backward stability. Routines are also provided to equilibrate the
  system, estimate the condition number, calculate the relative backward
  error, and estimate error bounds for the refined solutions.
</longdescription>
</pkgmetadata>