[gentoo-commits] repo/gentoo:master commit in: gnome-extra/nemo/

["Sam James" <sam@gentoo.org>]

commit:     0eb4f5cb324256d2080cabe2bbb3f2b77fb89924
Author:     Matthew S. Turnbull <sparky <AT> bluefang-logic <DOT> com>
AuthorDate: Mon Dec  9 07:11:58 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Mar 10 02:24:02 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0eb4f5cb

gnome-extra/nemo: add 6.4.5

Signed-off-by: Matthew S. Turnbull <sparky <AT> bluefang-logic.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 gnome-extra/nemo/Manifest          |   1 +
 gnome-extra/nemo/nemo-6.4.5.ebuild | 145 +++++++++++++++++++++++++++++++++++++
 2 files changed, 146 insertions(+)

diff --git a/gnome-extra/nemo/Manifest b/gnome-extra/nemo/Manifest
index 25d478fa7103..f161c5d0daab 100644
--- a/gnome-extra/nemo/Manifest
+++ b/gnome-extra/nemo/Manifest
@@ -1 +1,2 @@
 DIST nemo-6.2.8.tar.gz 1505198 BLAKE2B fc74ab19e5aef65ba279f212f505cab91aa0dc92b19d31d4ae2f44b3222bd2278fbdf0df0bc36fa3973b91c9c06fab2c211b58c8d840deef5e60d5dbcbfa4dd7 SHA512 cd943603cfb14cc9d50466872607d191a3af7ff61f05549407caa5d9dfe606e080d6eb40d17bbcdf3a9e810bcc493f3be087b1eac6c8272746cd72c9751822af
+DIST nemo-6.4.5.tar.gz 1511087 BLAKE2B 48a620f6aed0c4652f734ce9ee7e0d9a9d5946ab7f2398baba079825dc4a18d829bc2bb0c59796534970f829adc15a9e60c62e9baebed94a2104aac080f77ef3 SHA512 4163dafe0d2c581468b70bf78d928b42d4e71823d698b6e8c5f86e48d148f29fcc7b02f451eba6018ae21c6e3f6ec876c5460ddeff16a8a30613ee19fcec496a

diff --git a/gnome-extra/nemo/nemo-6.4.5.ebuild b/gnome-extra/nemo/nemo-6.4.5.ebuild
new file mode 100644
index 000000000000..bafb36cbd0c3
--- /dev/null
+++ b/gnome-extra/nemo/nemo-6.4.5.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit meson flag-o-matic gnome2-utils python-single-r1 readme.gentoo-r1 virtualx xdg
+
+DESCRIPTION="A file manager for Cinnamon, forked from Nautilus"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/nemo"
+SRC_URI="https://github.com/linuxmint/nemo/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+ LGPL-2.1+ FDL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="exif gtk-doc +nls selinux test tracker wayland xmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# https://github.com/linuxmint/nemo/issues/2501
+RESTRICT="test"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	>=dev-libs/glib-2.45.7:2[dbus]
+	>=dev-libs/gobject-introspection-0.9.12:=
+	>=dev-libs/json-glib-1.6.0
+	dev-libs/libxmlb:0/2[introspection]
+	>=gnome-extra/cinnamon-desktop-6.4:0=
+	gnome-extra/libgsf:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.24.41-r1:3[introspection,wayland?,X]
+	x11-libs/libX11
+	>=x11-libs/pango-1.40.0
+	>=x11-libs/xapp-2.8.8[introspection]
+
+	exif? (
+		>=media-libs/libexif-0.6.20
+	)
+	selinux? (
+		sys-libs/libselinux
+	)
+	tracker? (
+		app-misc/tracker:3
+	)
+	xmp? (
+		>=media-libs/exempi-2.2.0:=
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	x11-themes/adwaita-icon-theme
+
+	nls? (
+		>=gnome-extra/cinnamon-translations-6.4
+	)
+"
+PDEPEND="
+	>=gnome-base/gvfs-0.1.2
+"
+DEPEND="
+	${COMMON_DEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	>=dev-util/gdbus-codegen-2.31.0
+	>=dev-util/intltool-0.40.1
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	gtk-doc? (
+		dev-util/gtk-doc
+	)
+"
+
+PATCHES=(
+	# Undo the switch to untex as it's not packaged.
+	"${FILESDIR}/${PN}-5.0.3-use-detex.patch"
+)
+
+DISABLE_AUTOFORMATTING="yes"
+FORCE_PRINT_ELOG="yes"
+DOC_CONTENTS="
+${PN} functionality can be extended by installing other packages.
+
+sys-apps/gnome-disk-utility - Mount archive files
+gnome-extra/nemo-fileroller - Extract/Create archive files
+
+${PN} search capabilities can be extended through external
+helpers. Install any of the following packages to make
+their associated file types searchable.
+
+epub                     - app-arch/unzip and app-text/html2text
+Image metadata           - media-gfx/exif
+MP3 tags                 - media-sound/id3
+Microsoft Office .doc    - app-text/catdoc
+Microsoft Office .xls    - dev-python/xlrd
+PDF                      - app-text/poppler[utils]
+PostScript               - app-text/ghostscript-gpl
+TeX                      - app-text/texlive-core
+"
+
+src_prepare() {
+	default
+	python_fix_shebang files/usr/share/nemo/actions install-scripts
+}
+
+src_configure() {
+	# defang automagic dependencies
+	use wayland || append-cflags -DGENTOO_GTK_HIDE_WAYLAND
+
+	local emesonargs=(
+		$(meson_use exif)
+		$(meson_use xmp)
+		$(meson_use selinux)
+		$(meson_use tracker)
+		$(meson_use gtk-doc gtk_doc)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}