[gentoo-commits] gentoo-x86 commit in net-im/licq: ChangeLog licq-1.3.9.ebuild

[gentoo-commits] gentoo-x86 commit in net-im/licq: ChangeLog licq-1.3.9.ebuild

[Patrick Lauer (patrick)]

patrick     10/05/17 19:54:11

  Modified:             ChangeLog
  Added:                licq-1.3.9.ebuild
  Log:
  Bump for #320259
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.118                net-im/licq/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/licq/ChangeLog?rev=1.118&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/licq/ChangeLog?rev=1.118&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/licq/ChangeLog?r1=1.117&r2=1.118

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/licq/ChangeLog,v
retrieving revision 1.117
retrieving revision 1.118
diff -u -r1.117 -r1.118
--- ChangeLog	13 Jan 2010 20:26:52 -0000	1.117
+++ ChangeLog	17 May 2010 19:54:11 -0000	1.118
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/licq
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/licq/ChangeLog,v 1.117 2010/01/13 20:26:52 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/licq/ChangeLog,v 1.118 2010/05/17 19:54:11 patrick Exp $
+
+*licq-1.3.9 (17 May 2010)
+
+  17 May 2010; Patrick Lauer <patrick@gentoo.org> +licq-1.3.9.ebuild:
+  Bump for #320259
 
   13 Jan 2010; Raúl Porcel <armin76@gentoo.org> licq-1.3.8-r1.ebuild:
   alpha/ia64/sparc stable wrt #299749



1.1                  net-im/licq/licq-1.3.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/licq/licq-1.3.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/licq/licq-1.3.9.ebuild?rev=1.1&content-type=text/plain

Index: licq-1.3.9.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/licq/licq-1.3.9.ebuild,v 1.1 2010/05/17 19:54:11 patrick Exp $

EAPI=2
CMAKE_USE_DIR="${S}/plugins/qt4-gui"
inherit cmake-utils eutils

DESCRIPTION="ICQ Client with v8 support"
HOMEPAGE="http://www.licq.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
IUSE="debug linguas_he ncurses msn nls crypt socks5 ssl qt4 xosd"

RDEPEND="crypt? ( >=app-crypt/gpgme-1 )
	ncurses? ( sys-libs/ncurses
		dev-libs/cdk )
	ssl? ( >=dev-libs/openssl-0.9.5a )
	qt4? ( x11-libs/qt-gui:4 )
	xosd? ( x11-libs/xosd )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	dev-libs/boost"

pkg_setup() {
	licq_plugins="auto-reply email rms"
	use ncurses && licq_plugins="${licq_plugins} console"
	use msn && licq_plugins="${licq_plugins} msn"
	use xosd && licq_plugins="${licq_plugins} osd"
}

src_configure() {
	econf \
		$(use_enable linguas_he hebrew) \
		--disable-dependency-tracking \
		$(use_enable debug) \
		$(use_enable socks5) \
		$(use_enable ssl openssl) \
		$(use_enable nls)

	local x
	for x in ${licq_plugins}; do
		cd "${S}"/plugins/${x}
		econf
	done

	if use qt4; then
		# http://licq.org/ticket/1662
		mycmakeargs="${mycmakeargs}
			-DWITH_KDE=OFF"
		cmake-utils_src_configure
	fi
}

src_compile() {
	emake || die

	local x
	for x in ${licq_plugins}; do
		cd "${S}"/plugins/${x}
		emake || die
	done

	use qt4 && cmake-utils_src_compile
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc README

	docinto doc
	dodoc doc/*

	use crypt && dodoc README.GPG
	use ssl && dodoc README.OPENSSL

	exeinto /usr/share/${PN}/upgrade
	doexe upgrade/*.pl || die

	local x
	for x in ${licq_plugins}; do
		cd "${S}"/plugins/${x}
		emake DESTDIR="${D}" install || die
		docinto ${x}
		dodoc README* *.conf
	done

	if use qt4; then
		docinto qt4
		DOCS="README" cmake-utils_src_install
	fi

	rm -rf "${D}"/var
}