public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in net-fs/samba: samba-3.5.3.ebuild ChangeLog
@ 2010-05-19 15:19 Patrick Lauer (patrick)
  0 siblings, 0 replies; 4+ messages in thread
From: Patrick Lauer (patrick) @ 2010-05-19 15:19 UTC (permalink / raw
  To: gentoo-commits

patrick     10/05/19 15:19:28

  Modified:             ChangeLog
  Added:                samba-3.5.3.ebuild
  Log:
  Bump
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.415                net-fs/samba/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?rev=1.415&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?rev=1.415&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?r1=1.414&r2=1.415

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v
retrieving revision 1.414
retrieving revision 1.415
diff -u -r1.414 -r1.415
--- ChangeLog	18 May 2010 08:08:36 -0000	1.414
+++ ChangeLog	19 May 2010 15:19:28 -0000	1.415
@@ -1,6 +1,11 @@
 # ChangeLog for net-fs/samba
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v 1.414 2010/05/18 08:08:36 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v 1.415 2010/05/19 15:19:28 patrick Exp $
+
+*samba-3.5.3 (19 May 2010)
+
+  19 May 2010; Patrick Lauer <patrick@gentoo.org> +samba-3.5.3.ebuild:
+  Bump
 
   18 May 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org> samba-3.4.6.ebuild:
   x86 stable wrt bug #300158



1.1                  net-fs/samba/samba-3.5.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild?rev=1.1&content-type=text/plain

Index: samba-3.5.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild,v 1.1 2010/05/19 15:19:28 patrick Exp $

EAPI="2"

inherit pam confutils versionator multilib eutils

MY_PV=${PV/_/}
MY_P="${PN}-${MY_PV}"

DESCRIPTION="Library bits of the samba network filesystem"
HOMEPAGE="http://www.samba.org/"
SRC_URI="mirror://samba/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="acl addns ads aio avahi caps +client cluster cups debug doc examples fam
	ldap ldb +netapi pam quota +readline +server +smbclient smbsharemodes swat
	syslog winbind "

DEPEND="dev-libs/popt
	!net-fs/samba-client
	!net-fs/samba-libs
	!net-fs/samba-server
	sys-libs/talloc
	sys-libs/tdb
	virtual/libiconv
	ads? ( virtual/krb5 sys-fs/e2fsprogs
		client? ( sys-apps/keyutils ) )
	avahi? ( net-dns/avahi )
	caps? ( sys-libs/libcap )
	client? ( !net-fs/mount-cifs
		dev-libs/iniparser )
	cluster? ( dev-db/ctdb )
	cups? ( net-print/cups )
	debug? ( dev-libs/dmalloc )
	fam? ( dev-libs/libgamin )
	ldap? ( net-nds/openldap )
	pam? ( virtual/pam
		winbind? ( dev-libs/iniparser ) )
	readline? ( >=sys-libs/readline-5.2 )
	syslog? ( virtual/logger )"

RDEPEND="${DEPEND}"

# Disable tests since we don't want to build that much here
RESTRICT="test"

SBINPROGS=""
BINPROGS=""

if use server ; then
	SBINPROGS="${SBINPROGS} bin/smbd bin/nmbd"
	BINPROGS="${BINPROGS} bin/testparm bin/smbstatus bin/smbcontrol bin/pdbedit
		bin/profiles bin/sharesec bin/eventlogadm"

	use swat && SBINPROGS="${SBINPROGS} bin/swat"
	use winbind && SBINPROGS="${SBINPROGS} bin/winbindd"
	use ads && use winbind && SBINPROGS="${SBINPROGS} bin/winbind_krb5_locator"
fi

if use client ; then
	BINPROGS="${BINPROGS} bin/smbclient bin/net bin/smbget bin/smbtree
		bin/nmblookup bin/smbpasswd bin/rpcclient bin/smbcacls bin/smbcquotas
		bin/ntlm_auth"

	use ads && SBINPROGS="${SBINPROGS} bin/cifs.upcall"
fi

use cups && BINPROGS="${BINPROGS} bin/smbspool"
use ldb && BINPROGS="${BINPROGS} bin/ldbedit bin/ldbsearch bin/ldbadd bin/ldbdel bin/ldbmodify bin/ldbrename";
use winbind && BINPROGS="${BINPROGS} bin/wbinfo"

S="${WORKDIR}/${MY_P}/source3"

# TODO:
# - enable iPrint on Prefix/OSX and Darwin?
# - selftest-prefix? selftest?
# - AFS?

CONFDIR="${FILESDIR}/$(get_version_component_range 1-2)"

pkg_setup() {
	confutils_use_depend_all ads ldap
	confutils_use_depend_all swat server
}

src_prepare() {
	cp "${FILESDIR}/samba-3.4.2-lib.tevent.python.mk" "../lib/tevent/python.mk"

	# ensure that winbind has correct ldflags (QA notice)
	sed -i \
		-e 's|LDSHFLAGS="|LDSHFLAGS="\\${LDFLAGS} |g' \
		configure || die "sed failed"
}

src_configure() {
	local myconf

	# Filter out -fPIE
	[[ ${CHOST} == *-*bsd* ]] || use hppa && myconf="${myconf} --disable-pie"

	# Upstream refuses to make this configurable
	use caps && export ac_cv_header_sys_capability_h=yes || export ac_cv_header_sys_capability_h=no

	# use_with doesn't accept 2 USE-flags
	if use client && use ads ; then
		myconf="${myconf} --with-cifsupcall"
	else
		myconf="${myconf} --without-cifsupcall"
	fi

	# Notes:
	# - automount is only needed in conjunction with NIS and we don't have that
	# anymore => LDAP?
	# - --without-dce-dfs and --without-nisplus-home can't be passed to configure but are disabled by default
	econf ${myconf} \
		--with-piddir=/var/run/samba \
		--sysconfdir=/etc/samba \
		--localstatedir=/var \
		$(use_enable debug developer) \
		--enable-largefile \
		--enable-socket-wrapper \
		--enable-nss-wrapper \
		$(use_enable swat) \
		$(use_enable debug dmalloc) \
		$(use_enable cups) \
		--disable-iprint \
		$(use_enable fam) \
		--enable-shared-libs \
		--disable-dnssd \
		$(use_enable avahi) \
		--with-fhs \
		--with-privatedir=/var/lib/samba/private \
		--with-rootsbindir=/var/cache/samba \
		--with-lockdir=/var/cache/samba \
		--with-swatdir=/usr/share/doc/${PF}/swat \
		--with-configdir=/etc/samba \
		--with-logfilebase=/var/log/samba \
		--with-pammodulesdir=$(getpam_mod_dir) \
		--without-afs \
		--without-fake-kaserver \
		--without-vfs-afsacl \
		$(use_with ldap) \
		$(use_with ads) \
		$(use_with ads krb5 /usr) \
		$(use_with ads dnsupdate) \
		--without-automount \
		$(use_with client cifsmount) \
		$(use_with client cifsumount) \
		$(use_with pam) \
		$(use_with pam pam_smbpass) \
		$(use_with syslog) \
		$(use_with quota quotas) \
		$(use_with quota sys-quotas) \
		--without-utmp \
		--without-lib{talloc,tdb} \
		$(use_with netapi libnetapi) \
		$(use_with smbclient libsmbclient) \
		$(use_with smbsharemodes libsmbsharemodes) \
		$(use_with addns libaddns) \
		$(use_with cluster ctdb /usr) \
		$(use_with cluster cluster-support) \
		$(use_with acl acl-support) \
		$(use_with aio aio-support) \
		--with-sendfile-support \
		$(use_with winbind) \
		--without-included-popt \
		--without-included-iniparser
}

src_compile() {
	# compile libs
	if use addns ; then
		einfo "make addns library"
		emake libaddns || die "emake libaddns failed"
	fi
	if use netapi ; then
		einfo "make netapi library"
		emake libnetapi || die "emake libnetapi failed"
	fi
	if use smbclient ; then
		einfo "make smbclient library"
		emake libsmbclient || die "emake libsmbclient failed"
	fi
	if use smbsharemodes ; then
		einfo "make smbsharemodes library"
		emake libsmbsharemodes || die "emake libsmbsharemodes failed"
	fi

	# compile modules
	emake modules || die "building modules failed"

	# compile pam moudles
	if use pam ; then
		einfo "make pam modules"
		emake pam_modules || die "emake pam_modules failed";
	fi

	# compile winbind nss modules
	if use winbind ; then
		einfo "make nss modules"
		emake nss_modules || die "emake nss_modules failed";
	fi

	# compile utilities
	if [ -n "${BINPROGS}" ] ; then
		einfo "make binprogs"
		emake ${BINPROGS} || die "emake binprogs failed";
	fi
	if [ -n "${SBINPROGS}" ] ; then
		einfo "make sbinprogs"
		emake ${SBINPROGS} || die "emake sbinprogs failed";
	fi

	if use client ; then
		einfo "make {,u}mount.cifs"
		emake bin/{,u}mount.cifs || die "emake {,u}mount.cifs failed"
	fi
}

src_install() {
	# install libs
	if use addns ; then
		einfo "install addns library"
		emake installlibaddns DESTDIR="${D}" || die "emake install libaddns failed"
	fi
	if use netapi ; then
		einfo "install netapi library"
		emake installlibnetapi DESTDIR="${D}" || die "emake install libnetapi failed"
	fi
	if use smbclient ; then
		einfo "install smbclient library"
		emake installlibsmbclient DESTDIR="${D}" || die "emake install libsmbclient failed"
	fi
	if use smbsharemodes ; then
		einfo "install smbsharemodes library"
		emake installlibsmbsharemodes DESTDIR="${D}" || die "emake install libsmbsharemodes failed"
	fi

	# install modules
	emake installmodules DESTDIR="${D}" || die "installing modules failed"

	if use pam ; then
		einfo "install pam modules"
		emake installpammodules DESTDIR="${D}" || die "emake installpammodules failed"

		if use winbind ; then
			newpamd "${CONFDIR}/system-auth-winbind.pam" system-auth-winbind
			doman ../docs/manpages/pam_winbind.8
		fi

		newpamd "${CONFDIR}/samba.pam" samba
		dodoc pam_smbpass/README
	fi

	# Nsswitch extensions. Make link for wins and winbind resolvers
	if use winbind ; then
		einfo "install libwbclient"
		emake installlibwbclient DESTDIR="${D}" || die "emake installlibwbclient failed"
		dolib.so ../nsswitch/libnss_wins.so
		dosym libnss_wins.so /usr/$(get_libdir)/libnss_wins.so.2
		dolib.so ../nsswitch/libnss_winbind.so
		dosym libnss_winbind.so /usr/$(get_libdir)/libnss_winbind.so.2
	fi

	# install binaries
	insinto /usr
	for prog in ${SBINPROGS} ; do
		dosbin ${prog} || die "installing ${prog} failed"
		doman ../docs/manpages/${prog/bin\/}* || die "doman failed"
	done

	for prog in ${BINPROGS} ; do
		dobin ${prog} || die "installing ${prog} failed"
		doman ../docs/manpages/${prog/bin\/}* || die "doman failed"
	done

	# install server components
	if use server ; then
		doman ../docs/manpages/vfs* ../docs/manpages/samba.7

		diropts -m0700
		keepdir /var/lib/samba/private

		diropts -m1777
		keepdir /var/spool/samba

		diropts -m0755
		keepdir /var/{cache,log}/samba
		keepdir /var/lib/samba/{netlogon,profiles}
		keepdir /var/lib/samba/printers/{W32X86,WIN40,W32ALPHA,W32MIPS,W32PPC,X64,IA64,COLOR}
		keepdir /usr/$(get_libdir)/samba/{auth,pdb,rpc,idmap,nss_info,gpext}

		newconfd "${CONFDIR}/samba.confd" samba
		newinitd "${CONFDIR}/samba.initd" samba

		insinto /etc/samba
		doins "${CONFDIR}"/{smbusers,lmhosts}

		if use ldap ; then
			insinto /etc/openldap/schema
			doins ../examples/LDAP/samba.schema
		fi

		if use swat ; then
			insinto /etc/xinetd.d
			newins "${CONFDIR}/swat.xinetd" swat
			script/installswat.sh "${D}" "${ROOT}/usr/share/doc/${PF}/swat" "${S}" \
				|| die "installing swat failed"
		fi

		dodoc ../MAINTAINERS ../README* ../Roadmap ../WHATSNEW.txt ../docs/THANKS
	fi

	# install client files ({u,}mount.cifs into /)
	if use client ; then
		into /
		dosbin bin/{u,}mount.cifs || die "u/mount.cifs not around"
		doman ../docs/manpages/{u,}mount.cifs.8 || die "can't create man pages"
	fi

	# install the spooler to cups
	use cups && dosym /usr/bin/smbspool $(cups-config --serverbin)/backend/smb

	# install misc files
	insinto /etc/samba
	doins "${CONFDIR}"/smb.conf.default
	doman  ../docs/manpages/smb.conf.5

	insinto /usr/"$(get_libdir)"/samba
	doins ../codepages/{valid.dat,upcase.dat,lowcase.dat}

	# install docs
	if use doc ; then
		dohtml -r ../docs/htmldocs/*
		dodoc ../docs/*.pdf
	fi

	# install examples
	if use examples ; then
		einfo "install examples"
		insinto /usr/share/doc/${PF}/examples

		if use smbclient ; then
			doins -r ../examples/libsmbclient
		fi

		if use winbind ; then
			doins -r ../examples/pam_winbind ../examples/nss
		fi

		if use server ; then
			doins -r \
				auth autofs dce-dfs LDAP logon misc pdb perfcounter \
				printer-accounting printing scripts tridge validchars VFS
		fi
	fi

	# Remove empty installation directories
	rmdir --ignore-fail-on-non-empty \
		"${D}/usr/$(get_libdir)/samba" \
		"${D}/usr"/{sbin,bin} \
		"${D}/usr/share"/{man,locale,} \
		"${D}/var"/{run,lib/samba/private,lib/samba,lib,cache/samba,cache,} \
	#	|| die "tried to remove non-empty dirs, this seems like a bug in the ebuild"
}






^ permalink raw reply	[flat|nested] 4+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-fs/samba: samba-3.5.3.ebuild ChangeLog
@ 2010-05-21 17:31 Victor Ostorga (vostorga)
  0 siblings, 0 replies; 4+ messages in thread
From: Victor Ostorga (vostorga) @ 2010-05-21 17:31 UTC (permalink / raw
  To: gentoo-commits

vostorga    10/05/21 17:31:08

  Modified:             samba-3.5.3.ebuild ChangeLog
  Log:
  Fixing build with USE=ads
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.3                  net-fs/samba/samba-3.5.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild?r1=1.2&r2=1.3

Index: samba-3.5.3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- samba-3.5.3.ebuild	19 May 2010 17:16:15 -0000	1.2
+++ samba-3.5.3.ebuild	21 May 2010 17:31:08 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild,v 1.2 2010/05/19 17:16:15 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild,v 1.3 2010/05/21 17:31:08 vostorga Exp $
 
 EAPI="2"
 
@@ -49,6 +49,8 @@
 
 SBINPROGS=""
 BINPROGS=""
+KRBPLUGIN=""
+PLUGINEXT=".so"
 
 if use server ; then
 	SBINPROGS="${SBINPROGS} bin/smbd bin/nmbd"
@@ -57,7 +59,7 @@
 
 	use swat && SBINPROGS="${SBINPROGS} bin/swat"
 	use winbind && SBINPROGS="${SBINPROGS} bin/winbindd"
-	use ads && use winbind && SBINPROGS="${SBINPROGS} bin/winbind_krb5_locator"
+	use ads && use winbind && KRBPLUGIN="${KRBPLUGIN} bin/winbind_krb5_locator"
 fi
 
 if use client ; then
@@ -214,6 +216,11 @@
 		emake ${SBINPROGS} || die "emake sbinprogs failed";
 	fi
 
+	if [ -n "${KRBPLUGIN}" ] ; then
+		einfo "make krbplugin"
+		emake ${KRBPLUGIN}${PLUGINEXT} || die "emake krbplugin failed";
+	fi
+
 	if use client ; then
 		einfo "make {,u}mount.cifs"
 		emake bin/{,u}mount.cifs || die "emake {,u}mount.cifs failed"
@@ -277,6 +284,21 @@
 		doman ../docs/manpages/${prog/bin\/}* || die "doman failed"
 	done
 
+	# install krbplugin
+	if has_version app-crypt/mit-krb5 ; then
+		insinto /usr/$(get_libdir)/krb5/plugins/libkrb5
+		doins ${KRBPLUGIN}${PLUGINEXT} || die "installing
+		${KRBPLUGIN}${PLUGINEXT} failed"
+	elif has_version app-crypt/heimdal ; then
+		insinto /usr/$(get_libdir)/plugin/krb5
+		doins ${KRBPLUGIN}${PLUGINEXT} || die "installing
+		${KRBPLUGIN}${PLUGINEXT} failed"
+	fi
+	insinto /usr
+	for prog in ${KRBPLUGIN} ; do
+		doman ../docs/manpages/${prog/bin\/}* || die "doman failed"
+	done
+
 	# install server components
 	if use server ; then
 		doman ../docs/manpages/vfs* ../docs/manpages/samba.7



1.418                net-fs/samba/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?rev=1.418&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?rev=1.418&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?r1=1.417&r2=1.418

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v
retrieving revision 1.417
retrieving revision 1.418
diff -u -r1.417 -r1.418
--- ChangeLog	20 May 2010 00:04:21 -0000	1.417
+++ ChangeLog	21 May 2010 17:31:08 -0000	1.418
@@ -1,6 +1,10 @@
 # ChangeLog for net-fs/samba
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v 1.417 2010/05/20 00:04:21 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v 1.418 2010/05/21 17:31:08 vostorga Exp $
+
+  21 May 2010; Víctor Ostorga <vostorga@gentoo.org> samba-3.5.3.ebuild:
+  Fixing build with USE=ads winbind, patch thanks to Rainer Ruecker
+  <rainer@emdete.de> bugs #314709 #315975
 
   20 May 2010; Jeroen Roovers <jer@gentoo.org> samba-3.4.6.ebuild:
   Stable for HPPA (bug #300158).






^ permalink raw reply	[flat|nested] 4+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-fs/samba: samba-3.5.3.ebuild ChangeLog
@ 2010-05-24 21:56 Victor Ostorga (vostorga)
  0 siblings, 0 replies; 4+ messages in thread
From: Victor Ostorga (vostorga) @ 2010-05-24 21:56 UTC (permalink / raw
  To: gentoo-commits

vostorga    10/05/24 21:56:45

  Modified:             samba-3.5.3.ebuild ChangeLog
  Log:
  Fixing krbplugin install, and server examples location, bug #320953 , patch thanks to Honza Macháček <Hloupy.Honza@centrum.cz>
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.4                  net-fs/samba/samba-3.5.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild?r1=1.3&r2=1.4

Index: samba-3.5.3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- samba-3.5.3.ebuild	21 May 2010 17:31:08 -0000	1.3
+++ samba-3.5.3.ebuild	24 May 2010 21:56:45 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild,v 1.3 2010/05/21 17:31:08 vostorga Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild,v 1.4 2010/05/24 21:56:45 vostorga Exp $
 
 EAPI="2"
 
@@ -285,19 +285,21 @@
 	done
 
 	# install krbplugin
-	if has_version app-crypt/mit-krb5 ; then
-		insinto /usr/$(get_libdir)/krb5/plugins/libkrb5
-		doins ${KRBPLUGIN}${PLUGINEXT} || die "installing
-		${KRBPLUGIN}${PLUGINEXT} failed"
-	elif has_version app-crypt/heimdal ; then
-		insinto /usr/$(get_libdir)/plugin/krb5
-		doins ${KRBPLUGIN}${PLUGINEXT} || die "installing
-		${KRBPLUGIN}${PLUGINEXT} failed"
+	if [ -n "${KRBPLUGIN}" ] ; then
+		if has_version app-crypt/mit-krb5 ; then
+			insinto /usr/$(get_libdir)/krb5/plugins/libkrb5
+			doins ${KRBPLUGIN}${PLUGINEXT} || die "installing
+			${KRBPLUGIN}${PLUGINEXT} failed"
+		elif has_version app-crypt/heimdal ; then
+			insinto /usr/$(get_libdir)/plugin/krb5
+			doins ${KRBPLUGIN}${PLUGINEXT} || die "installing
+			${KRBPLUGIN}${PLUGINEXT} failed"
+		fi
+		insinto /usr
+		for prog in ${KRBPLUGIN} ; do
+			doman ../docs/manpages/${prog/bin\/}* || die "doman failed"
+		done
 	fi
-	insinto /usr
-	for prog in ${KRBPLUGIN} ; do
-		doman ../docs/manpages/${prog/bin\/}* || die "doman failed"
-	done
 
 	# install server components
 	if use server ; then
@@ -344,7 +346,9 @@
 	fi
 
 	# install the spooler to cups
-	use cups && dosym /usr/bin/smbspool $(cups-config --serverbin)/backend/smb
+	if use cups ; then
+		dosym /usr/bin/smbspool $(cups-config --serverbin)/backend/smb
+	fi
 
 	# install misc files
 	insinto /etc/samba
@@ -362,7 +366,6 @@
 
 	# install examples
 	if use examples ; then
-		einfo "install examples"
 		insinto /usr/share/doc/${PF}/examples
 
 		if use smbclient ; then
@@ -374,9 +377,10 @@
 		fi
 
 		if use server ; then
-			doins -r \
-				auth autofs dce-dfs LDAP logon misc pdb perfcounter \
-				printer-accounting printing scripts tridge validchars VFS
+			cd ../examples
+			doins -r auth autofs dce-dfs LDAP logon misc pdb \
+			perfcounter printer-accounting printing scripts tridge \
+			validchars VFS
 		fi
 	fi
 



1.419                net-fs/samba/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?rev=1.419&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?rev=1.419&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?r1=1.418&r2=1.419

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v
retrieving revision 1.418
retrieving revision 1.419
diff -u -r1.418 -r1.419
--- ChangeLog	21 May 2010 17:31:08 -0000	1.418
+++ ChangeLog	24 May 2010 21:56:45 -0000	1.419
@@ -1,6 +1,10 @@
 # ChangeLog for net-fs/samba
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v 1.418 2010/05/21 17:31:08 vostorga Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v 1.419 2010/05/24 21:56:45 vostorga Exp $
+
+  24 May 2010; Víctor Ostorga <vostorga@gentoo.org> samba-3.5.3.ebuild:
+  Fixing krbplugin install, and server examples location, bug #320953 ,
+  patch thanks to Honza Macháček <Hloupy.Honza@centrum.cz> 
 
   21 May 2010; Víctor Ostorga <vostorga@gentoo.org> samba-3.5.3.ebuild:
   Fixing build with USE=ads winbind, patch thanks to Rainer Ruecker






^ permalink raw reply	[flat|nested] 4+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-fs/samba: samba-3.5.3.ebuild ChangeLog
@ 2010-06-02 16:03 Victor Ostorga (vostorga)
  0 siblings, 0 replies; 4+ messages in thread
From: Victor Ostorga (vostorga) @ 2010-06-02 16:03 UTC (permalink / raw
  To: gentoo-commits

vostorga    10/06/02 16:03:31

  Modified:             samba-3.5.3.ebuild ChangeLog
  Log:
  Adding support for winbind shared modules idmap_rid , idmap_ad and idmap_ldap bug #301968
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.6                  net-fs/samba/samba-3.5.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild?r1=1.5&r2=1.6

Index: samba-3.5.3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- samba-3.5.3.ebuild	1 Jun 2010 14:04:59 -0000	1.5
+++ samba-3.5.3.ebuild	2 Jun 2010 16:03:31 -0000	1.6
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild,v 1.5 2010/06/01 14:04:59 vostorga Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/samba-3.5.3.ebuild,v 1.6 2010/06/02 16:03:31 vostorga Exp $
 
 EAPI="2"
 
@@ -51,6 +51,7 @@
 BINPROGS=""
 KRBPLUGIN=""
 PLUGINEXT=".so"
+SHAREDMODS=""
 
 if use server ; then
 	SBINPROGS="${SBINPROGS} bin/smbd bin/nmbd"
@@ -72,7 +73,13 @@
 
 use cups && BINPROGS="${BINPROGS} bin/smbspool"
 use ldb && BINPROGS="${BINPROGS} bin/ldbedit bin/ldbsearch bin/ldbadd bin/ldbdel bin/ldbmodify bin/ldbrename";
-use winbind && BINPROGS="${BINPROGS} bin/wbinfo"
+
+if use winbind ; then
+	BINPROGS="${BINPROGS} bin/wbinfo"
+	SHAREDMODS="${SHAREDMODS}idmap_rid"
+	use ads && SHAREDMODS="${SHAREDMODS},idmap_ad"
+	use ldap && SHAREDMODS="${SHAREDMODS},idmap_ldap"
+fi
 
 S="${WORKDIR}/${MY_P}/source3"
 
@@ -178,6 +185,7 @@
 		$(use_with aio aio-support) \
 		--with-sendfile-support \
 		$(use_with winbind) \
+		--with-shared-modules=${SHAREDMODS} \
 		--without-included-popt \
 		--without-included-iniparser
 }



1.421                net-fs/samba/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?rev=1.421&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?rev=1.421&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/samba/ChangeLog?r1=1.420&r2=1.421

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v
retrieving revision 1.420
retrieving revision 1.421
diff -u -r1.420 -r1.421
--- ChangeLog	1 Jun 2010 14:04:59 -0000	1.420
+++ ChangeLog	2 Jun 2010 16:03:31 -0000	1.421
@@ -1,6 +1,10 @@
 # ChangeLog for net-fs/samba
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v 1.420 2010/06/01 14:04:59 vostorga Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/samba/ChangeLog,v 1.421 2010/06/02 16:03:31 vostorga Exp $
+
+  02 Jun 2010; Víctor Ostorga <vostorga@gentoo.org> samba-3.5.3.ebuild:
+  Adding support for winbind shared modules idmap_rid , idmap_ad and
+  idmap_ldap bug #301968
 
   01 Jun 2010; Víctor Ostorga <vostorga@gentoo.org> samba-3.4.6.ebuild,
   samba-3.4.8.ebuild, -samba-3.5.0.ebuild, -samba-3.5.2-r1.ebuild,






^ permalink raw reply	[flat|nested] 4+ messages in thread
end of thread, other threads:[~2010-06-02 16:03 UTC | newest]

Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-05-24 21:56 [gentoo-commits] gentoo-x86 commit in net-fs/samba: samba-3.5.3.ebuild ChangeLog Victor Ostorga (vostorga)
  -- strict thread matches above, loose matches on Subject: below --
2010-06-02 16:03 Victor Ostorga (vostorga)
2010-05-21 17:31 Victor Ostorga (vostorga)
2010-05-19 15:19 Patrick Lauer (patrick)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox