[gentoo-commits] repo/gentoo:master commit in: www-apps/nikola/files/, www-apps/nikola/

["Ulrich Müller" <ulm@gentoo.org>]

commit:     b7f5b24a2bdac36c3895c6a41c61e83e21b7ee68
Author:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
AuthorDate: Sun Jun  8 09:28:58 2025 +0000
Commit:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
CommitDate: Sun Jun  8 09:35:53 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b7f5b24a

www-apps/nikola: add 8.3.3

Signed-off-by: Ulrich Müller <ulm <AT> gentoo.org>

 www-apps/nikola/Manifest                           |  1 +
 .../nikola/files/nikola-8.3.3-site-packages.patch  | 16 ++++++
 www-apps/nikola/nikola-8.3.3.ebuild                | 67 ++++++++++++++++++++++
 3 files changed, 84 insertions(+)

diff --git a/www-apps/nikola/Manifest b/www-apps/nikola/Manifest
index 0bf1276aa0ec..d0bc68c58efc 100644
--- a/www-apps/nikola/Manifest
+++ b/www-apps/nikola/Manifest
@@ -1 +1,2 @@
 DIST Nikola-8.3.1.tar.gz 4559433 BLAKE2B 32bffeaf5f490f6c7bdf48b1c3b1906e4fb9a94fb196ecba8f0c2f074489b05e57c4278ae6ec8a6d91838772d19ddb0444166e05caa4d0d3055bd388b9b8cc63 SHA512 cbf4e099e2e1ee22ab16c8a3d3984617097721cb24cf03cf9673fc89d051fa712a05cbbfb522f85d6808155a0fa8835b1630096691a33c25aee8cf24564df050
+DIST nikola-8.3.3.tar.gz 4569665 BLAKE2B bf1b3da4c14726bc38a57e9c02ceaf010c90f0c0f2144d74e943e5f882f0094fe6bb80e11d7576e4ccfae1cad5a58280bc16be2451d520df91a5def0736ce868 SHA512 ab4ae1b1d8e2ac370cfe4e6ab2a4f112d2cf0534d91724413f4e958b699df602fbef928dd4cecc81826d83b860af2d063d4a8256d01c7ade0fb7be273ac85e4b

diff --git a/www-apps/nikola/files/nikola-8.3.3-site-packages.patch b/www-apps/nikola/files/nikola-8.3.3-site-packages.patch
new file mode 100644
index 000000000000..23f0cfabdabe
--- /dev/null
+++ b/www-apps/nikola/files/nikola-8.3.3-site-packages.patch
@@ -0,0 +1,16 @@
+commit 46919f494553c818737dc822beafdcc3b34cdad5
+Author: Chris Warrick <kwpolska@gmail.com>
+Date:   Sun, 25 May 2025 20:58:42 +0200
+
+    Fix #3852 — fix data being installed site-packages
+
+--- a/pyproject.toml
++++ b/pyproject.toml
+@@ -102,6 +102,7 @@ docs = [
+ nikola = "nikola.__main__:main"
+ 
+ [tool.setuptools.packages.find]
++namespaces = false
+ exclude = ["tests", "tests.*"]
+ 
+ [tool.setuptools.data-files]

diff --git a/www-apps/nikola/nikola-8.3.3.ebuild b/www-apps/nikola/nikola-8.3.3.ebuild
new file mode 100644
index 000000000000..e6e6401b8511
--- /dev/null
+++ b/www-apps/nikola/nikola-8.3.3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10,11,12,13} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature pypi shell-completion
+
+DESCRIPTION="A static website and blog generator"
+HOMEPAGE="https://getnikola.com/"
+SRC_URI="$(pypi_sdist_url --no-normalize)"
+
+LICENSE="MIT Apache-2.0 CC0-1.0 public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+RESTRICT="test" # needs coveralls
+
+BDEPEND=">=dev-python/docutils-0.13[${PYTHON_USEDEP}]" # needs rst2man to build manpage
+RDEPEND="${BDEPEND}
+	>=dev-python/babel-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.3[${PYTHON_USEDEP}]
+	>=dev-python/doit-0.32[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.3.5[${PYTHON_USEDEP}]
+	>=dev-python/mako-1.0[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/natsort-3.5.2[${PYTHON_USEDEP}]
+	>=dev-python/piexif-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-1.6[${PYTHON_USEDEP}]
+	>=dev-python/pyrss2gen-1.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-67.2.0[${PYTHON_USEDEP}]
+	>=dev-python/unidecode-0.04.16[${PYTHON_USEDEP}]
+	>=dev-python/yapsy-1.11.223[${PYTHON_USEDEP}]
+	dev-python/pillow[jpeg,${PYTHON_USEDEP}]
+	dev-python/cloudpickle[${PYTHON_USEDEP}]"
+
+PATCHES=("${FILESDIR}/${P}-site-packages.patch")
+
+python_compile_all() {
+	nikola tabcompletion --shell=bash > ${PN}.bashcomp || die
+	nikola tabcompletion --shell=zsh > ${PN}.zshcomp || die
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# hackish way to remove docs that ended up in the wrong place
+	rm -r "${ED}/usr/share/doc/${PN}" || die
+
+	dodoc AUTHORS.txt CHANGES.txt README.rst docs/*.rst
+	gunzip "${ED}/usr/share/man/man1/${PN}.1.gz" || die
+
+	newbashcomp ${PN}.bashcomp ${PN}
+	newzshcomp ${PN}.zshcomp _${PN}
+}
+
+pkg_postinst() {
+	optfeature "chart generation" dev-python/pygal
+	optfeature "hyphenation support" dev-python/pyphen
+	optfeature "notebook compilation and LESS support" dev-python/ipython
+	optfeature "alternative templating engine to Mako" dev-python/jinja2
+	optfeature "built-in web server support" dev-python/aiohttp
+	optfeature "monitoring file system events" dev-python/watchdog
+	optfeature "extracting metadata from web media links" dev-python/micawber
+}