[gentoo-commits] repo/gentoo:master commit in: gnome-extra/cinnamon-session/

["Sam James" <sam@gentoo.org>]

commit:     5fff5723ee059fc1fca25beb68ba3d7cca12dee5
Author:     Matthew S. Turnbull <sparky <AT> bluefang-logic <DOT> com>
AuthorDate: Sat Dec  7 23:08:54 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Mar 10 02:24:00 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5fff5723

gnome-extra/cinnamon-session: add 6.4.0

Signed-off-by: Matthew S. Turnbull <sparky <AT> bluefang-logic.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 gnome-extra/cinnamon-session/Manifest              |  1 +
 .../cinnamon-session/cinnamon-session-6.4.0.ebuild | 86 ++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/gnome-extra/cinnamon-session/Manifest b/gnome-extra/cinnamon-session/Manifest
index 0e36ea5d0ff1..377e80b682ca 100644
--- a/gnome-extra/cinnamon-session/Manifest
+++ b/gnome-extra/cinnamon-session/Manifest
@@ -1 +1,2 @@
 DIST cinnamon-session-6.2.1.tar.gz 166106 BLAKE2B ef7bb345f6c32f5402d9ff5dca152455a861e41e4fc5a77d1184f75ef17b70ab78bd3cfc9f63265703153d86217b5cd0a679f50add722110c47f7246050ca68f SHA512 bc0e69b938920149c26e2470aab9c2290b3b7ecea8a6e8249683402eb07af0c3a88c42cb86723d422dd14442246e841469010a05e808e675ff0e7ff1cc834224
+DIST cinnamon-session-6.4.0.tar.gz 165993 BLAKE2B 13bed1e5cec912f679c13c9ef8e4bbca8c267c37663910ba0a82e78074c77405c259020dffb86c843f2e080792e836a567d120eb5c80459e870a29a959f7f4a3 SHA512 6ad1238a133ed07716807bdcd9599321fe8e27b3de849e7323dab09b79c71a2414f926be2e5dc2584da38bd47e921b3ad2391193c6c241af32524fca68d270b4

diff --git a/gnome-extra/cinnamon-session/cinnamon-session-6.4.0.ebuild b/gnome-extra/cinnamon-session/cinnamon-session-6.4.0.ebuild
new file mode 100644
index 000000000000..c22e79716a91
--- /dev/null
+++ b/gnome-extra/cinnamon-session/cinnamon-session-6.4.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit meson gnome2-utils python-single-r1
+
+DESCRIPTION="Cinnamon session manager"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-session"
+SRC_URI="https://github.com/linuxmint/cinnamon-session/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="systemd"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.37.3:2
+	>=gnome-extra/cinnamon-desktop-6.4:0=
+	media-libs/libcanberra[pulseaudio]
+	virtual/opengl
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3:3[introspection]
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXext
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango[X]
+	>=x11-libs/xapp-2.8.8[introspection]
+
+	systemd? (
+		>=sys-apps/systemd-183
+	)
+	!systemd? (
+		sys-auth/elogind[policykit]
+	)
+"
+DEPEND="
+	${COMMON_DEPEND}
+	x11-libs/xtrans
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang data cinnamon-session-quit
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dipv6=true
+		-Dxtrans=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}