[gentoo-commits] gentoo-x86 commit in media-video/rtmpdump: ChangeLog rtmpdump-2.2e.ebuild

[gentoo-commits] gentoo-x86 commit in media-video/rtmpdump: ChangeLog rtmpdump-2.2e.ebuild

[Markos Chandras (hwoarang)]

hwoarang    10/06/05 18:09:11

  Modified:             ChangeLog
  Added:                rtmpdump-2.2e.ebuild
  Log:
  Version bump
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  media-video/rtmpdump/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/rtmpdump/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/rtmpdump/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/rtmpdump/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/rtmpdump/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	5 Jun 2010 11:07:22 -0000	1.1
+++ ChangeLog	5 Jun 2010 18:09:10 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/rtmpdump
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/rtmpdump/ChangeLog,v 1.1 2010/06/05 11:07:22 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/rtmpdump/ChangeLog,v 1.2 2010/06/05 18:09:10 hwoarang Exp $
+
+*rtmpdump-2.2e (05 Jun 2010)
+
+  05 Jun 2010; Markos Chandras <hwoarang@gentoo.org> +rtmpdump-2.2e.ebuild:
+  Version bump thanks to Maxime de Roucy (maxime1986)
+  <maxime.deroucy@gmail.com>
 
 *rtmpdump-2.2d (05 Jun 2010)
 



1.1                  media-video/rtmpdump/rtmpdump-2.2e.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/rtmpdump/rtmpdump-2.2e.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/rtmpdump/rtmpdump-2.2e.ebuild?rev=1.1&content-type=text/plain

Index: rtmpdump-2.2e.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/rtmpdump/rtmpdump-2.2e.ebuild,v 1.1 2010/06/05 18:09:10 hwoarang Exp $

EAPI="2"

inherit toolchain-funcs

DESCRIPTION="Open source command-line RTMP client intended to stream audio or video flash content"
HOMEPAGE="http://rtmpdump.mplayerhq.hu/"
SRC_URI="http://rtmpdump.mplayerhq.hu/download/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gnutls polarssl ssl"

DEPEND="ssl? (
		gnutls? ( net-libs/gnutls )
		polarssl? ( !gnutls? ( net-libs/polarssl ) )
		!gnutls? ( !polarssl? ( dev-libs/openssl ) )
	)
	sys-libs/zlib"
RDEPEND="${DEPEND}"

pkg_setup() {
	if ! use ssl && ( use gnutls ||	use polarssl ) ; then
		ewarn "USE='gnutls polarssl' are ignored without USE='ssl'."
		ewarn "Please review the local USE flags for this package."
	fi
}

src_prepare() {
	# fix Makefile ( bug #298535 and bug #318353 )
	sed -i 's/\$(MAKEFLAGS)//g' Makefile \
		|| die "failed to fix Makefile"
}

src_compile() {
	local crypto=""
	if use ssl ; then
		if use gnutls ;	then
			crypto="GNUTLS"
		elif use polarssl ; then
			crypto="POLARSSL"
		else
			crypto="OPENSSL"
		fi
	fi

	emake CC=$(tc-getCC) LD=$(tc-getLD) \
		OPT="${CFLAGS}" XLDFLAGS="${LDFLAGS}" CRYPTO="${crypto}" SYS=posix || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" prefix="${DESTTREE}" mandir="${DOCDESTTREE}" install \
		|| die "emake install failed"
	dodoc README ChangeLog rtmpdump.1.html rtmpgw.8.html || die "dodoc failed"
}