[gentoo-commits] repo/proj/guru:dev commit in: media-sound/lms/

["David Roman" <davidroman96@gmail.com>]

commit:     5b13d9f281d9c307c2cc7ef45b8ab56d71b64b4d
Author:     David Roman <davidroman96 <AT> gmail <DOT> com>
AuthorDate: Wed Mar  5 13:15:23 2025 +0000
Commit:     David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Wed Mar  5 13:15:23 2025 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=5b13d9f2

media-sound/lms: add slot rebuild for wt and boost

Signed-off-by: David Roman <davidroman96 <AT> gmail.com>

 media-sound/lms/lms-3.64.0-r1.ebuild | 68 ++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

diff --git a/media-sound/lms/lms-3.64.0-r1.ebuild b/media-sound/lms/lms-3.64.0-r1.ebuild
new file mode 100644
index 000000000..7c03b6f8e
--- /dev/null
+++ b/media-sound/lms/lms-3.64.0-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake pam systemd
+
+DESCRIPTION="Lightweight Music Server."
+HOMEPAGE="https://lms-demo.poupon.dev/ https://github.com/epoupon/lms"
+SRC_URI="https://github.com/epoupon/lms/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test +stb"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-arch/libarchive
+	acct-user/lms
+	dev-cpp/wt:=
+	dev-libs/boost:=
+	dev-libs/libconfig[cxx]
+	media-libs/taglib
+	media-video/ffmpeg[mp3,opus]
+	sys-libs/pam
+
+	!stb? ( media-gfx/graphicsmagick )
+
+"
+
+DEPEND="
+	${RDEPEND}
+
+	stb? ( dev-libs/stb )
+"
+
+BDEPEND="
+	test? ( dev-cpp/gtest )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DLMS_IMAGE_BACKEND=$(usex stb stb graphicsmagick)
+		-DENABLE_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	systemd_newunit conf/systemd/default.service lms.service
+	newinitd "${FILESDIR}/lms.init" lms
+	dopamd conf/pam/lms
+	mv "${ED}/usr/share/lms/lms.conf" "${ED}/etc/lms.conf" || die
+
+	# Already installed in the proper directory
+	rm "${ED}/usr/share/lms/default.service" || die
+	rm "${ED}/usr/share/lms/lms" || die
+
+	keepdir /var/log/lms
+	fowners -R lms:lms /var/log/lms
+
+	keepdir /var/lms
+	fowners lms:lms /var/lms
+}