[gentoo-commits] repo/gentoo:master commit in: games-simulation/openrct2/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     c8fa346f3b9c33f0eb0ffe135938fb1bdcd87a22
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Tue Apr  8 19:35:21 2025 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Tue Apr  8 19:46:28 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c8fa346f

games-simulation/openrct2: add 0.4.21

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 games-simulation/openrct2/Manifest               |   1 +
 games-simulation/openrct2/openrct2-0.4.21.ebuild | 180 +++++++++++++++++++++++
 2 files changed, 181 insertions(+)

diff --git a/games-simulation/openrct2/Manifest b/games-simulation/openrct2/Manifest
index ea5a5a99c0d2..34e35f29592b 100644
--- a/games-simulation/openrct2/Manifest
+++ b/games-simulation/openrct2/Manifest
@@ -1,6 +1,7 @@
 DIST openrct2-0.4.18.tar.gz 22955683 BLAKE2B 5e19ebbf021753e402bb00bf33f79eda254bb2b0c4d22113ab7cdc802cbee2f4a37a5142b238b5eeb0a3d6fce919f60dc0ab2b9c73c628cf273137aa88902878 SHA512 236fa52b9136e6ac329c9c7e4bf415a6c50588e8c30d8973b9da44ab83da3a75177092f8d7492535ea9f82ffa710d8484245c662531d7e3230e2daf69d56c4a2
 DIST openrct2-0.4.19.1.tar.gz 23336008 BLAKE2B b2675bda44d0347cc65a8a507827c56dd92dbcd7fabff85e61529411b721a539ea431d6a4e841bb566f4b9f4d518c1fc4d3ce312f4f910b92acdd41fb97af73a SHA512 3c237fcb89819ce2130eb22371ccb93d559cf89f226f749cfe7f3f187e52af0f083091d9ac8250d3d9d812ee7debfba08e55a72d94f8e0ddca5e2d10765a524e
 DIST openrct2-0.4.20.tar.gz 23347865 BLAKE2B fb593b5caafe7e4e4d43f6e44c84cf7a13a72d13c22421187e74a2d928368d447a1dceb3ae4572b0ca0c0f55628488a4c713900252f4c8586586808835834419 SHA512 e6e4a5f585fc3b8f6078e66aeda59e1d6ed0a26af5a26f2f933fb0a70ef019c717f12f0acfcc9048f1b223412b8ef005de2b7a16b22f5ed0c71fae4877fdfeef
+DIST openrct2-0.4.21.tar.gz 23506846 BLAKE2B b870df75c932896b3cb1a160681dc9995cb7987f00da0d33f93879c4da621904cae75d41cbc67684750896092c859d3f2570cfd544dacae8390d6f26e86fd7d9 SHA512 e335522ab7e360236cf09f6c819c53d4459a8c7baa55d605655500c337c6fe1d4bb80795f911d0a0f0eb50c98b0dc9485642da05c93a0d47d4e9123036a9b3db
 DIST openrct2-objects-1.4.12.zip 7599482 BLAKE2B 896c54e873a7cc143335e8b73dd3115def8fb5205de0028120dee63589db1644b9ba37e390d15cea0cac31014682ac8901e88b519684a03c686b93a702ada579 SHA512 b37984ec5578f4d7f9a43359ade30a621a22474ddbf46614de98e505ed16a62e8621d8c58a6470d66d0e0876db03a4181b259f7fc9468b883422d094c4a8af91
 DIST openrct2-objects-1.5.1.zip 7986278 BLAKE2B e4d87d26682c4edaf6be545df500d2f49a2ddbd793915d4ade79d3a27ac0a3f62d80445435c9662b6e8648f201be80d00f6b48ad04341c0aa08c83ac8814bd1d SHA512 6799943ffa06bb61f670c1b5cd77b03ba6b5c6960e1169b613244cad04b014105a1742034821e33a633b3f2bfbc25f85e1b6d0344a388acdf54bedfd57f82b00
 DIST openrct2-objects-1.6.1.zip 8056882 BLAKE2B e309f0d10f4a37fcf1b9591a64a280470f7942f255b1fe725abec11bac6316fff49d2fdfb34934d3a1f41a3b95c2bc2bf23c6b562229579356c2c3b5d046ded1 SHA512 220476a5ebc3863999abcf20b2070760d6b9f4e9a92b7a8b0c2a80ac8c60bbc6ff02c71d1ef7b84394a362cbe04a1e19c5a3d6ef56bf9b0da25e3dfd02b66e8b

