* [gentoo-commits] gentoo-x86 commit in dev-lisp/clisp: ChangeLog clisp-2.48-r2.ebuild
@ 2010-06-03 20:13 TomAs Touceda (chiiph)
0 siblings, 0 replies; 2+ messages in thread
From: TomAs Touceda (chiiph) @ 2010-06-03 20:13 UTC (permalink / raw
To: gentoo-commits
chiiph 10/06/03 20:13:23
Modified: ChangeLog
Added: clisp-2.48-r2.ebuild
Log:
CLisp supports db:4.7, update dependency.
(Portage version: 2.2_rc67/cvs/Linux i686)
Revision Changes Path
1.98 dev-lisp/clisp/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/clisp/ChangeLog?rev=1.98&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/clisp/ChangeLog?rev=1.98&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/clisp/ChangeLog?r1=1.97&r2=1.98
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lisp/clisp/ChangeLog,v
retrieving revision 1.97
retrieving revision 1.98
diff -u -r1.97 -r1.98
--- ChangeLog 14 Apr 2010 01:53:24 -0000 1.97
+++ ChangeLog 3 Jun 2010 20:13:23 -0000 1.98
@@ -1,6 +1,11 @@
# ChangeLog for dev-lisp/clisp
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lisp/clisp/ChangeLog,v 1.97 2010/04/14 01:53:24 chiiph Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lisp/clisp/ChangeLog,v 1.98 2010/06/03 20:13:23 chiiph Exp $
+
+*clisp-2.48-r2 (03 Jun 2010)
+
+ 03 Jun 2010; Tomas Touceda <chiiph@gentoo.org> +clisp-2.48-r2.ebuild:
+ CLisp supports db:4.7, update dependency.
14 Apr 2010; Tomas Touceda <chiiph@gentoo.org> -clisp-2.48.ebuild:
Cleanup old testing ebuild
1.1 dev-lisp/clisp/clisp-2.48-r2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/clisp/clisp-2.48-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/clisp/clisp-2.48-r2.ebuild?rev=1.1&content-type=text/plain
Index: clisp-2.48-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lisp/clisp/clisp-2.48-r2.ebuild,v 1.1 2010/06/03 20:13:23 chiiph Exp $
EAPI="2"
inherit flag-o-matic eutils toolchain-funcs multilib
DESCRIPTION="A portable, bytecode-compiled implementation of Common Lisp"
HOMEPAGE="http://clisp.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc -sparc ~x86"
IUSE="berkdb hyperspec X new-clx dbus fastcgi gdbm gtk pari +pcre postgres +readline svm -threads +unicode +zlib"
RDEPEND="virtual/libiconv
>=dev-libs/libsigsegv-2.4
>=dev-libs/ffcall-1.10
dbus? ( sys-apps/dbus )
fastcgi? ( dev-libs/fcgi )
gdbm? ( sys-libs/gdbm )
gtk? ( >=x11-libs/gtk+-2.10 >=gnome-base/libglade-2.6 )
pari? ( >=sci-mathematics/pari-2.3.0 )
postgres? ( >=virtual/postgresql-base-8.0 )
readline? ( >=sys-libs/readline-5.0 )
pcre? ( dev-libs/libpcre )
svm? ( sci-libs/libsvm )
zlib? ( sys-libs/zlib )
X? ( new-clx? ( x11-libs/libXpm ) )
hyperspec? ( dev-lisp/hyperspec )
berkdb? ( sys-libs/db:4.7 )"
DEPEND="${RDEPEND}
X? ( new-clx? ( x11-misc/imake x11-proto/xextproto ) )"
PDEPEND="dev-lisp/gentoo-init"
PROVIDE="virtual/commonlisp"
enable_modules() {
[[ $# = 0 ]] && die "${FUNCNAME[0]} must receive at least one argument"
for m in "$@" ; do
einfo "enabling module $m"
myconf+=" --with-module=${m}"
done
}
BUILDDIR="builddir"
# modules not enabled:
# * dirkey: fails to compile, requiring windows.h, possibly wrong #ifdefs
# * matlab, netica: not in portage
# * oracle: can't install oracle-instantclient
src_prepare() {
# More than -O1 breaks alpha/ia64
if use alpha || use ia64; then
sed -i -e 's/-O2//g' src/makemake.in || die
fi
}
src_configure() {
# We need this to build on alpha/ia64
if use alpha || use ia64; then
replace-flags -O? -O1
append-flags '-D NO_MULTIMAP_SHM -D NO_MULTIMAP_FILE -D NO_SINGLEMAP -D NO_TRIVIALMAP'
fi
# QA issue with lisp.run
append-flags -Wa,--noexecstack
# built-in features
local myconf="--with-ffcall --without-dynamic-modules"
# There's a problem with jit_allocai function
# if use jit; then
# myconf+=" --with-jitc=lightning"
# fi
if use threads; then
myconf+=" --with-threads=POSIX_THREADS"
fi
# default modules
enable_modules wildcard rawsock
# optional modules
use elibc_glibc && enable_modules bindings/glibc
if use X; then
if use new-clx; then
enable_modules clx/new-clx
else
enable_modules clx/mit-clx
fi
fi
if use postgres; then
enable_modules postgresql
append-flags -I$(pg_config --includedir)
fi
if use berkdb; then
enable_modules berkeley-db
append-flags -I/usr/include/db4.7
fi
use dbus && enable_modules dbus
use fastcgi && enable_modules fastcgi
use gdbm && enable_modules gdbm
use gtk && enable_modules gtk2
use pari && enable_modules pari
use pcre && enable_modules pcre
use svm && enable_modules libsvm
use zlib && enable_modules zlib
if use hyperspec; then
CLHSROOT="file:///usr/share/doc/hyperspec/HyperSpec/"
else
CLHSROOT="http://www.lispworks.com/reference/HyperSpec/"
fi
# configure chokes on --sysconfdir option
local configure="./configure --prefix=/usr --libdir=/usr/$(get_libdir) \
$(use_with readline) $(use_with unicode) \
${myconf} --hyperspec=${CLHSROOT} ${BUILDDIR}"
einfo "${configure}"
${configure} || die "./configure failed"
sed -i 's,"vi","nano",g' "${BUILDDIR}"/config.lisp || die
IMPNOTES="file://${ROOT%/}/usr/share/doc/${PN}-${PVR}/html/impnotes.html"
sed -i "s,http://clisp.cons.org/impnotes/,${IMPNOTES},g" \
"${BUILDDIR}"/config.lisp || die
}
src_compile() {
export VARTEXFONTS="${T}"/fonts
cd "${BUILDDIR}"
# parallel build fails
emake -j1 || die "emake failed"
}
src_install() {
pushd "${BUILDDIR}"
make DESTDIR="${D}" prefix=/usr install-bin || die
doman clisp.1 || die
dodoc SUMMARY README* NEWS MAGIC.add ANNOUNCE || die
fperms a+x /usr/$(get_libdir)/clisp-${PV/_*/}/clisp-link || die
# stripping them removes common symbols (defined but uninitialised variables)
# which are then needed to build modules...
export STRIP_MASK="*/usr/$(get_libdir)/clisp-${PV}/*/*"
popd
dohtml doc/impnotes.{css,html} doc/regexp.html doc/clisp.png || die
dodoc doc/{CLOS-guide,LISP-tutorial}.txt || die
}
pkg_postinst() {
if use threads || use jit; then
while read line; do elog ${line}; done <<EOF
Upstream considers threads to be of Alpha quality, therefore
it is likely that you will encounter bugs in using them. If you do,
please report bugs upstream:
Mailing list: https://lists.sourceforge.net/lists/listinfo/clisp-devel
Bug tracker: http://sourceforge.net/tracker/?atid=101355&group_id=1355
EOF
fi
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-lisp/clisp: ChangeLog clisp-2.48-r2.ebuild
@ 2012-12-04 0:00 Panagiotis Christopoulos (pchrist)
0 siblings, 0 replies; 2+ messages in thread
From: Panagiotis Christopoulos (pchrist) @ 2012-12-04 0:00 UTC (permalink / raw
To: gentoo-commits
pchrist 12/12/04 00:00:48
Modified: ChangeLog clisp-2.48-r2.ebuild
Log:
minor patch to 2.48-r2, fixes bug #425748 , thanks to Alexey Kretov (domini at onego.ru)
(Portage version: 2.1.11.33/cvs/Linux x86_64, unsigned Manifest commit)
Revision Changes Path
1.105 dev-lisp/clisp/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/clisp/ChangeLog?rev=1.105&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/clisp/ChangeLog?rev=1.105&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/clisp/ChangeLog?r1=1.104&r2=1.105
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lisp/clisp/ChangeLog,v
retrieving revision 1.104
retrieving revision 1.105
diff -u -r1.104 -r1.105
--- ChangeLog 29 Mar 2011 12:17:01 -0000 1.104
+++ ChangeLog 4 Dec 2012 00:00:48 -0000 1.105
@@ -1,6 +1,11 @@
# ChangeLog for dev-lisp/clisp
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lisp/clisp/ChangeLog,v 1.104 2011/03/29 12:17:01 angelos Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lisp/clisp/ChangeLog,v 1.105 2012/12/04 00:00:48 pchrist Exp $
+
+ 03 Dec 2012; Panagiotis Christopoulos <pchrist@gentoo.org>
+ clisp-2.48-r2.ebuild, +files/clisp-2.48-bits_ipctypes_to_sys_ipc.patch:
+ minor patch to 2.48-r2, fixes bug #425748 , thanks to Alexey Kretov (domini
+ at onego.ru)
29 Mar 2011; Christoph Mende <angelos@gentoo.org> clisp-2.47-r1.ebuild,
clisp-2.48-r1.ebuild, clisp-2.48-r2.ebuild:
1.5 dev-lisp/clisp/clisp-2.48-r2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/clisp/clisp-2.48-r2.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/clisp/clisp-2.48-r2.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lisp/clisp/clisp-2.48-r2.ebuild?r1=1.4&r2=1.5
Index: clisp-2.48-r2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lisp/clisp/clisp-2.48-r2.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- clisp-2.48-r2.ebuild 29 Mar 2011 12:17:01 -0000 1.4
+++ clisp-2.48-r2.ebuild 4 Dec 2012 00:00:48 -0000 1.5
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lisp/clisp/clisp-2.48-r2.ebuild,v 1.4 2011/03/29 12:17:01 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lisp/clisp/clisp-2.48-r2.ebuild,v 1.5 2012/12/04 00:00:48 pchrist Exp $
EAPI="2"
@@ -57,6 +57,7 @@
if use alpha || use ia64; then
sed -i -e 's/-O2//g' src/makemake.in || die
fi
+ epatch "${FILESDIR}/${P}-bits_ipctypes_to_sys_ipc.patch"
}
src_configure() {
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2012-12-04 0:00 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-06-03 20:13 [gentoo-commits] gentoo-x86 commit in dev-lisp/clisp: ChangeLog clisp-2.48-r2.ebuild TomAs Touceda (chiiph)
-- strict thread matches above, loose matches on Subject: below --
2012-12-04 0:00 Panagiotis Christopoulos (pchrist)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox