[gentoo-commits] repo/gentoo:master commit in: x11-libs/xapp/

["Sam James" <sam@gentoo.org>]

commit:     e39bb4033541e4ec89c57e2a4fd95e94fec8c4c4
Author:     Matthew S. Turnbull <sparky <AT> bluefang-logic <DOT> com>
AuthorDate: Sat Dec  7 21:07:34 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Mar 10 02:23:56 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e39bb403

x11-libs/xapp: add 2.8.8

Signed-off-by: Matthew S. Turnbull <sparky <AT> bluefang-logic.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 x11-libs/xapp/Manifest          |   1 +
 x11-libs/xapp/xapp-2.8.8.ebuild | 117 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 118 insertions(+)

diff --git a/x11-libs/xapp/Manifest b/x11-libs/xapp/Manifest
index 14e89dfa9c39..70f71bde0f14 100644
--- a/x11-libs/xapp/Manifest
+++ b/x11-libs/xapp/Manifest
@@ -1 +1,2 @@
 DIST xapp-2.8.5.tar.gz 274241 BLAKE2B 86b38dcab542e934f65e2fb11a5c1e7a5e26e8c725c5c91fed7bec6e0676f40ab6fd85b0421378e4860271ef1c9954d8c5a42b465232670d3d695dcda0734e0b SHA512 133a01309f0bc33a0aa73ee86eb8900573b4ab5b84e9e503b04b246448bce0b05880403288a739c5e252a2276311afba86c9c687887dd6e8c528734e328c6ee7
+DIST xapp-2.8.8.tar.gz 276737 BLAKE2B ad6d33785a2935777bf1dfa96de22edef676280eb7ac48976889c27351010627805c7ebabfd2f7ba7c16ac71ccc65f7306f40f94a045733ff005a841e8b17676 SHA512 0c876d0fa59da10fd079d3c38879ace398dbe99a6351a5437b60c87c2c339799f5228260653d9c03b8efab8c310519fc7edba5eca8f571e683bf06b7aee88403

diff --git a/x11-libs/xapp/xapp-2.8.8.ebuild b/x11-libs/xapp/xapp-2.8.8.ebuild
new file mode 100644
index 000000000000..b73207fba46c
--- /dev/null
+++ b/x11-libs/xapp/xapp-2.8.8.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2-utils vala meson python-r1
+
+DESCRIPTION="Cross-desktop libraries and common resources"
+HOMEPAGE="https://github.com/linuxmint/xapp/"
+
+SRC_URI="https://github.com/linuxmint/xapp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="LGPL-3 xfce? ( GPL-3 )"
+SLOT="0"
+
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="gtk-doc introspection mate vala xfce"
+REQUIRED_USE="${PYTHON_REQUIRED_USE} vala? ( introspection )"
+
+DEPEND="
+	>=dev-libs/glib-2.44.0:2
+	dev-libs/libdbusmenu[gtk3]
+	gnome-base/libgnomekbd:=
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.22.0:2[introspection?]
+	>=x11-libs/gtk+-3.22.0:3[introspection?]
+	x11-libs/libxkbfile
+	x11-libs/libX11
+	x11-libs/pango
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	${DEPEND}
+
+	introspection? (
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	sys-apps/dbus
+	sys-devel/gettext
+
+	gtk-doc? (
+		dev-util/gtk-doc
+	)
+
+	introspection? (
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+
+	vala? (
+		$(vala_depend)
+	)
+"
+
+PATCHES=(
+	# Don't install pastebin upload wrapper
+	"${FILESDIR}"/0001-don-t-install-pastebin-upload-wrapper.patch
+)
+
+src_prepare() {
+	use vala && vala_setup
+
+	default
+
+	# Fix meson helpers
+	python_setup
+	python_fix_shebang .
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		$(meson_use introspection)
+		$(meson_use mate)
+		$(meson_use vala vapi)
+		$(meson_use xfce)
+	)
+
+	if use introspection; then
+		local xapp_python_targets=()
+
+		get_xapp_python_targets() {
+			xapp_python_targets+=("${EPYTHON}")
+		}
+		python_foreach_impl get_xapp_python_targets
+
+		emesonargs+=(
+			-Dpython_target="$(echo "${xapp_python_targets[@]}" | tr ' ' ,)"
+		)
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use introspection; then
+		python_foreach_impl python_optimize
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}