[gentoo-commits] gentoo-x86 commit in dev-util/coccinelle: ChangeLog coccinelle-0.2.2.ebuild

[gentoo-commits] gentoo-x86 commit in dev-util/coccinelle: ChangeLog coccinelle-0.2.2.ebuild

[Alexis Ballier (aballier)]

aballier    10/04/09 13:14:09

  Modified:             ChangeLog
  Added:                coccinelle-0.2.2.ebuild
  Log:
  version bump
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  dev-util/coccinelle/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/coccinelle/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/coccinelle/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/coccinelle/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/coccinelle/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	6 Apr 2010 11:55:18 -0000	1.3
+++ ChangeLog	9 Apr 2010 13:14:09 -0000	1.4
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/coccinelle
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/coccinelle/ChangeLog,v 1.3 2010/04/06 11:55:18 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/coccinelle/ChangeLog,v 1.4 2010/04/09 13:14:09 aballier Exp $
+
+*coccinelle-0.2.2 (09 Apr 2010)
+
+  09 Apr 2010; Alexis Ballier <aballier@gentoo.org>
+  +coccinelle-0.2.2.ebuild:
+  version bump
 
   06 Apr 2010; Alexis Ballier <aballier@gentoo.org> coccinelle-0.2.1.ebuild:
   set VARTEXFONTS to avoid sandbox violations, bug #312343



1.1                  dev-util/coccinelle/coccinelle-0.2.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/coccinelle/coccinelle-0.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/coccinelle/coccinelle-0.2.2.ebuild?rev=1.1&content-type=text/plain

Index: coccinelle-0.2.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/coccinelle/coccinelle-0.2.2.ebuild,v 1.1 2010/04/09 13:14:09 aballier Exp $

EAPI="2"

inherit multilib

DESCRIPTION="Program matching and transformation engine"
HOMEPAGE="http://coccinelle.lip6.fr/"
SRC_URI="http://coccinelle.lip6.fr/distrib/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc +ocamlopt python"

RDEPEND="python? ( dev-lang/python )
	>=dev-lang/ocaml-3.10[ocamlopt?]"
DEPEND="${RDEPEND}
	doc? ( virtual/latex-base
		|| ( dev-texlive/texlive-latexextra app-text/ptex ) )"

src_configure() {
	# non-autoconf
	./configure \
		--prefix=/usr \
		$(use ocamlopt || echo "--no-opt") \
		$(use_with python) \
		|| die
	sed -i "s:^LIBDIR=.*:LIBDIR=/usr/$(get_libdir)/ocaml/stublibs/:" Makefile.config
	sed -i "s:^SHAREDIR=.*:SHAREDIR=/usr/libexec/${PN}/:" Makefile.config
	sed -i "s:^MANDIR=.*:MANDIR=/usr/share/man/:" Makefile.config
}

src_compile() {
	emake depend || die
	emake || die
	if use doc ; then
		VARTEXFONTS="${T}"/fonts emake docs || die
	fi
	if use ocamlopt ; then
		emake opt || die
	fi
}

src_test() {
	./spatch standard.h -parse_c -dir tests/ || die
	yes | ./spatch -iso_file standard.iso -macro_file_builtins standard.h -testall || die
	if use ocamlopt ; then
		./spatch.opt -iso_file standard.iso -macro_file_builtins standard.h -testall ||	die
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc authors.txt bugs.txt changes.txt credits.txt readme.txt
	use doc && dodoc docs/manual/*.pdf
	export STRIP_MASK='*/coccinelle/spatch'
}