* [gentoo-commits] repo/proj/guru:dev commit in: media-libs/libsdl3/
@ 2025-01-31 14:17 David Roman
0 siblings, 0 replies; 4+ messages in thread
From: David Roman @ 2025-01-31 14:17 UTC (permalink / raw
To: gentoo-commits
commit: 18c190151622ca7fdcb904e4848c8085d617145c
Author: David Roman <davidroman96 <AT> gmail <DOT> com>
AuthorDate: Fri Jan 31 14:05:22 2025 +0000
Commit: David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Fri Jan 31 14:05:22 2025 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=18c19015
media-libs/libsdl3: unkeyword 3.2.0
Signed-off-by: David Roman <davidroman96 <AT> gmail.com>
media-libs/libsdl3/libsdl3-3.2.0.ebuild | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/media-libs/libsdl3/libsdl3-3.2.0.ebuild b/media-libs/libsdl3/libsdl3-3.2.0.ebuild
index 5668d3249..1c5799560 100644
--- a/media-libs/libsdl3/libsdl3-3.2.0.ebuild
+++ b/media-libs/libsdl3/libsdl3-3.2.0.ebuild
@@ -13,7 +13,7 @@ S="${WORKDIR}/${MY_P}"
LICENSE="ZLIB"
SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="~amd64"
IUSE="alsa aqua cpu_flags_ppc_altivec cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_x86_avx512f cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 custom-cflags dbus doc fcitx gles1 gles2 +haptic ibus jack +joystick kms opengl oss pipewire pulseaudio sndio +sound static-libs test udev +video vulkan wayland X xscreensaver"
RESTRICT="!test? ( test )"
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/proj/guru:dev commit in: media-libs/libsdl3/
@ 2025-01-31 14:35 David Roman
0 siblings, 0 replies; 4+ messages in thread
From: David Roman @ 2025-01-31 14:35 UTC (permalink / raw
To: gentoo-commits
commit: a87baeec9877cf6fa1ec6b6ae9b9a8a659bc3978
Author: David Roman <davidroman96 <AT> gmail <DOT> com>
AuthorDate: Fri Jan 31 14:31:49 2025 +0000
Commit: David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Fri Jan 31 14:31:49 2025 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=a87baeec
media-libs/libsdl3: remove gles1 USE
Signed-off-by: David Roman <davidroman96 <AT> gmail.com>
media-libs/libsdl3/libsdl3-3.2.0.ebuild | 8 +++-----
media-libs/libsdl3/metadata.xml | 1 -
2 files changed, 3 insertions(+), 6 deletions(-)
diff --git a/media-libs/libsdl3/libsdl3-3.2.0.ebuild b/media-libs/libsdl3/libsdl3-3.2.0.ebuild
index 1c5799560..77497b8bd 100644
--- a/media-libs/libsdl3/libsdl3-3.2.0.ebuild
+++ b/media-libs/libsdl3/libsdl3-3.2.0.ebuild
@@ -15,12 +15,12 @@ LICENSE="ZLIB"
SLOT="0"
KEYWORDS="~amd64"
-IUSE="alsa aqua cpu_flags_ppc_altivec cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_x86_avx512f cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 custom-cflags dbus doc fcitx gles1 gles2 +haptic ibus jack +joystick kms opengl oss pipewire pulseaudio sndio +sound static-libs test udev +video vulkan wayland X xscreensaver"
+CPU_FLAGS_USE="cpu_flags_ppc_altivec cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_x86_avx512f cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2"
+IUSE="alsa aqua ${CPU_FLAGS_USE} custom-cflags dbus doc fcitx gles2 +haptic ibus jack +joystick kms opengl oss pipewire pulseaudio sndio +sound static-libs test udev +video vulkan wayland X xscreensaver"
RESTRICT="!test? ( test )"
REQUIRED_USE="
alsa? ( sound )
fcitx? ( dbus )
- gles1? ( video )
gles2? ( video )
haptic? ( joystick )
ibus? ( dbus )
@@ -71,13 +71,11 @@ COMMON_DEPEND="
RDEPEND="
${COMMON_DEPEND}
fcitx? ( app-i18n/fcitx:* )
- gles1? ( media-libs/mesa[${MULTILIB_USEDEP},gles1(+)] )
gles2? ( media-libs/mesa[${MULTILIB_USEDEP},gles2(+)] )
vulkan? ( media-libs/vulkan-loader )
"
DEPEND="
${COMMON_DEPEND}
- gles1? ( media-libs/libglvnd )
gles2? ( media-libs/libglvnd )
ibus? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
test? ( x11-libs/libX11[${MULTILIB_USEDEP}] )
@@ -158,7 +156,7 @@ src_configure() {
-DSDL_KMSDRM_SHARED=OFF
-DSDL_DUMMYVIDEO=$(usex video)
-DSDL_OPENGL=$(usex opengl)
- -DSDL_OPENGLES=$(use gles1 || use gles2 && echo ON || echo OFF)
+ -DSDL_OPENGLES=$(usex gles2)
-DSDL_VULKAN=$(usex vulkan)
-DSDL_LIBUDEV=$(usex udev)
-DSDL_DBUS=$(usex dbus)
diff --git a/media-libs/libsdl3/metadata.xml b/media-libs/libsdl3/metadata.xml
index dc9c17b6f..09a579301 100644
--- a/media-libs/libsdl3/metadata.xml
+++ b/media-libs/libsdl3/metadata.xml
@@ -25,7 +25,6 @@
</longdescription>
<use>
<flag name="fcitx">Enable support for <pkg>app-i18n/fcitx</pkg></flag>
- <flag name="gles1">include OpenGL ES 1.0 support</flag>
<flag name="haptic">Enable the haptic (force feedback) subsystem</flag>
<flag name="ibus">Enable support for <pkg>app-i18n/ibus</pkg></flag>
<flag name="joystick">Control joystick support (disable at your own risk)</flag>
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/proj/guru:dev commit in: media-libs/libsdl3/
@ 2025-01-31 14:40 David Roman
0 siblings, 0 replies; 4+ messages in thread
From: David Roman @ 2025-01-31 14:40 UTC (permalink / raw
To: gentoo-commits
commit: aba98928c1f76eaf02ab18bcd39d519b179af925
Author: David Roman <davidroman96 <AT> gmail <DOT> com>
AuthorDate: Fri Jan 31 14:40:06 2025 +0000
Commit: David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Fri Jan 31 14:40:06 2025 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=aba98928
media-libs/libsdl3: test USE depends on vulkan
Signed-off-by: David Roman <davidroman96 <AT> gmail.com>
media-libs/libsdl3/libsdl3-3.2.0.ebuild | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/media-libs/libsdl3/libsdl3-3.2.0.ebuild b/media-libs/libsdl3/libsdl3-3.2.0.ebuild
index 77497b8bd..fadecd0b9 100644
--- a/media-libs/libsdl3/libsdl3-3.2.0.ebuild
+++ b/media-libs/libsdl3/libsdl3-3.2.0.ebuild
@@ -28,7 +28,7 @@ REQUIRED_USE="
opengl? ( video )
pulseaudio? ( sound )
sndio? ( sound )
- test? ( static-libs )
+ test? ( static-libs vulkan )
vulkan? ( video )
wayland? ( gles2 )
xscreensaver? ( X )
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/proj/guru:dev commit in: media-libs/libsdl3/
@ 2025-03-05 12:58 demize
0 siblings, 0 replies; 4+ messages in thread
From: demize @ 2025-03-05 12:58 UTC (permalink / raw
To: gentoo-commits
commit: c325d1b6250d4642fc69db610cd96c0a424d5141
Author: demize <demize <AT> unstable <DOT> systems>
AuthorDate: Wed Mar 5 12:57:03 2025 +0000
Commit: demize <demize <AT> unstable <DOT> systems>
CommitDate: Wed Mar 5 12:57:03 2025 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=c325d1b6
media-libs/libsdl3: treeclean, promoted to ::gentoo
Signed-off-by: demize <demize <AT> unstable.systems>
media-libs/libsdl3/Manifest | 1 -
media-libs/libsdl3/libsdl3-3.2.0.ebuild | 191 --------------------------------
media-libs/libsdl3/metadata.xml | 40 -------
3 files changed, 232 deletions(-)
diff --git a/media-libs/libsdl3/Manifest b/media-libs/libsdl3/Manifest
deleted file mode 100644
index b92770963..000000000
--- a/media-libs/libsdl3/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST SDL3-3.2.0.tar.gz 15776789 BLAKE2B a2c35eb9cf6f4344268e2595f1248cb3c6df95448ae6e4259ec69a7d3f286096d2f9bb49cdb031573d3b2854123156a98ca02bf03450b4e6a7c488d4b4f3612e SHA512 b7722883e83cc609b0696f3b9459724912b53fbe6132ea63ad0b302f0821ff79e9497a8d7ad522854c88d6a6607fc5edec88a8f8c3d6f748f9e313b4e84b9b32
diff --git a/media-libs/libsdl3/libsdl3-3.2.0.ebuild b/media-libs/libsdl3/libsdl3-3.2.0.ebuild
deleted file mode 100644
index fadecd0b9..000000000
--- a/media-libs/libsdl3/libsdl3-3.2.0.ebuild
+++ /dev/null
@@ -1,191 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake-multilib flag-o-matic
-
-MY_P="SDL3-${PV}"
-DESCRIPTION="Simple Direct Media Layer"
-HOMEPAGE="https://www.libsdl.org/"
-SRC_URI="https://www.libsdl.org/release/${MY_P}.tar.gz"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="ZLIB"
-SLOT="0"
-KEYWORDS="~amd64"
-
-CPU_FLAGS_USE="cpu_flags_ppc_altivec cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_x86_avx512f cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2"
-IUSE="alsa aqua ${CPU_FLAGS_USE} custom-cflags dbus doc fcitx gles2 +haptic ibus jack +joystick kms opengl oss pipewire pulseaudio sndio +sound static-libs test udev +video vulkan wayland X xscreensaver"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="
- alsa? ( sound )
- fcitx? ( dbus )
- gles2? ( video )
- haptic? ( joystick )
- ibus? ( dbus )
- jack? ( sound )
- opengl? ( video )
- pulseaudio? ( sound )
- sndio? ( sound )
- test? ( static-libs vulkan )
- vulkan? ( video )
- wayland? ( gles2 )
- xscreensaver? ( X )
-"
-
-COMMON_DEPEND="
- virtual/libiconv[${MULTILIB_USEDEP}]
- alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
- dbus? ( >=sys-apps/dbus-1.6.18-r1[${MULTILIB_USEDEP}] )
- ibus? ( app-i18n/ibus )
- jack? ( virtual/jack[${MULTILIB_USEDEP}] )
- kms? (
- >=x11-libs/libdrm-2.4.82[${MULTILIB_USEDEP}]
- >=media-libs/mesa-9.0.0[${MULTILIB_USEDEP},gbm(+)]
- )
- opengl? (
- >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
- >=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
- )
- pipewire? ( media-video/pipewire:=[${MULTILIB_USEDEP}] )
- pulseaudio? ( media-libs/libpulse[${MULTILIB_USEDEP}] )
- sndio? ( media-sound/sndio:=[${MULTILIB_USEDEP}] )
- udev? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
- wayland? (
- >=dev-libs/wayland-1.20[${MULTILIB_USEDEP}]
- gui-libs/libdecor[${MULTILIB_USEDEP}]
- >=media-libs/mesa-9.1.6[${MULTILIB_USEDEP},egl(+),gles2(+),wayland]
- >=x11-libs/libxkbcommon-0.2.0[${MULTILIB_USEDEP}]
- )
- X? (
- >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
- >=x11-libs/libXcursor-1.1.14[${MULTILIB_USEDEP}]
- >=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
- >=x11-libs/libXfixes-6.0.0[${MULTILIB_USEDEP}]
- >=x11-libs/libXi-1.7.2[${MULTILIB_USEDEP}]
- >=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
- xscreensaver? ( >=x11-libs/libXScrnSaver-1.2.2-r1[${MULTILIB_USEDEP}] )
- )
-"
-RDEPEND="
- ${COMMON_DEPEND}
- fcitx? ( app-i18n/fcitx:* )
- gles2? ( media-libs/mesa[${MULTILIB_USEDEP},gles2(+)] )
- vulkan? ( media-libs/vulkan-loader )
-"
-DEPEND="
- ${COMMON_DEPEND}
- gles2? ( media-libs/libglvnd )
- ibus? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
- test? ( x11-libs/libX11[${MULTILIB_USEDEP}] )
- vulkan? ( dev-util/vulkan-headers )
- X? ( x11-base/xorg-proto )
-"
-BDEPEND="
- virtual/pkgconfig
- doc? (
- app-text/doxygen
- media-gfx/graphviz
- )
- wayland? ( >=dev-util/wayland-scanner-1.20 )
-"
-
-MULTILIB_WRAPPED_HEADERS=(
- /usr/include/SDL3/SDL_config.h
- /usr/include/SDL3/SDL_platform.h
- /usr/include/SDL3/begin_code.h
- /usr/include/SDL3/close_code.h
-)
-
-src_prepare() {
- cmake_src_prepare
-
- # Unbundle some headers.
- rm -r src/video/khronos || die
- ln -s "${ESYSROOT}/usr/include" src/video/khronos || die
-}
-
-src_configure() {
- use custom-cflags || strip-flags
-
- local mycmakeargs=(
- -DSDL_STATIC=$(usex static-libs)
- -DSDL_SYSTEM_ICONV=ON
- -DSDL_GCC_ATOMICS=ON
- -DSDL_AUDIO=$(usex sound)
- -DSDL_VIDEO=$(usex video)
- -DSDL_JOYSTICK=$(usex joystick)
- -DSDL_HAPTIC=$(usex haptic)
- -DSDL_POWER=ON
- -DSDL_ASSEMBLY=ON
- -DSDL_ALTIVEC=$(usex cpu_flags_ppc_altivec)
- -DSDL_MMX=$(usex cpu_flags_x86_mmx)
- -DSDL_SSE=$(usex cpu_flags_x86_sse)
- -DSDL_SSE2=$(usex cpu_flags_x86_sse2)
- -DSDL_SSE3=$(usex cpu_flags_x86_sse3)
- -DSDL_SSE4_1=$(usex cpu_flags_x86_sse4_1)
- -DSDL_SSE4_2=$(usex cpu_flags_x86_sse4_2)
- -DSDL_AVX=$(usex cpu_flags_x86_avx)
- -DSDL_AVX2=$(usex cpu_flags_x86_avx2)
- -DSDL_AVX512F=$(usex cpu_flags_x86_avx512f)
- -DSDL_OSS=$(usex oss)
- -DSDL_ALSA=$(usex alsa)
- -DSDL_ALSA_SHARED=OFF
- -DSDL_JACK=$(usex jack)
- -DSDL_JACK_SHARED=OFF
- -DSDL_PIPEWIRE=$(usex pipewire)
- -DSDL_PIPEWIRE_SHARED=OFF
- -DSDL_PULSEAUDIO=$(usex pulseaudio)
- -DSDL_PULSEAUDIO_SHARED=OFF
- -DSDL_WERROR=OFF
- -DSDL_SNDIO=$(usex sndio)
- -DSDL_SNDIO_SHARED=OFF
- -DSDL_DISKAUDIO=$(usex sound)
- -DSDL_DUMMYAUDIO=$(usex sound)
- -DSDL_WAYLAND=$(usex wayland)
- -DSDL_WAYLAND_SHARED=OFF
- -DSDL_WAYLAND_LIBDECOR=$(usex wayland)
- -DSDL_WAYLAND_LIBDECOR_SHARED=OFF
- -DSDL_RPI=OFF
- -DSDL_X11=$(usex X)
- -DSDL_X11_SHARED=OFF
- -DSDL_X11_XSCRNSAVER=$(usex xscreensaver)
- -DSDL_COCOA=$(usex aqua)
- -DSDL_KMSDRM=$(usex kms)
- -DSDL_KMSDRM_SHARED=OFF
- -DSDL_DUMMYVIDEO=$(usex video)
- -DSDL_OPENGL=$(usex opengl)
- -DSDL_OPENGLES=$(usex gles2)
- -DSDL_VULKAN=$(usex vulkan)
- -DSDL_LIBUDEV=$(usex udev)
- -DSDL_DBUS=$(usex dbus)
- -DSDL_IBUS=$(usex ibus)
- -DSDL_CCACHE=OFF
- -DSDL_DIRECTX=OFF
- -DSDL_RPATH=OFF
- -DSDL_VIDEO_RENDER_D3D=OFF
- -DSDL_TESTS=$(usex test)
- )
- cmake-multilib_src_configure
-}
-
-src_compile() {
- multilib-minimal_src_compile
-
- if use doc; then
- cd docs || die
- doxygen || die
- fi
-}
-
-src_test() {
- unset SDL_GAMECONTROLLERCONFIG SDL_GAMECONTROLLER_USE_BUTTON_LABELS
- cmake-multilib_src_test
-}
-
-multilib_src_install_all() {
- rm -r "${ED}"/usr/share/licenses/ || die
- dodoc {BUGS,WhatsNew}.txt {CREDITS,README}.md docs/README*.md
- use doc && dodoc -r docs/output/html/
-}
diff --git a/media-libs/libsdl3/metadata.xml b/media-libs/libsdl3/metadata.xml
deleted file mode 100644
index 09a579301..000000000
--- a/media-libs/libsdl3/metadata.xml
+++ /dev/null
@@ -1,40 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
- <maintainer type="person">
- <email>edgar@edgl.dev</email>
- <name>Edgar Luque</name>
- </maintainer>
- <longdescription>
- Simple DirectMedia Layer is a cross-platform multimedia library
- designed to provide low level access to audio, keyboard, mouse,
- joystick, 3D hardware via OpenGL, and 2D video framebuffer. It is
- used by MPEG playback software, emulators, and many popular games,
- including the award winning Linux port of "Civilization: Call To
- Power."
-
- Simple DirectMedia Layer supports Linux, Windows, BeOS, MacOS
- Classic, MacOS X, FreeBSD, OpenBSD, BSD/OS, Solaris, IRIX, and QNX.
- There is also code, but no official support, for Windows CE,
- AmigaOS, Dreamcast, Atari, NetBSD, AIX, OSF/Tru64, RISC OS, and
- SymbianOS.
-
- SDL is written in C, but works with C++ natively, and has bindings
- to several other languages, including Ada, Eiffel, Java, Lua, ML,
- Perl, PHP, Pike, Python, and Ruby.
- </longdescription>
- <use>
- <flag name="fcitx">Enable support for <pkg>app-i18n/fcitx</pkg></flag>
- <flag name="haptic">Enable the haptic (force feedback) subsystem</flag>
- <flag name="ibus">Enable support for <pkg>app-i18n/ibus</pkg></flag>
- <flag name="joystick">Control joystick support (disable at your own risk)</flag>
- <flag name="kms">Build the KMSDRM video driver</flag>
- <flag name="sndio">Enable support for the <pkg>media-sound/sndio</pkg> backend</flag>
- <flag name="pipewire">Enable support for the <pkg>media-video/pipewire</pkg> audio backend</flag>
- <flag name="sound">Control audio support (disable at your own risk)</flag>
- <flag name="video">Control video support (disable at your own risk)</flag>
- </use>
- <upstream>
- <remote-id type="github">libsdl-org/SDL</remote-id>
- </upstream>
-</pkgmetadata>
^ permalink raw reply related [flat|nested] 4+ messages in thread
end of thread, other threads:[~2025-03-05 12:58 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2025-03-05 12:58 [gentoo-commits] repo/proj/guru:dev commit in: media-libs/libsdl3/ demize
-- strict thread matches above, loose matches on Subject: below --
2025-01-31 14:40 David Roman
2025-01-31 14:35 David Roman
2025-01-31 14:17 David Roman
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox