public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-ose: ChangeLog virtualbox-ose-3.1.8.ebuild
@ 2010-05-10 13:20 Lars Wendler (polynomial-c)
  0 siblings, 0 replies; 7+ messages in thread
From: Lars Wendler (polynomial-c) @ 2010-05-10 13:20 UTC (permalink / raw
  To: gentoo-commits

polynomial-c    10/05/10 13:20:23

  Modified:             ChangeLog
  Added:                virtualbox-ose-3.1.8.ebuild
  Log:
  version bump
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.50                 app-emulation/virtualbox-ose/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	28 Mar 2010 13:44:08 -0000	1.49
+++ ChangeLog	10 May 2010 13:20:23 -0000	1.50
@@ -1,6 +1,12 @@
 # ChangeLog for app-emulation/virtualbox-ose
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.49 2010/03/28 13:44:08 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.50 2010/05/10 13:20:23 polynomial-c Exp $
+
+*virtualbox-ose-3.1.8 (10 May 2010)
+
+  10 May 2010; Lars Wendler <polynomial-c@gentoo.org>
+  +virtualbox-ose-3.1.8.ebuild:
+  version bump
 
 *virtualbox-ose-3.1.6 (28 Mar 2010)
 



1.1                  app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.1&content-type=text/plain

Index: virtualbox-ose-3.1.8.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.1 2010/05/10 13:20:23 polynomial-c Exp $

EAPI=2

inherit eutils fdo-mime flag-o-matic linux-info pax-utils qt4 toolchain-funcs

if [[ ${PV} == "9999" ]] ; then
	# XXX: should finish merging the -9999 ebuild into this one ...
	ESVN_REPO_URI="http://www.virtualbox.org/svn/vbox/trunk"
	inherit linux-mod subversion
else
	MY_P=VirtualBox-${PV}-OSE
	SRC_URI="http://download.virtualbox.org/virtualbox/${PV}/${MY_P}.tar.bz2"
	S=${WORKDIR}/${MY_P/-OSE/_OSE}
fi

DESCRIPTION="Software family of powerful x86 virtualization"
HOMEPAGE="http://www.virtualbox.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+additions alsa +hal headless pulseaudio +opengl python +qt4 sdk vboxwebsrv"

RDEPEND="!app-emulation/virtualbox-bin
	~app-emulation/virtualbox-modules-${PV}
	dev-libs/libIDL
	>=dev-libs/libxslt-1.1.19
	net-misc/curl
	!headless? (
		qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 opengl?	( x11-libs/qt-opengl:4 ) )
		opengl? ( virtual/opengl virtual/glut )
		x11-libs/libXcursor
		media-libs/libsdl[X,video]
		x11-libs/libXt
	)"
DEPEND="${RDEPEND}
	>=dev-util/kbuild-0.1.5-r1
	>=dev-lang/yasm-0.6.2
	sys-devel/bin86
	sys-devel/dev86
	sys-power/iasl
	media-libs/libpng
	sys-libs/libcap
	dev-util/pkgconfig
	alsa? ( >=media-libs/alsa-lib-1.0.13 )
	hal? ( sys-apps/hal )
	pulseaudio? ( media-sound/pulseaudio )
	python? ( >=dev-lang/python-2.3 )
	vboxwebsrv? ( >=net-libs/gsoap-2.7.13 )"
RDEPEND="${RDEPEND}
	additions? ( ~app-emulation/virtualbox-ose-additions-${PV} )"

QA_TEXTRELS_x86="usr/lib/virtualbox-ose/VBoxGuestPropSvc.so
	usr/lib/virtualbox-ose/VBoxSDL.so
	usr/lib/virtualbox-ose/VBoxSharedFolders.so
	usr/lib/virtualbox-ose/VBoxDD2.so
	usr/lib/virtualbox-ose/VBoxOGLrenderspu.so
	usr/lib/virtualbox-ose/VBoxPython.so
	usr/lib/virtualbox-ose/VBoxDD.so
	usr/lib/virtualbox-ose/VBoxDDU.so
	usr/lib/virtualbox-ose/VBoxREM64.so
	usr/lib/virtualbox-ose/VBoxSharedClipboard.so
	usr/lib/virtualbox-ose/VBoxHeadless.so
	usr/lib/virtualbox-ose/VBoxRT.so
	usr/lib/virtualbox-ose/VBoxREM.so
	usr/lib/virtualbox-ose/VBoxSettings.so
	usr/lib/virtualbox-ose/VBoxKeyboard.so
	usr/lib/virtualbox-ose/VBoxSharedCrOpenGL.so
	usr/lib/virtualbox-ose/VBoxVMM.so
	usr/lib/virtualbox-ose/VirtualBox.so
	usr/lib/virtualbox-ose/VBoxOGLhosterrorspu.so
	usr/lib/virtualbox-ose/components/VBoxC.so
	usr/lib/virtualbox-ose/components/VBoxSVCM.so
	usr/lib/virtualbox-ose/components/VBoxDDU.so
	usr/lib/virtualbox-ose/components/VBoxRT.so
	usr/lib/virtualbox-ose/components/VBoxREM.so
	usr/lib/virtualbox-ose/components/VBoxVMM.so
	usr/lib/virtualbox-ose/VBoxREM32.so
	usr/lib/virtualbox-ose/VBoxPython2_4.so
	usr/lib/virtualbox-ose/VBoxPython2_5.so
	usr/lib/virtualbox-ose/VBoxPython2_6.so
	usr/lib/virtualbox-ose/VBoxXPCOMC.so
	usr/lib/virtualbox-ose/VBoxOGLhostcrutil.so
	usr/lib/virtualbox-ose/VBoxNetDHCP.so"

pkg_setup() {
	if ! use headless && ! use qt4 ; then
		einfo "No USE=\"qt4\" selected, this build will not include"
		einfo "any Qt frontend."
	elif use headless && use qt4 ; then
		einfo "You selected USE=\"headless qt4\", defaulting to"
		einfo "USE=\"headless\", this build will not include any X11/Qt frontend."
	fi

	if ! use opengl ; then
		einfo "No USE=\"opengl\" selected, this build will lack"
		einfo "the OpenGL feature."
	fi
}

src_prepare() {
	# Remove shipped binaries (kBuild,yasm), see bug #232775
	rm -rf kBuild/bin tools

	# Disable things unused or split into separate ebuilds
	sed -e "s/MY_LIBDIR/$(get_libdir)/" \
		"${FILESDIR}"/${PN}-3-localconfig > LocalConfig.kmk || die

	# unset useless/problematic mesa checks in configure
	epatch "${FILESDIR}/${PN}-3.0.0-mesa-check.patch"
}

src_configure() {
	local myconf
	use alsa       || myconf="${myconf} --disable-alsa"
	use opengl     || myconf="${myconf} --disable-opengl"
	use pulseaudio || myconf="${myconf} --disable-pulse"
	use python     || myconf="${myconf} --disable-python"
	use hal        || myconf="${myconf} --disable-dbus"
	use vboxwebsrv && myconf="${myconf} --enable-webservice"
	if ! use headless ; then
		use qt4 || myconf="${myconf} --disable-qt4"
	else
		myconf="${myconf} --build-headless --disable-opengl"
	fi
	# not an autoconf script
	./configure \
		--with-gcc="$(tc-getCC)" \
		--with-g++="$(tc-getCXX)" \
		--disable-kmods \
		${myconf} \
		|| die "configure failed"
}

src_compile() {
	source ./env.sh

	# Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
	# and strip all flags
	strip-flags

	MAKE="kmk" emake \
		TOOL_GCC3_CC="$(tc-getCC)" TOOL_GCC3_CXX="$(tc-getCXX)" \
		TOOL_GCC3_AS="$(tc-getCC)" TOOL_GCC3_AR="$(tc-getAR)" \
		TOOL_GCC3_LD="$(tc-getCXX)" TOOL_GCC3_LD_SYSMOD="$(tc-getLD)" \
		TOOL_GCC3_CFLAGS="${CFLAGS}" TOOL_GCC3_CXXFLAGS="${CXXFLAGS}" \
		TOOL_YASM_AS=yasm KBUILD_PATH="${S}/kBuild" \
		all || die "kmk failed"
}

src_install() {
	cd "${S}"/out/linux.*/release/bin || die

	# Create configuration files
	insinto /etc/vbox
	newins "${FILESDIR}/${PN}-3-config" vbox.cfg

	# Set the right libdir
	sed -i \
		-e "s/MY_LIBDIR/$(get_libdir)/" \
		"${D}"/etc/vbox/vbox.cfg || die "vbox.cfg sed failed"

	# Symlink binaries to the shipped wrapper
	exeinto /usr/$(get_libdir)/${PN}
	newexe "${FILESDIR}/${PN}-3-wrapper" "VBox" || die
	fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBox
	fperms 0750 /usr/$(get_libdir)/${PN}/VBox

	dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxManage
	dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxVRDP
	dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxHeadless
	dosym /usr/$(get_libdir)/${PN}/VBoxTunctl /usr/bin/VBoxTunctl

	# Install binaries and libraries
	insinto /usr/$(get_libdir)/${PN}
	doins -r components || die

	if use sdk ; then
		doins -r sdk || die
	fi

	if use vboxwebsrv ; then
		doins vboxwebsrv || die
		fowners root:vboxusers /usr/$(get_libdir)/${PN}/vboxwebsrv
		fperms 0750 /usr/$(get_libdir)/${PN}/vboxwebsrv
		dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/vboxwebsrv
		newinitd "${FILESDIR}"/vboxwebsrv-initd vboxwebsrv
		newconfd "${FILESDIR}"/vboxwebsrv-confd vboxwebsrv
	fi

	for each in VBox{Manage,SVC,XPCOMIPCD,Tunctl,NetAdpCtl,NetDHCP} *so *r0 *gc ; do
		doins $each || die
		fowners root:vboxusers /usr/$(get_libdir)/${PN}/${each}
		fperms 0750 /usr/$(get_libdir)/${PN}/${each}
	done
	# VBoxNetAdpCtl binary needs to be suid root in any case..
	fperms 4750 /usr/$(get_libdir)/${PN}/VBoxNetAdpCtl

	if ! use headless ; then
		for each in VBox{SDL,Headless} ; do
			doins $each || die
			fowners root:vboxusers /usr/$(get_libdir)/${PN}/${each}
			fperms 4750 /usr/$(get_libdir)/${PN}/${each}
			pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/${each}
		done

		if use opengl ; then
			doins VBoxTestOGL || die
			fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBoxTestOGL
			fperms 0750 /usr/$(get_libdir)/${PN}/VBoxTestOGL
		fi

		dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxSDL

		if use qt4 ; then
			doins VirtualBox || die
			fowners root:vboxusers /usr/$(get_libdir)/${PN}/VirtualBox
			fperms 4750 /usr/$(get_libdir)/${PN}/VirtualBox
			pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/VirtualBox

			dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VirtualBox
		fi

		newicon	"${S}"/src/VBox/Frontends/VirtualBox/images/OSE/VirtualBox_32px.png ${PN}.png
		domenu "${FILESDIR}"/${PN}.desktop
	else
		doins VBoxHeadless || die
		fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBoxHeadless
		fperms 4750 /usr/$(get_libdir)/${PN}/VBoxHeadless
		pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/VBoxHeadless
	fi

	insinto /usr/share/${PN}
	if ! use headless && use qt4 ; then
		doins -r nls
	fi

	# set an env-variable for 3rd party tools
	echo -n "VBOX_APP_HOME=/usr/$(get_libdir)/${PN}" > "${T}/90virtualbox"
	doenvd "${T}/90virtualbox"
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	if ! use headless && use qt4 ; then
		elog "To launch VirtualBox just type: \"VirtualBox\""
	fi
	elog "You must be in the vboxusers group to use VirtualBox."
	elog ""
	elog "The latest user manual is available for download at:"
	elog "http://download.virtualbox.org/virtualbox/${PV}/UserManual.pdf"
	elog ""
	elog "For advanced networking setups you should emerge:"
	elog "net-misc/bridge-utils and sys-apps/usermode-utilities"
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}






