[gentoo-commits] repo/gentoo:master commit in: net-libs/gnome-online-accounts/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     1a59be65c78452dfe14b3fc901f7481338fe1e95
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Mon Aug  4 08:33:03 2025 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Mon Aug  4 08:55:38 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1a59be65

net-libs/gnome-online-accounts: add 3.54.4

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 net-libs/gnome-online-accounts/Manifest            |  1 +
 .../gnome-online-accounts-3.54.4.ebuild            | 85 ++++++++++++++++++++++
 2 files changed, 86 insertions(+)

diff --git a/net-libs/gnome-online-accounts/Manifest b/net-libs/gnome-online-accounts/Manifest
index 665edc652b7d..95ed11bd0747 100644
--- a/net-libs/gnome-online-accounts/Manifest
+++ b/net-libs/gnome-online-accounts/Manifest
@@ -1,3 +1,4 @@
 DIST gnome-online-accounts-3.48.1.tar.xz 383124 BLAKE2B a9e18bf034454429a84be0920110f4d74fba9462fb1f7f23e74f304e963323413d99af2d84caa9ef1c6841917f5b8249ac94dc433ba04546f2ae23d6268dcd70 SHA512 8f191994b8f38bee4b922b10b94e96d6f7cb323de0e9a1f29febea848cb2002320357262ccf6f28839e32e9216faeb28a871f878e1ad9478c61650fdd3549737
 DIST gnome-online-accounts-3.52.7.tar.xz 473480 BLAKE2B 736a57725a1f7aa5713a7e27e6bd213a87e90126dc41b7ad3d398cd1c395f88324c672afc91247afab20227993b4f0c58a0fbd516f37d0e429f342abdb9232f8 SHA512 8f45e87c0942496b56ee1ff257c006c7b866175145b1a71a13e7f45f802f1b150512c8396424f43a9594bf391d02dace20879c9e943bbbdb68cdf514147bbd73
 DIST gnome-online-accounts-3.52.8.tar.xz 473564 BLAKE2B 84d1eefaa70e5a3dde68a0512fc13b9832bdf3ae5571da2d5f7d05c5d1ffefbfc7c71d693acebd4f71efdcc2cde27d719441140b4d0d74a6c774dc08782ce9ad SHA512 64e36ae2486fac9c8fce8a2ef5c3008c490018c794b0860aba68e3877f1a7cbeae1087dd55cda575bd122c7dcec9fab6254f1a91d3c64bf804defc06f8f94652
+DIST gnome-online-accounts-3.54.4.tar.xz 485556 BLAKE2B fe0a4b8df83ca30750c1e6efb4760c77152b82eb4152f80360d9fefd6eace7408281f4a8361d1add4ace7276f4dc4f4869ed21bb6b51f538b48ad1f870990df8 SHA512 aa0e7a403c44442a8ed54f495918a63a8b4ef6bf4f9b87386bc786be26c430cd3a44745d0c2369436a29a21229f9048233d281453a0d64ef0ecab5fdd197762d

diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.54.4.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.54.4.ebuild
new file mode 100644
index 000000000000..11df74977129
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.54.4.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala xdg
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-online-accounts"
+
+LICENSE="LGPL-2+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+IUSE="debug doc gnome +introspection kerberos ms365 +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+# json-glib-0.16 needed for bug #485092
+RDEPEND="
+	>=dev-libs/glib-2.67.4:2
+	sys-apps/dbus
+	introspection? ( >=dev-libs/gobject-introspection-0.6.2:= )
+	>=gui-libs/libadwaita-1.6_beta
+	>=gui-libs/gtk-4.15.2:4
+	>=dev-libs/json-glib-0.16
+	>=app-crypt/libsecret-0.5
+	>=net-libs/libsoup-3.0:3.0
+	>=sys-apps/keyutils-1.6.2
+	dev-libs/libxml2:2=
+	>=net-libs/rest-0.9.0:1.0
+	kerberos? (
+		>=app-crypt/gcr-4.1.0:4=[gtk]
+		app-crypt/mit-krb5
+	)
+"
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+	dev-libs/libxslt
+	>=dev-util/gdbus-codegen-2.30.0
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+
+	dev-libs/gobject-introspection-common
+	gnome-base/gnome-common
+"
+BDEPEND="doc? ( dev-util/gi-docgen )"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	# TODO: Give users a way to set the G/FB/Windows Live secrets
+	local emesonargs=(
+		-Dgoabackend=true
+		-Dexchange=true
+		-Dfedora=false
+		-Dgoogle=true
+		-Dimap_smtp=true
+		$(meson_use kerberos)
+		-Downcloud=true
+		-Dwebdav=true
+		-Dwindows_live=true
+		$(meson_use doc documentation)
+		$(meson_use ms365 ms_graph)
+		$(meson_use introspection)
+		-Dman=true
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc; then
+		mv "${ED}"/usr/share/doc/${PN} "${ED}"/usr/share/doc/${PF} || die
+	fi
+}