[gentoo-commits] gentoo-x86 commit in app-portage/portato: ChangeLog portato-0.13.1-r1.ebuild portato-0.13.1.ebuild

[gentoo-commits] gentoo-x86 commit in app-portage/portato: ChangeLog portato-0.13.1-r1.ebuild portato-0.13.1.ebuild

[Christian Ruppert (idl0r)]

idl0r       10/04/13 14:02:48

  Modified:             ChangeLog
  Added:                portato-0.13.1-r1.ebuild
  Removed:              portato-0.13.1.ebuild
  Log:
  Improve python handling, bug 311789.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.25                 app-portage/portato/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/portato/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/portato/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/portato/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/portato/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	10 Apr 2010 14:47:04 -0000	1.24
+++ ChangeLog	13 Apr 2010 14:02:48 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for app-portage/portato
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/portato/ChangeLog,v 1.24 2010/04/10 14:47:04 idl0r Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/portato/ChangeLog,v 1.25 2010/04/13 14:02:48 idl0r Exp $
+
+*portato-0.13.1-r1 (13 Apr 2010)
+
+  13 Apr 2010; Christian Ruppert <idl0r@gentoo.org> -portato-0.13.1.ebuild,
+  +portato-0.13.1-r1.ebuild:
+  Improve python handling, bug 311789.
 
   10 Apr 2010; Christian Ruppert <idl0r@gentoo.org> portato-0.13.1.ebuild:
   Apply patch by René 'Necoro' Neumann <gentoo@necoro.eu> to fix



1.1                  app-portage/portato/portato-0.13.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/portato/portato-0.13.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/portato/portato-0.13.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: portato-0.13.1-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/portato/portato-0.13.1-r1.ebuild,v 1.1 2010/04/13 14:02:48 idl0r Exp $

EAPI="2"

inherit python eutils distutils

DESCRIPTION="A GUI for Portage written in Python"
HOMEPAGE="http://necoro.eu/portato"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="kde +libnotify nls userpriv sqlite"
LANGS="ca de es_ES pl pt_BR tr"
for X in $LANGS; do IUSE="${IUSE} linguas_${X}"; done

COMMON_DEPEND="|| (
	dev-lang/python:2.7[sqlite?,threads]
	dev-lang/python:2.6[sqlite?,threads]
	dev-lang/python:2.5[sqlite?,threads] )"

RDEPEND="$COMMON_DEPEND
	app-portage/portage-utils
	x11-libs/vte[python]
	dev-python/pygtksourceview:2
	>=dev-python/pygtk-2.14.0
	dev-python/shm
	>=sys-apps/portage-2.1.6

	!userpriv? (
		kde? ( kde-base/kdesu )
		!kde? ( || ( x11-misc/ktsuss x11-libs/gksu ) )
	)

	libnotify? ( dev-python/notify-python )
	nls? ( virtual/libintl )"

DEPEND="$COMMON_DEPEND
	nls? ( sys-devel/gettext )"

CONFIG_DIR="etc/${PN}"
DATA_DIR="usr/share/${PN}"
LOCALE_DIR="usr/share/locale"
PLUGIN_DIR="${DATA_DIR}/plugins"
ICON_DIR="${DATA_DIR}/icons"
TEMPLATE_DIR="${DATA_DIR}/templates"

pkg_setup()
{
	python_set_active_version 2
}

src_configure ()
{
	sed -i 	-e "s;^\(VERSION\s*=\s*\).*;\1\"${PV}\";" \
			-e "s;^\(CONFIG_DIR\s*=\s*\).*;\1\"${ROOT}${CONFIG_DIR}/\";" \
			-e "s;^\(DATA_DIR\s*=\s*\).*;\1\"${ROOT}${DATA_DIR}/\";" \
			-e "s;^\(TEMPLATE_DIR\s*=\s*\).*;\1\"${ROOT}${TEMPLATE_DIR}/\";" \
			-e "s;^\(ICON_DIR\s*=\s*\).*;\1\"${ROOT}${ICON_DIR}/\";" \
			-e "s;^\(LOCALE_DIR\s*=\s*\).*;\1\"${ROOT}${LOCALE_DIR}/\";" \
			"${PN}"/constants.py || die "sed failed"

	if use userpriv; then
		sed -i -e "s/Exec=.*/Exec=portato --no-fork/" portato.desktop || die "sed failed"
	fi
}

src_compile ()
{
	if use nls; then
		./pocompile.sh -emerge ${LINGUAS} || die "pocompile failed"
	fi

	distutils_src_compile
}

src_install ()
{
	dodir ${DATA_DIR} || die

	distutils_src_install

	python_convert_shebangs 2 portato.py
	newbin portato.py portato || die
	dodoc doc/*

	# config
	insinto ${CONFIG_DIR}
	doins etc/* || die

	# plugins
	insinto ${PLUGIN_DIR}

	# desktop
	doicon icons/portato-icon.png || die
	domenu portato.desktop || die

	# nls
	if use nls && [ -d i18n/mo ]; then
		domo i18n/mo/*
	fi

	# man page
	doman portato.1
}

pkg_postinst ()
{
	distutils_pkg_postinst
	python_mod_optimize "/${PLUGIN_DIR}"
}

pkg_postrm ()
{
	distutils_pkg_postrm
	python_mod_cleanup "/${PLUGIN_DIR}"

	# try to remove the DATA_DIR, as it may still exist
	# reason: it was tried to remove it before plugin stuff was purged
	rmdir "${ROOT}"${DATA_DIR} 2> /dev/null
}