[gentoo-commits] repo/gentoo:master commit in: dev-python/python-debian/

["Michał Górny" <mgorny@gentoo.org>]

commit:     2e097cfb3bc583fc90adfa697205c351f78c06f1
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 10 06:29:10 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Mar 10 06:31:08 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2e097cfb

dev-python/python-debian: Bump to 1.0.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/python-debian/Manifest                  |  1 +
 .../python-debian/python-debian-1.0.0.ebuild       | 49 ++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/dev-python/python-debian/Manifest b/dev-python/python-debian/Manifest
index 85e2989d4069..e8e0b82080db 100644
--- a/dev-python/python-debian/Manifest
+++ b/dev-python/python-debian/Manifest
@@ -1 +1,2 @@
 DIST python-debian_0.1.49.tar.xz 191388 BLAKE2B 590e6f7877684caaa5a74f06d335bcf7808960968209cf18bb2cec7e81f33a3b0ff458bbe30264ae5fc015de9357dddb1522b5fd93bf33d0a7fabef1b7dd98f9 SHA512 201ceecdd8c1d3dc0cca0f661407bcfb825a1cba07c528858cc1123ab16afe0df50e338c8cd82ea24230812a9cc136220bd4f0dccbac19ad53efe48eaa25cf6f
+DIST python-debian_1.0.0.tar.xz 197964 BLAKE2B 38e9ce2f1bbb15577e18189ad1a26d230f24ef7d20490556ab72149f68e5945e777018abca256d49020f4985f13953b6fd1640042272df763af38a8e57eb3766 SHA512 86d58c5185580010773f4d7236aa84276828a094f07bc8fe11d77c2cdf8a4b911284299dd2c2728dbbb802091b4a81b5ff2876404dfb9d944df1d996bb369228

diff --git a/dev-python/python-debian/python-debian-1.0.0.ebuild b/dev-python/python-debian/python-debian-1.0.0.ebuild
new file mode 100644
index 000000000000..5f1d288769cd
--- /dev/null
+++ b/dev-python/python-debian/python-debian-1.0.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 2011-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python modules to work with Debian-related data formats"
+HOMEPAGE="
+	https://salsa.debian.org/python-debian-team/python-debian/
+	https://pypi.org/project/python-debian/
+"
+SRC_URI="mirror://debian/pool/main/${PN::1}/${PN}/${PN}_${PV}.tar.xz"
+
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/charset-normalizer[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		app-arch/dpkg
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# silence false positives
+	rm -rf debian || die
+}
+
+python_compile_all() {
+	# See debian/rules.
+	"${EPYTHON}" src/debian/doc-debtags > README.debtags || die
+}
+
+python_test() {
+	epytest --doctest-modules
+}