^ permalink raw reply	[flat|nested] 7+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-ose: ChangeLog virtualbox-ose-3.1.8.ebuild
@ 2010-05-11 15:47 Lars Wendler (polynomial-c)
  0 siblings, 0 replies; 7+ messages in thread
From: Lars Wendler (polynomial-c) @ 2010-05-11 15:47 UTC (permalink / raw
  To: gentoo-commits

polynomial-c    10/05/11 15:47:16

  Modified:             ChangeLog virtualbox-ose-3.1.8.ebuild
  Log:
  Added patch to fix compilation with latest iasl release.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.51                 app-emulation/virtualbox-ose/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.51&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.51&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?r1=1.50&r2=1.51

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v
retrieving revision 1.50
retrieving revision 1.51
diff -u -r1.50 -r1.51
--- ChangeLog	10 May 2010 13:20:23 -0000	1.50
+++ ChangeLog	11 May 2010 15:47:16 -0000	1.51
@@ -1,6 +1,12 @@
 # ChangeLog for app-emulation/virtualbox-ose
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.50 2010/05/10 13:20:23 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.51 2010/05/11 15:47:16 polynomial-c Exp $
+
+  11 May 2010; Lars Wendler <polynomial-c@gentoo.org>
+  virtualbox-ose-3.1.8.ebuild,
+  +files/virtualbox-ose-3.1.8-iasl-length-calculation-fix.patch:
+  Added patch to fix compilation with latest iasl release reported by
+  Ladislav Laska and others.
 
 *virtualbox-ose-3.1.8 (10 May 2010)
 



1.2                  app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?r1=1.1&r2=1.2

Index: virtualbox-ose-3.1.8.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- virtualbox-ose-3.1.8.ebuild	10 May 2010 13:20:23 -0000	1.1
+++ virtualbox-ose-3.1.8.ebuild	11 May 2010 15:47:16 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.1 2010/05/10 13:20:23 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.2 2010/05/11 15:47:16 polynomial-c Exp $
 
 EAPI=2
 
@@ -111,6 +111,9 @@
 
 	# unset useless/problematic mesa checks in configure
 	epatch "${FILESDIR}/${PN}-3.0.0-mesa-check.patch"
+
+	# fix with newer iasl (bug #319127)
+	epatch "${FILESDIR}/${P}-iasl-length-calculation-fix.patch"
 }
 
 src_configure() {






^ permalink raw reply	[flat|nested] 7+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-ose: ChangeLog virtualbox-ose-3.1.8.ebuild
@ 2010-06-08 19:22 Lars Wendler (polynomial-c)
  0 siblings, 0 replies; 7+ messages in thread
From: Lars Wendler (polynomial-c) @ 2010-06-08 19:22 UTC (permalink / raw
  To: gentoo-commits

polynomial-c    10/06/08 19:22:27

  Modified:             ChangeLog virtualbox-ose-3.1.8.ebuild
  Log:
  Forgot to add fix for bug #322783 to version 3.1.8
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.62                 app-emulation/virtualbox-ose/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.62&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.62&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?r1=1.61&r2=1.62

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v
retrieving revision 1.61
retrieving revision 1.62
diff -u -r1.61 -r1.62
--- ChangeLog	8 Jun 2010 19:01:03 -0000	1.61
+++ ChangeLog	8 Jun 2010 19:22:27 -0000	1.62
@@ -1,6 +1,10 @@
 # ChangeLog for app-emulation/virtualbox-ose
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.61 2010/06/08 19:01:03 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.62 2010/06/08 19:22:27 polynomial-c Exp $
+
+  08 Jun 2010; Lars Wendler <polynomial-c@gentoo.org>
+  virtualbox-ose-3.1.8.ebuild:
+  Forgot to add fix for bug #322783 to version 3.1.8
 
 *virtualbox-ose-3.2.4-r1 (08 Jun 2010)
 



1.3                  app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?r1=1.2&r2=1.3

Index: virtualbox-ose-3.1.8.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- virtualbox-ose-3.1.8.ebuild	11 May 2010 15:47:16 -0000	1.2
+++ virtualbox-ose-3.1.8.ebuild	8 Jun 2010 19:22:27 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.2 2010/05/11 15:47:16 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.3 2010/06/08 19:22:27 polynomial-c Exp $
 
 EAPI=2
 
@@ -35,7 +35,8 @@
 		x11-libs/libXcursor
 		media-libs/libsdl[X,video]
 		x11-libs/libXt
-	)"
+	)
+	headless? ( x11-libs/libX11 )"
 DEPEND="${RDEPEND}
 	>=dev-util/kbuild-0.1.5-r1
 	>=dev-lang/yasm-0.6.2