diff --git a/games-simulation/openrct2/openrct2-0.4.21.ebuild b/games-simulation/openrct2/openrct2-0.4.21.ebuild
new file mode 100644
index 000000000000..89fb631d91e5
--- /dev/null
+++ b/games-simulation/openrct2/openrct2-0.4.21.ebuild
@@ -0,0 +1,180 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake readme.gentoo-r1 xdg-utils
+
+MY_PN="OpenRCT2"
+MY_PN_MSX="openmusic"
+MY_PN_OBJ="objects"
+MY_PN_RPL="replays"
+MY_PN_SFX="opensound"
+MY_PN_TS="title-sequences"
+MY_PV_MSX="1.6"
+MY_PV_OBJ="1.6.1"
+MY_PV_RPL="0.0.86"
+MY_PV_SFX="1.0.5"
+MY_PV_TS="0.4.14"
+
+DESCRIPTION="An open source re-implementation of Chris Sawyer's RollerCoaster Tycoon 2"
+HOMEPAGE="https://openrct2.org/"
+SRC_URI="
+	https://github.com/${MY_PN}/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/${MY_PN}/${MY_PN_MSX}/releases/download/v${MY_PV_MSX}/${MY_PN_MSX}.zip -> ${PN}-${MY_PN_MSX}-${MY_PV_MSX}.zip
+	https://github.com/${MY_PN}/${MY_PN_OBJ}/releases/download/v${MY_PV_OBJ}/${MY_PN_OBJ}.zip -> ${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}.zip
+	https://github.com/${MY_PN}/OpenSoundEffects/releases/download/v${MY_PV_SFX}/${MY_PN_SFX}.zip -> ${PN}-${MY_PN_SFX}-${MY_PV_SFX}.zip
+	https://github.com/${MY_PN}/${MY_PN_TS}/releases/download/v${MY_PV_TS}/${MY_PN_TS}.zip -> ${PN}-${MY_PN_TS}-${MY_PV_TS}.zip
+	test? ( https://github.com/${MY_PN}/${MY_PN_RPL}/releases/download/v${MY_PV_RPL}/${MY_PN_RPL}.zip -> ${PN}-${MY_PN_RPL}-${MY_PV_RPL}.zip )
+"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="dedicated +flac +opengl scripting test +truetype +vorbis"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-libs/icu:=
+	dev-libs/jansson:=
+	dev-libs/libzip:=
+	media-libs/libpng:=
+	net-misc/curl[ssl]
+	sys-libs/zlib
+	!dedicated? (
+		media-libs/libsdl2
+		media-libs/speexdsp
+		flac? ( media-libs/flac:= )
+		opengl? ( virtual/opengl )
+		vorbis? ( media-libs/libvorbis )
+	)
+	dev-libs/openssl:0=
+	scripting? ( dev-lang/duktape:= )
+	truetype? (
+		media-libs/fontconfig:1.0
+		media-libs/freetype:2
+	)
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	dedicated? (
+		acct-group/openrct2
+		acct-user/openrct2
+	)
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	dev-cpp/nlohmann_json
+	test? ( dev-cpp/gtest )
+"
+
+BDEPEND="
+	app-arch/unzip
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.4.1-gtest-1.10.patch"
+	"${FILESDIR}/${PN}-0.4.16-include-additional-paths.patch"
+)
+
+src_unpack() {
+	unpack "${P}".tar.gz
+
+	mkdir -p "${S}"/data || die
+	cd "${S}"/data
+	unpack "${PN}-${MY_PN_MSX}-${MY_PV_MSX}".zip
+	unpack "${PN}-${MY_PN_SFX}-${MY_PV_SFX}".zip
+
+	mkdir -p "${S}"/data/object || die
+	cd "${S}"/data/object || die
+	unpack "${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}".zip
+
+	mkdir -p "${S}"/data/sequence || die
+	cd "${S}"/data/sequence || die
+	unpack "${PN}-${MY_PN_TS}-${MY_PV_TS}".zip
+
+	if use test; then
+		mkdir -p "${S}"/testdata/replays || die
+		cd "${S}"/testdata/replays || die
+		unpack "${PN}-${MY_PN_RPL}-${MY_PV_RPL}".zip
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Don't treat warnings as errors.
+	sed -e 's/-Werror//' -i CMakeLists.txt || die
+}
+
+src_configure() {
+	# Note: There is currently no support for Disord-RPC and Google Benchmark,
+	# as both packages do not exist in Gentoo, so support for them has been disabled.
+	local mycmakeargs=(
+		-DDISABLE_DISCORD_RPC=ON
+		$(usex !dedicated "-DDISABLE_FLAC=$(usex !flac)" "")
+		-DDISABLE_GOOGLE_BENCHMARK=ON
+		-DDISABLE_GUI=$(usex dedicated)
+		-DDISABLE_HTTP=OFF
+		-DDISABLE_IPO=ON
+		-DDISABLE_NETWORK=OFF
+		$(usex !dedicated "-DDISABLE_OPENGL=$(usex !opengl)" "")
+		-DDISABLE_TTF=$(usex !truetype)
+		$(usex !dedicated "-DDISABLE_VORBIS=$(usex !vorbis)" "")
+		-DDOWNLOAD_OBJECTS=OFF
+		-DDOWNLOAD_OPENMSX=OFF
+		-DDOWNLOAD_OPENSFX=OFF
+		-DDOWNLOAD_REPLAYS=OFF
+		-DDOWNLOAD_TITLE_SEQUENCES=OFF
+		-DENABLE_SCRIPTING=$(usex scripting)
+		-DOPENRCT2_USE_CCACHE=OFF
+		-DPORTABLE=OFF
+		-DSTATIC=OFF
+		-DWITH_TESTS=$(usex test)
+		-DUSE_MMAP=ON
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Since the tests need the OpenRCT2 data,
+	# we need to symlink them into the build directory,
+	# otherwise some tests will fail, as they don't find the OpenRCT2 data.
+	# It is currently not possible to override that path.
+	# See: https://github.com/OpenRCT2/OpenRCT2/issues/6473
+	ln -s "${S}"/data "${BUILD_DIR}" || die
+
+	cmake_src_test
+}
+
+src_install() {
+	use scripting && DOCS+=( "distribution/scripting.md" "distribution/openrct2.d.ts" )
+
+	cmake_src_install
+
+	if use dedicated; then
+		newinitd "${FILESDIR}"/openrct2.initd openrct2
+		newconfd "${FILESDIR}"/openrct2.confd openrct2
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}