[gentoo-commits] repo/gentoo:master commit in: media-libs/zint/

["Sam James" <sam@gentoo.org>]

commit:     e3175e7d5bf6f5c0f088c602c3ff645aabfba70d
Author:     Alfred Wingate <parona <AT> protonmail <DOT> com>
AuthorDate: Fri Feb 28 15:42:33 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Mar  5 11:38:35 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e3175e7d

media-libs/zint: add 2.15.0

Signed-off-by: Alfred Wingate <parona <AT> protonmail.com>
Closes: https://github.com/gentoo/gentoo/pull/40818
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-libs/zint/Manifest           |  1 +
 media-libs/zint/zint-2.15.0.ebuild | 58 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/media-libs/zint/Manifest b/media-libs/zint/Manifest
index de2859089c15..0da97c660c1e 100644
--- a/media-libs/zint/Manifest
+++ b/media-libs/zint/Manifest
@@ -1 +1,2 @@
 DIST zint-2.14.0-src.tar.gz 6261059 BLAKE2B 77bed36f42536fa96f1a69206c221d6f5b09eb25008bfe5e389b3f713eefc0299cf5dbb76f98037bb2af01bf21d6dd0c471ccc24876f7be0829e5d331822dde5 SHA512 ef6b7eb32f7df94ad277877741fbfd0e4f3e534107eeb2938425c51a4e83002a87571dbabe0d6449c41bd42978be575a69955105d6323a0b41b58f7bb8e7ab97
+DIST zint-2.15.0-src.tar.gz 6355115 BLAKE2B 15fd6521a504250f6c53e00790e162e1d2ad607dd9162288052b64eb695f62006ef8bb4f4024dacfd0fcfd50c66b0dd7826de2cdd2f7a86e3c522d81ec4a82f9 SHA512 7b5f44837a3a16637be5871ce848747ef520d623d86c88602c4ba8f0fe76705836ccee67a83e7ad0544e56b041dadbe88c5ed0b3219946be924213be18d74e2a

diff --git a/media-libs/zint/zint-2.15.0.ebuild b/media-libs/zint/zint-2.15.0.ebuild
new file mode 100644
index 000000000000..543ef8d6fd42
--- /dev/null
+++ b/media-libs/zint/zint-2.15.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake desktop xdg
+
+DESCRIPTION="Barcode encoding library supporting over 50 symbologies"
+HOMEPAGE="https://www.zint.org.uk/"
+SRC_URI="
+	https://downloads.sourceforge.net/${PN}/${P}-src.tar.gz
+"
+S="${WORKDIR}/${P}-src"
+
+# see LICENSE
+LICENSE="BSD GPL-3+"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64"
+IUSE="gui png test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	gui? (
+		dev-qt/qtbase:6[gui,widgets]
+		dev-qt/qtsvg:6
+		dev-qt/qttools:6[widgets]
+	)
+	png? (
+		media-libs/libpng:=
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DZINT_FRONTEND=ON
+		-DZINT_QT6=$(usex gui)
+		-DZINT_TEST=$(usex test)
+		-DZINT_UNINSTALL=OFF
+		-DZINT_USE_PNG=$(usex png)
+		-DZINT_USE_QT=$(usex gui)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local -x QT_QPA_PLATFORM=offscreen
+	cmake_src_test -j1 # parallel tests cause failures to each other
+}
+
+src_install() {
+	cmake_src_install
+	einstalldocs
+	if use gui; then
+		domenu zint-qt.desktop
+		doicon zint-qt.png
+	fi
+}