[gentoo-commits] repo/gentoo:master commit in: app-emacs/dape/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     91835eca375a96c2aaa78ef217c28631a1904e45
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 11 18:53:02 2025 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Tue Mar 11 18:55:59 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=91835eca

app-emacs/dape: bump to 0.23.0

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 app-emacs/dape/Manifest           |  1 +
 app-emacs/dape/dape-0.23.0.ebuild | 70 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/app-emacs/dape/Manifest b/app-emacs/dape/Manifest
index 70274cc19d14..94f53d836e32 100644
--- a/app-emacs/dape/Manifest
+++ b/app-emacs/dape/Manifest
@@ -1 +1,2 @@
 DIST dape-0.22.0.tar.gz 78792 BLAKE2B 42743bcb2c82680b90f42c01a9212eca08eba7c41bc8874ffebbe9f1b4003812ad453afb8ef049c085def3466c835a7f63c4b96efe6fccfd6366089d303df990 SHA512 057776fd479dbf1ca3206593fd778e35182e9a2915966ff6e45c87c76e62a96dc19474d35a5bba4015f419e34cf8fa31d214c4164c6cab2ed6e5edb788e4a658
+DIST dape-0.23.0.tar.gz 79466 BLAKE2B 70c6741d11c392eb420aa3173aff8b4c293d640b28ee02c352bc2f2ccff9293c15d8855aca421fff3e7d2824865c8fa6e3f218471b8cb2bceef51e3e7e30355a SHA512 e3c4fb922cb1cd328e49afd8cb52df15fd0dcf5636f9ba0b5c882cfdaf12a2c7349749f23a7c6bae98210cf5e2f9224570edbdcba9748c2a7ac216b4890d5952

diff --git a/app-emacs/dape/dape-0.23.0.ebuild b/app-emacs/dape/dape-0.23.0.ebuild
new file mode 100644
index 000000000000..e3cc513f8bb9
--- /dev/null
+++ b/app-emacs/dape/dape-0.23.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS="29.1"
+
+inherit elisp
+
+DESCRIPTION="Debug Adapter Protocol for Emacs"
+HOMEPAGE="https://github.com/svaante/dape"
+
+if [[ "${PV}" == 9999 ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/svaante/${PN}.git"
+else
+	SRC_URI="https://github.com/svaante/${PN}/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="
+	|| (
+		app-emacs/jsonrpc
+		>=app-editors/emacs-30:*
+	)
+"
+DEPEND="
+	${RDEPEND}
+"
+
+# Requires debugpy, but we do not package debugpy right now, as well as
+# js-debug.  Most tests use only the former.
+RESTRICT="test"
+
+# Remove tests.el to skip compilation and failing tests (see above comment).
+ELISP_REMOVE="${PN}-tests.el"
+
+DOCS=( README.org CHANGELOG.org LICENSE )
+SITEFILE="50${PN}-gentoo.el"
+
+# elisp-enable-tests ert . -l dape-tests.el
+
+pkg_setup() {
+	elisp_pkg_setup
+	local has_jsonrpc="$(${EMACS} ${EMACSFLAGS} \
+		--eval "(princ (>= emacs-major-version 30))")"
+	if has_version app-emacs/jsonrpc || [[ ${has_jsonrpc} = t ]]; then
+		:
+	else
+		die "Emacs does not have jsonrpc.el 1.0.25 or later, nor was app-emacs/jsonrpc installed"
+	fi
+}
+
+src_compile() {
+	elisp_src_compile
+	elisp-make-autoload-file
+}
+
+src_install() {
+	# Need to ignore dape-tests.el.
+	einstalldocs
+	elisp-install "${PN}" dape.el dape.elc dape-autoloads.el
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+}