^ permalink raw reply	[flat|nested] 7+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-ose: ChangeLog virtualbox-ose-3.1.8.ebuild
@ 2010-06-21 13:45 Christoph Mende (angelos)
  0 siblings, 0 replies; 7+ messages in thread
From: Christoph Mende (angelos) @ 2010-06-21 13:45 UTC (permalink / raw
  To: gentoo-commits

angelos     10/06/21 13:45:47

  Modified:             ChangeLog virtualbox-ose-3.1.8.ebuild
  Log:
  Stable on amd64 wrt bug #320595
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.63                 app-emulation/virtualbox-ose/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.63&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.63&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?r1=1.62&r2=1.63

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v
retrieving revision 1.62
retrieving revision 1.63
diff -u -r1.62 -r1.63
--- ChangeLog	8 Jun 2010 19:22:27 -0000	1.62
+++ ChangeLog	21 Jun 2010 13:45:47 -0000	1.63
@@ -1,6 +1,10 @@
 # ChangeLog for app-emulation/virtualbox-ose
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.62 2010/06/08 19:22:27 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.63 2010/06/21 13:45:47 angelos Exp $
+
+  21 Jun 2010; Christoph Mende <angelos@gentoo.org>
+  virtualbox-ose-3.1.8.ebuild:
+  Stable on amd64 wrt bug #320595
 
   08 Jun 2010; Lars Wendler <polynomial-c@gentoo.org>
   virtualbox-ose-3.1.8.ebuild:



1.4                  app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?r1=1.3&r2=1.4

Index: virtualbox-ose-3.1.8.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- virtualbox-ose-3.1.8.ebuild	8 Jun 2010 19:22:27 -0000	1.3
+++ virtualbox-ose-3.1.8.ebuild	21 Jun 2010 13:45:47 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.3 2010/06/08 19:22:27 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.4 2010/06/21 13:45:47 angelos Exp $
 
 EAPI=2
 
@@ -21,7 +21,7 @@
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 ~x86"
 IUSE="+additions alsa +hal headless pulseaudio +opengl python +qt4 sdk vboxwebsrv"
 
 RDEPEND="!app-emulation/virtualbox-bin






^ permalink raw reply	[flat|nested] 7+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-ose: ChangeLog virtualbox-ose-3.1.8.ebuild
@ 2010-07-10 21:51 Lars Wendler (polynomial-c)
  0 siblings, 0 replies; 7+ messages in thread
From: Lars Wendler (polynomial-c) @ 2010-07-10 21:51 UTC (permalink / raw
  To: gentoo-commits

polynomial-c    10/07/10 21:51:11

  Modified:             ChangeLog virtualbox-ose-3.1.8.ebuild
  Log:
  Removed opengl USE flag (see bug #325117).
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.66                 app-emulation/virtualbox-ose/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.66&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.66&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?r1=1.65&r2=1.66

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v
retrieving revision 1.65
retrieving revision 1.66
diff -u -r1.65 -r1.66
--- ChangeLog	27 Jun 2010 16:23:27 -0000	1.65
+++ ChangeLog	10 Jul 2010 21:51:11 -0000	1.66
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/virtualbox-ose
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.65 2010/06/27 16:23:27 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.66 2010/07/10 21:51:11 polynomial-c Exp $
+
+  10 Jul 2010; Lars Wendler <polynomial-c@gentoo.org>
+  virtualbox-ose-3.1.8.ebuild:
+  Removed opengl USE flag as build system is b0rked. Thanks to Ronald for
+  reporting this in bug #325117.
 
   27 Jun 2010; Kacper Kowalik <xarthisius@gentoo.org>
   virtualbox-ose-3.2.6.ebuild, +files/virtualbox-ose-asneeded.patch:



1.5                  app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?r1=1.4&r2=1.5

Index: virtualbox-ose-3.1.8.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- virtualbox-ose-3.1.8.ebuild	21 Jun 2010 13:45:47 -0000	1.4
+++ virtualbox-ose-3.1.8.ebuild	10 Jul 2010 21:51:11 -0000	1.5
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.4 2010/06/21 13:45:47 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.5 2010/07/10 21:51:11 polynomial-c Exp $
 
 EAPI=2
 
@@ -22,7 +22,7 @@
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="amd64 ~x86"
-IUSE="+additions alsa +hal headless pulseaudio +opengl python +qt4 sdk vboxwebsrv"
+IUSE="+additions alsa +hal headless pulseaudio python +qt4 sdk vboxwebsrv"
 
 RDEPEND="!app-emulation/virtualbox-bin
 	~app-emulation/virtualbox-modules-${PV}
@@ -31,7 +31,8 @@
 	net-misc/curl
 	!headless? (
 		qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 opengl?	( x11-libs/qt-opengl:4 ) )
-		opengl? ( virtual/opengl virtual/glut )
+		virtual/opengl
+		virtual/glut
 		x11-libs/libXcursor
 		media-libs/libsdl[X,video]
 		x11-libs/libXt
@@ -120,7 +121,6 @@
 src_configure() {
 	local myconf
 	use alsa       || myconf="${myconf} --disable-alsa"
-	use opengl     || myconf="${myconf} --disable-opengl"
 	use pulseaudio || myconf="${myconf} --disable-pulse"
 	use python     || myconf="${myconf} --disable-python"
 	use hal        || myconf="${myconf} --disable-dbus"






^ permalink raw reply	[flat|nested] 7+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-ose: ChangeLog virtualbox-ose-3.1.8.ebuild
@ 2010-07-14 13:07 Christian Faulhammer (fauli)
  0 siblings, 0 replies; 7+ messages in thread
From: Christian Faulhammer (fauli) @ 2010-07-14 13:07 UTC (permalink / raw
  To: gentoo-commits

fauli       10/07/14 13:07:55

  Modified:             ChangeLog virtualbox-ose-3.1.8.ebuild
  Log:
  stable x86, bug 320595
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.67                 app-emulation/virtualbox-ose/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.67&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.67&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?r1=1.66&r2=1.67

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v
retrieving revision 1.66
retrieving revision 1.67
diff -u -r1.66 -r1.67
--- ChangeLog	10 Jul 2010 21:51:11 -0000	1.66
+++ ChangeLog	14 Jul 2010 13:07:54 -0000	1.67
@@ -1,6 +1,10 @@
 # ChangeLog for app-emulation/virtualbox-ose
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.66 2010/07/10 21:51:11 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.67 2010/07/14 13:07:54 fauli Exp $
+
+  14 Jul 2010; Christian Faulhammer <fauli@gentoo.org>
+  virtualbox-ose-3.1.8.ebuild:
+  stable x86, bug 320595
 
   10 Jul 2010; Lars Wendler <polynomial-c@gentoo.org>
   virtualbox-ose-3.1.8.ebuild:



1.7                  app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?r1=1.6&r2=1.7

Index: virtualbox-ose-3.1.8.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- virtualbox-ose-3.1.8.ebuild	11 Jul 2010 08:15:13 -0000	1.6
+++ virtualbox-ose-3.1.8.ebuild	14 Jul 2010 13:07:54 -0000	1.7
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.6 2010/07/11 08:15:13 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.7 2010/07/14 13:07:54 fauli Exp $
 
 EAPI=2
 
@@ -21,7 +21,7 @@
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="amd64 ~x86"
+KEYWORDS="amd64 x86"
 IUSE="+additions alsa +hal headless pulseaudio python +qt4 sdk vboxwebsrv"
 
 RDEPEND="!app-emulation/virtualbox-bin






^ permalink raw reply	[flat|nested] 7+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-ose: ChangeLog virtualbox-ose-3.1.8.ebuild
@ 2010-08-04  8:40 Lars Wendler (polynomial-c)
  0 siblings, 0 replies; 7+ messages in thread
From: Lars Wendler (polynomial-c) @ 2010-08-04  8:40 UTC (permalink / raw
  To: gentoo-commits

polynomial-c    10/08/04 08:40:06

  Modified:             ChangeLog virtualbox-ose-3.1.8.ebuild
  Log:
  VBoxTestOGL is only available with USE="qt4" (bug #330379).
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.70                 app-emulation/virtualbox-ose/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.70&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.70&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?r1=1.69&r2=1.70

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v
retrieving revision 1.69
retrieving revision 1.70
diff -u -r1.69 -r1.70
--- ChangeLog	1 Aug 2010 10:37:35 -0000	1.69
+++ ChangeLog	4 Aug 2010 08:40:06 -0000	1.70
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/virtualbox-ose
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.69 2010/08/01 10:37:35 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.70 2010/08/04 08:40:06 polynomial-c Exp $
+
+  04 Aug 2010; Lars Wendler <polynomial-c@gentoo.org>
+  virtualbox-ose-3.1.8.ebuild:
+  VBoxTestOGL is only available with USE="qt4". Thanks to Christoph
+  Safferling for reporting this issue in bug #330379.
 
   01 Aug 2010; Lars Wendler <polynomial-c@gentoo.org>
   virtualbox-ose-3.1.8.ebuild, virtualbox-ose-3.2.4-r1.ebuild,



1.10                 app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild?r1=1.9&r2=1.10

Index: virtualbox-ose-3.1.8.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- virtualbox-ose-3.1.8.ebuild	1 Aug 2010 10:37:35 -0000	1.9
+++ virtualbox-ose-3.1.8.ebuild	4 Aug 2010 08:40:06 -0000	1.10
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.9 2010/08/01 10:37:35 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.1.8.ebuild,v 1.10 2010/08/04 08:40:06 polynomial-c Exp $
 
 EAPI=2
 
@@ -206,10 +206,6 @@
 			pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/${each}
 		done
 
-		doins VBoxTestOGL || die
-		fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBoxTestOGL
-		fperms 0750 /usr/$(get_libdir)/${PN}/VBoxTestOGL
-
 		dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxSDL
 
 		if use qt4 ; then
@@ -218,6 +214,10 @@
 			fperms 4750 /usr/$(get_libdir)/${PN}/VirtualBox
 			pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/VirtualBox
 
+			doins VBoxTestOGL || die
+			fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBoxTestOGL
+			fperms 0750 /usr/$(get_libdir)/${PN}/VBoxTestOGL
+
 			dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VirtualBox
 		fi
 






^ permalink raw reply	[flat|nested] 7+ messages in thread
end of thread, other threads:[~2010-08-04  9:03 UTC | newest]

Thread overview: 7+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-05-11 15:47 [gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-ose: ChangeLog virtualbox-ose-3.1.8.ebuild Lars Wendler (polynomial-c)
  -- strict thread matches above, loose matches on Subject: below --
2010-08-04  8:40 Lars Wendler (polynomial-c)
2010-07-14 13:07 Christian Faulhammer (fauli)
2010-07-10 21:51 Lars Wendler (polynomial-c)
2010-06-21 13:45 Christoph Mende (angelos)
2010-06-08 19:22 Lars Wendler (polynomial-c)
2010-05-10 13:20 Lars Wendler (polynomial-c)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox