[gentoo-commits] repo/gentoo:master commit in: media-gfx/mandelbulber/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     5e8ccb96107af4d084c4c409b5f398da90cba58c
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 15 17:15:10 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Apr 15 17:30:28 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5e8ccb96

media-gfx/mandelbulber: add 2.33

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-gfx/mandelbulber/Manifest                 |  1 +
 media-gfx/mandelbulber/mandelbulber-2.33.ebuild | 80 +++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/media-gfx/mandelbulber/Manifest b/media-gfx/mandelbulber/Manifest
index 1d4c15d1b6a9..b332e41d3781 100644
--- a/media-gfx/mandelbulber/Manifest
+++ b/media-gfx/mandelbulber/Manifest
@@ -1 +1,2 @@
 DIST mandelbulber2-2.32.tar.gz 134765742 BLAKE2B a43ab2e445a65901190c42d6afb947e94d322ddb41f179a9a4763feee8ae5b8e510c2ab6f842b7f17b5b800184a73088b2a3ee4b8d359ffa5e15159eb7f957ad SHA512 f42cebd4939a7d1216c1c09f669bf3bf244e249a8428c02919a735959a5dd91c8614313d21b25cb6f26acd5f7d711287e3c10239c143f542887706f4f970fff4
+DIST mandelbulber2-2.33.tar.gz 136014229 BLAKE2B 3650914f35245dd943a967a685d6c98e1cc7540f945c3c5275edf239e310d116b375bad72f1937c4bc519816cfffe1cb6940f1c15d17b43eb7847c41a6e33594 SHA512 6f199b233cf79f6e0210c1ebd56075bc7551c1e7f712856121e7bcadcbf265ed1c1dd4850a815fb2e53a07a846660e7c49f341aff0df9eb53dfc6c80a1dd7f00

diff --git a/media-gfx/mandelbulber/mandelbulber-2.33.ebuild b/media-gfx/mandelbulber/mandelbulber-2.33.ebuild
new file mode 100644
index 000000000000..42b9f0c2d491
--- /dev/null
+++ b/media-gfx/mandelbulber/mandelbulber-2.33.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="${PN}2-${PV}"
+inherit desktop qmake-utils toolchain-funcs xdg
+
+DESCRIPTION="Tool to render 3D fractals"
+HOMEPAGE="https://www.mandelbulber.com"
+SRC_URI="https://github.com/buddhi1980/${PN}2/releases/download/${PV}/${MY_P}.tar.gz
+	https://downloads.sourceforge.net/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="CC-BY-4.0 GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="opencl openexr sndfile tiff"
+
+# IUSE="joystick"
+# 	joystick? ( dev-qt/qtgamepad:6 )
+RDEPEND="
+	dev-libs/lzo
+	dev-qt/qtbase:6[concurrent,gui,network,widgets]
+	dev-qt/qtmultimedia:6[qml]
+	media-libs/libpng:=
+	sci-libs/gsl:=
+	opencl? (
+		dev-cpp/clhpp
+		virtual/opencl
+	)
+	openexr? (
+		dev-libs/imath:=
+		media-libs/openexr:=
+	)
+	sndfile? ( media-libs/libsndfile )
+	tiff? ( media-libs/tiff:= )
+"
+DEPEND="${RDEPEND}
+	dev-qt/qttools:6[designer]
+"
+BDEPEND="virtual/pkgconfig"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && tc-check-openmp
+}
+
+src_prepare() {
+	default
+
+	sed -i -e "s/qtHaveModule(gamepad)/false/" makefiles/common.pri || die # TODO: dev-qt/qtgamepad:6
+	use openexr || sed -i -e "s/packagesExist(OpenEXR)/false/" makefiles/common.pri || die
+	use sndfile || sed -i -e "s/packagesExist(sndfile)/false/" makefiles/common.pri || die
+	use tiff || sed -i -e "s/packagesExist(libtiff-4)/false/" makefiles/common.pri || die
+}
+
+src_configure() {
+	if use opencl; then
+		eqmake6 makefiles/${PN}-opencl.pro
+	else
+		eqmake6 makefiles/${PN}.pro
+	fi
+}
+
+src_install() {
+	dobin ${PN}2
+
+	dodoc README NEWS usr/share/doc/${PN}2/Mandelbulber_Manual.pdf
+
+	insinto /usr/share/${PN}2
+	doins -r usr/share/${PN}2/*
+
+	domenu ${PN}2.desktop
+
+	newicon -s 256 qt/icons/${PN}.png ${PN}2.png
+}