[gentoo-commits] repo/gentoo:master commit in: media-libs/phonon/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     35af58707a717506ac77d6cce9fc635b93519f90
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 16 21:12:18 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Mar 16 23:19:53 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=35af5870

media-libs/phonon: drop 4.12.0-r4

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-libs/phonon/phonon-4.12.0-r4.ebuild | 100 ------------------------------
 1 file changed, 100 deletions(-)

diff --git a/media-libs/phonon/phonon-4.12.0-r4.ebuild b/media-libs/phonon/phonon-4.12.0-r4.ebuild
deleted file mode 100644
index 8252c541ac00..000000000000
--- a/media-libs/phonon/phonon-4.12.0-r4.ebuild
+++ /dev/null
@@ -1,100 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake desktop flag-o-matic kde.org multibuild
-
-DESCRIPTION="KDE multimedia abstraction library"
-HOMEPAGE="https://community.kde.org/Phonon"
-
-if [[ ${KDE_BUILD_TYPE} = release ]]; then
-	SRC_URI="mirror://kde/stable/phonon/${PV}/${P}.tar.xz"
-	KEYWORDS="amd64 ~arm arm64 ~loong ppc64 ~riscv ~x86"
-fi
-
-LICENSE="|| ( LGPL-2.1 LGPL-3 ) !pulseaudio? ( || ( GPL-2 GPL-3 ) )"
-SLOT="0"
-IUSE="debug designer minimal pulseaudio +qt5 qt6"
-REQUIRED_USE="|| ( qt5 qt6 )"
-
-DEPEND="
-	pulseaudio? (
-		dev-libs/glib:2
-		media-libs/libpulse[glib]
-	)
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtwidgets:5
-		designer? ( dev-qt/designer:5 )
-	)
-	qt6? (
-		dev-qt/qt5compat:6
-		dev-qt/qtbase:6[gui,widgets]
-		designer? ( dev-qt/qttools:6[designer] )
-	)
-"
-RDEPEND="${DEPEND}
-	!media-libs/phonon-gstreamer
-	|| (
-		kde-frameworks/breeze-icons:*
-		kde-frameworks/oxygen-icons:*
-	)
-"
-BDEPEND="
-	dev-libs/libpcre2:*
-	>=kde-frameworks/extra-cmake-modules-5.115.0:*
-	virtual/pkgconfig
-	qt5? ( dev-qt/linguist-tools:5 )
-	qt6? ( dev-qt/qttools:6[linguist] )
-"
-PDEPEND="!minimal? ( >=media-libs/phonon-vlc-0.12.0[qt5?,qt6?] )"
-
-PATCHES=( "${FILESDIR}/${P}-cmake.patch" ) # bug 938315
-
-pkg_setup() {
-	MULTIBUILD_VARIANTS=( $(usev qt5) $(usev qt6) )
-}
-
-src_configure() {
-	use debug || append-cppflags -DQT_NO_DEBUG
-
-	myconfigure() {
-		local mycmakeargs=(
-			-DQT_MAJOR_VERSION=${MULTIBUILD_VARIANT/qt/}
-			-DPHONON_BUILD_${MULTIBUILD_VARIANT^^}=ON
-			-DKDE_INSTALL_USE_QT_SYS_PATHS=ON # ecm.eclass
-			-DKDE_INSTALL_DOCBUNDLEDIR="${EPREFIX}/usr/share/help" # ecm.eclass
-			-DPHONON_BUILD_DESIGNER_PLUGIN=$(usex designer)
-			-DCMAKE_DISABLE_FIND_PACKAGE_GLIB2=$(usex !pulseaudio)
-			-DCMAKE_DISABLE_FIND_PACKAGE_PulseAudio=$(usex !pulseaudio)
-		)
-
-		if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
-			mycmakeargs+=(
-				-DPHONON_BUILD_QT5=OFF
-				-DPHONON_BUILD_SETTINGS=ON
-			)
-		else
-			mycmakeargs+=(
-				-DPHONON_BUILD_QT6=OFF
-				-DPHONON_BUILD_SETTINGS=$(usex !qt6)
-			)
-		fi
-
-		cmake_src_configure
-	}
-
-	multibuild_foreach_variant myconfigure
-}
-
-src_compile() {
-	multibuild_foreach_variant cmake_src_compile
-}
-
-src_install() {
-	multibuild_foreach_variant cmake_src_install
-	make_desktop_entry "${PN}settings" \
-		"Phonon Audio and Video" preferences-desktop-sound
-}