[gentoo-commits] gentoo-x86 commit in sys-apps/parted: parted-2.3.ebuild ChangeLog

["Jeroen Roovers (jer)" <jer@gentoo.org>]

jer         10/05/29 16:18:05

  Modified:             ChangeLog
  Added:                parted-2.3.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc67/cvs/Linux i686)

Revision  Changes    Path
1.148                sys-apps/parted/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/parted/ChangeLog?rev=1.148&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/parted/ChangeLog?rev=1.148&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/parted/ChangeLog?r1=1.147&r2=1.148

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/parted/ChangeLog,v
retrieving revision 1.147
retrieving revision 1.148
diff -u -r1.147 -r1.148
--- ChangeLog	20 May 2010 17:17:13 -0000	1.147
+++ ChangeLog	29 May 2010 16:18:05 -0000	1.148
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/parted
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/parted/ChangeLog,v 1.147 2010/05/20 17:17:13 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/parted/ChangeLog,v 1.148 2010/05/29 16:18:05 jer Exp $
+
+*parted-2.3 (29 May 2010)
+
+  29 May 2010; Jeroen Roovers <jer@gentoo.org> +parted-2.3.ebuild:
+  Version bump.
 
   20 May 2010; Jeroen Roovers <jer@gentoo.org> parted-2.2.ebuild:
   Reverting x86 stabilisation (bug #316453).



1.1                  sys-apps/parted/parted-2.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/parted/parted-2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/parted/parted-2.3.ebuild?rev=1.1&content-type=text/plain

Index: parted-2.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/parted/parted-2.3.ebuild,v 1.1 2010/05/29 16:18:05 jer Exp $

EAPI="2"

inherit autotools eutils

DESCRIPTION="Create, destroy, resize, check, copy partitions and file systems"
HOMEPAGE="http://www.gnu.org/software/parted"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="nls readline +debug selinux device-mapper"

# specific version for gettext needed
# to fix bug 85999
DEPEND=">=sys-fs/e2fsprogs-1.27
	>=sys-libs/ncurses-5.2
	nls? ( >=sys-devel/gettext-0.12.1-r2 )
	readline? ( >=sys-libs/readline-5.2 )
	selinux? ( sys-libs/libselinux )
	device-mapper? ( || (
		>=sys-fs/lvm2-2.02.45
		sys-fs/device-mapper )
	)"

src_prepare() {
	# The symlink test should SKIP instead of FAIL
	# when /dev/mapper is not found
	sed -i libparted/tests/Makefile.am \
		-e 's|t3000-symlink.sh||g' || die "sed failed"

	# The t6000-dm.sh test should equally SKIP instead of FAIL
	# when no dm support is present in the kernel
	sed -i tests/Makefile.am \
		-e '/t6000-dm.sh/d' || die "sed failed"

	eautoreconf
}

src_configure() {
	econf \
		$(use_with readline) \
		$(use_enable nls) \
		$(use_enable debug) \
		$(use_enable selinux) \
		$(use_enable device-mapper) \
		--disable-rpath \
		--disable-Werror || die "Configure failed"
}

src_test() {
	if use debug; then
		emake check || die "emake check failed"
	else
		ewarn "Skipping tests because USE=-debug is set."
	fi
}

src_install() {
	emake install DESTDIR="${D}" || die "Install failed"
	dodoc AUTHORS BUGS ChangeLog NEWS README THANKS TODO
	dodoc doc/{API,FAT,USER.jp}
}