[gentoo-commits] gentoo-x86 commit in media-sound/lame: ChangeLog lame-3.98.4.ebuild

["Alexis Ballier (aballier)" <aballier@gentoo.org>]

aballier    10/04/12 07:02:16

  Modified:             ChangeLog
  Added:                lame-3.98.4.ebuild
  Log:
  version bump
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.120                media-sound/lame/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/lame/ChangeLog?rev=1.120&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/lame/ChangeLog?rev=1.120&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/lame/ChangeLog?r1=1.119&r2=1.120

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v
retrieving revision 1.119
retrieving revision 1.120
diff -u -r1.119 -r1.120
--- ChangeLog	3 Mar 2010 13:07:46 -0000	1.119
+++ ChangeLog	12 Apr 2010 07:02:16 -0000	1.120
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/lame
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v 1.119 2010/03/03 13:07:46 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v 1.120 2010/04/12 07:02:16 aballier Exp $
+
+*lame-3.98.4 (12 Apr 2010)
+
+  12 Apr 2010; Alexis Ballier <aballier@gentoo.org> +lame-3.98.4.ebuild:
+  version bump
 
 *lame-3.98.3 (03 Mar 2010)
 



1.1                  media-sound/lame/lame-3.98.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/lame/lame-3.98.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/lame/lame-3.98.4.ebuild?rev=1.1&content-type=text/plain

Index: lame-3.98.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/lame-3.98.4.ebuild,v 1.1 2010/04/12 07:02:16 aballier Exp $

inherit flag-o-matic toolchain-funcs eutils autotools versionator

DESCRIPTION="LAME Ain't an MP3 Encoder"
HOMEPAGE="http://lame.sourceforge.net"

SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug mmx mp3rtp sndfile"

RDEPEND=">=sys-libs/ncurses-5.2
	sndfile? ( >=media-libs/libsndfile-1.0.2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	mmx? ( dev-lang/nasm )"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# The frontened tries to link staticly, but we prefer shared libs
	epatch "${FILESDIR}"/${PN}-3.98-shared-frontend.patch

	# If ccc (alpha compiler) is installed on the system, the default
	# configure is broken, fix it to respect CC.  This is only
	# directly broken for ARCH=alpha but would affect anybody with a
	# ccc binary in their PATH.  Bug #41908  (26 Jul 2004 agriffis)
	epatch "${FILESDIR}"/${PN}-3.96-ccc.patch

	# Patch gtk stuff, otherwise eautoreconf dies
	epatch "${FILESDIR}"/${PN}-3.98-gtk-path.patch

	# Read and write from std* when sndfile is used
	epatch "${FILESDIR}"/${PN}-3.98.2-get_audio.patch

	# It fails parallel make otherwise when enabling nasm...
	mkdir "${S}/libmp3lame/i386/.libs" || die

	AT_M4DIR="${S}" eautoreconf
	epunt_cxx # embedded bug #74498
}

src_compile() {
	use sndfile && myconf="--with-fileio=sndfile"
	# The user sets compiler optimizations... But if you'd like
	# lame to choose it's own... uncomment one of these (experiMENTAL)
	# myconf="${myconf} --enable-expopt=full \
	# myconf="${myconf} --enable-expopt=norm \

	econf \
		--enable-shared \
		$(use_enable debug debug norm) \
		--disable-mp3x \
		$(use_enable mmx nasm) \
		$(use_enable mp3rtp) \
		${myconf} || die "econf failed"

	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" pkghtmldir="/usr/share/doc/${PF}/html" install || die

	dodoc API ChangeLog HACKING README* STYLEGUIDE TODO USAGE || die
	dohtml misc/lameGUI.html Dll/LameDLLInterface.htm || die

	dobin "${S}"/misc/mlame || die
}

pkg_postinst(){
	if use mp3rtp ; then
	    ewarn "Warning, support for the encode-to-RTP program, 'mp3rtp'"
	    ewarn "is broken as of August 2001."
	    ewarn " "
	fi
}