[gentoo-commits] gentoo-x86 commit in dev-python/sphinx: ChangeLog sphinx-1.0_beta2.ebuild sphinx-1.0_beta1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-python/sphinx: ChangeLog sphinx-1.0_beta2.ebuild sphinx-1.0_beta1.ebuild

[Dirkjan Ochtman (djc)]

djc         10/05/31 06:25:40

  Modified:             ChangeLog
  Added:                sphinx-1.0_beta2.ebuild
  Removed:              sphinx-1.0_beta1.ebuild
  Log:
  Bumped the dev-python/sphinx beta version.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.56                 dev-python/sphinx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sphinx/ChangeLog?rev=1.56&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sphinx/ChangeLog?rev=1.56&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sphinx/ChangeLog?r1=1.55&r2=1.56

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v
retrieving revision 1.55
retrieving revision 1.56
diff -u -r1.55 -r1.56
--- ChangeLog	25 May 2010 10:53:47 -0000	1.55
+++ ChangeLog	31 May 2010 06:25:40 -0000	1.56
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/sphinx
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v 1.55 2010/05/25 10:53:47 djc Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v 1.56 2010/05/31 06:25:40 djc Exp $
+
+*sphinx-1.0_beta2 (31 May 2010)
+
+  31 May 2010; Dirkjan Ochtman <djc@gentoo.org> -sphinx-1.0_beta1.ebuild,
+  +sphinx-1.0_beta2.ebuild:
+  Bumped the Sphinx 1.0 beta version.
 
 *sphinx-1.0_beta1 (25 May 2010)
 



1.1                  dev-python/sphinx/sphinx-1.0_beta2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sphinx/sphinx-1.0_beta2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sphinx/sphinx-1.0_beta2.ebuild?rev=1.1&content-type=text/plain

Index: sphinx-1.0_beta2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/sphinx-1.0_beta2.ebuild,v 1.1 2010/05/31 06:25:40 djc Exp $

EAPI="3"
SUPPORT_PYTHON_ABIS="1"
DISTUTILS_SRC_TEST="nosetests"

inherit distutils

MY_PN="Sphinx"
MY_P="${MY_PN}-${PV/_beta/b}"

DESCRIPTION="Tool to create documentation for Python projects"
HOMEPAGE="http://sphinx.pocoo.org/ http://pypi.python.org/pypi/Sphinx"
SRC_URI="http://pypi.python.org/packages/source/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS=""
IUSE="doc test latex"

RDEPEND=">=dev-python/pygments-0.8
	>=dev-python/jinja-2.2
	>=dev-python/docutils-0.5
	latex? ( dev-texlive/texlive-latexextra )"
DEPEND="${RDEPEND}
	dev-python/setuptools
	test? ( dev-python/nose )"
RESTRICT_PYTHON_ABIS="3.*"

S="${WORKDIR}/${MY_P}"

DOCS="CHANGES"

src_compile() {
	distutils_src_compile

	if use doc; then
		cd doc
		einfo "Generation of documentation"
		PYTHONPATH="../" emake SPHINXBUILD="$(PYTHON -f) ../sphinx-build.py" html || die "Generation of documentation failed"
	fi
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml -A txt -r doc/_build/html/* || die "dohtml failed"
	fi
}

pkg_postinst() {
	distutils_pkg_postinst

	# Generating the Grammar pickle to avoid on the fly generation causing sandbox violations (bug #266015)
	generation_of_grammar_pickle() {
		"$(PYTHON)" -c "from sphinx.pycode.pgen2.driver import load_grammar; load_grammar('${ROOT%/}${EPREFIX}$(python_get_sitedir)/sphinx/pycode/Grammar.txt')" || die "Generation of grammar pickle failed"
	}
	python_execute_function --action-message 'Generation of Grammar pickle with Python ${PYTHON_ABI}...' generation_of_grammar_pickle
}

pkg_postrm() {
	distutils_pkg_postrm

	deletion_of_grammar_pickle() {
		rm "${ROOT%/}${EPREFIX}$(python_get_sitedir)/sphinx/pycode"/Grammar*.pickle
	}
	python_execute_function --action-message 'Deletion of Grammar pickle with Python ${PYTHON_ABI}...' deletion_of_grammar_pickle
}