[gentoo-commits] repo/gentoo:master commit in: dev-util/diffoscope/

["Sam James" <sam@gentoo.org>]

commit:     1e9ef60c8054fef1f0cf0a24567737a78623dd82
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Mar  7 01:53:01 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Mar  7 01:53:01 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1e9ef60c

dev-util/diffoscope: add 289

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/diffoscope/Manifest              |   1 +
 dev-util/diffoscope/diffoscope-289.ebuild | 140 ++++++++++++++++++++++++++++++
 2 files changed, 141 insertions(+)

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index b64c2a8a3d49..75fb59717ffe 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -2,3 +2,4 @@ DIST diffoscope-284.tar.bz2 3149578 BLAKE2B 4969e394a32d076101d59c0ca730d4e3515e
 DIST diffoscope-285.tar.bz2 3151919 BLAKE2B ad7c20368f8d3747b8b092d8761d6596809e39ee6ba09115e15f3b6c32da7e3cc590eed5628fb07cfc1fcf2f3b56ee7a4c3fd920c413e7f9e7a0522dfc6c721c SHA512 4b2eb41ddfee687408377185fb0ff5e88d6956c09a4dfceceb7c136596a3b00192be949c141f16f47e90f58da2f9ee1f51cd020f688e1bd6048462f357f14a03
 DIST diffoscope-286.tar.bz2 3155046 BLAKE2B 20676f44d6722962aed53351c006a538d2ac1d20bb2f38edc6f4bbf0e09d28de80d72045db3f9c1ed95c3b3156f40f995962a8510e8c01e0c21900df9a335489 SHA512 42d47801f0dc6cf66f3261639040dd82c5fde73656ab1a33dad325383e4bc6351d03c7509661172c946f554136ea23bf9b6787ba736138461690e507097dc133
 DIST diffoscope-288.tar.bz2 3157674 BLAKE2B 546cf9cca9ca1f81470cfa347517054cc00a5195eb90b3aa72b6fdfde23e1385d4264f6c2c3b3c462a8ef4547fc136c6c758e240423deecb0689721057786bac SHA512 c93849f6bfa7173981b783e68114dfda44938629d5152ce67751b341ce3153c9dbc188dbf95c6d3bc69bfc3d303ab081db70ac37c5e30def3b364351ffd9d88b
+DIST diffoscope-289.tar.bz2 3157044 BLAKE2B bd7c705098857251883a4506d483e23c24c845ecc624e7487afc111e01a8aee710862abf0ea1638c9c2455812d4cf6a2f491e63bfa6389d4dc9ff053a30de30b SHA512 e47538aed4136ef0891d569a0723c45d294757592762f20281fe6061aa52a4f926f49e7e491cb0a746f6f60bc14834762d1de968879db49b8a9a3b0e01a1ffc6

diff --git a/dev-util/diffoscope/diffoscope-289.ebuild b/dev-util/diffoscope/diffoscope-289.ebuild
new file mode 100644
index 000000000000..6f5fc7ca5b80
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-289.ebuild
@@ -0,0 +1,140 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+# We could use pypi, but upstream provide distribution tarballs, so let's use those.
+# TODO: verify-sig
+SRC_URI="https://diffoscope.org/archive/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	|| (
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		sys-apps/file[python,${PYTHON_USEDEP}]
+	)
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/python-tlsh[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-alternatives/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( llvm-core/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/pypdf[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( virtual/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="
+	test? (
+		app-arch/p7zip
+		app-text/docx2txt
+		app-text/html2text
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+	tests/comparators/test_gif.py::test_has_visuals
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+
+	# Fails on ZFS
+	tests/test_main.py::test_non_unicode_filename
+
+	# Fails on (unreleased) LLVM 16 with minor difference
+	#tests/comparators/test_macho.py::test_llvm_diff
+	#tests/comparators/test_elf.py::test_libmix_differences
+)
+
+distutils_enable_tests pytest
+
+src_test() {
+	case $(tc-get-ptr-size) in
+		4)
+			EPYTEST_IGNORE+=(
+				# Needs fixing in Perl itself (bug #934443)
+				tests/comparators/test_epub.py
+				tests/comparators/test_zip.py
+			)
+			;;
+		*)
+			;;
+	esac
+
+	distutils-r1_src_test
+}