[gentoo-commits] repo/gentoo:master commit in: app-crypt/acme/

["Sam James" <sam@gentoo.org>]

commit:     a8fe2cde4038798d22998d0bee2cd2f84aaa7c00
Author:     Thibaud CANALE <thican <AT> thican <DOT> net>
AuthorDate: Wed Feb 12 02:26:47 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Feb 26 10:30:03 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a8fe2cde

app-crypt/acme: add 3.2.0

Closes: https://bugs.gentoo.org/949637
Signed-off-by: Thibaud CANALE <thican <AT> thican.net>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-crypt/acme/Manifest          |  1 +
 app-crypt/acme/acme-3.2.0.ebuild | 65 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/app-crypt/acme/Manifest b/app-crypt/acme/Manifest
index 47b249c84df7..715100bf16f6 100644
--- a/app-crypt/acme/Manifest
+++ b/app-crypt/acme/Manifest
@@ -2,3 +2,4 @@ DIST certbot-2.10.0.gh.tar.gz 2322931 BLAKE2B cb84815ec2db2b4b365f2f2bdee1749263
 DIST certbot-2.11.0.gh.tar.gz 2322114 BLAKE2B d266483d1ffc9f9274df3d5e389ed961758e77e9455a7324132bb2bfe4896db663642a98ac7250d35fbbd60d6aef0d6d2a58f98ad17130958dcfcd61283c2479 SHA512 ba47fc98faaf47278c58e107356371c06039f70ad539d2ca1ac39462bb45c7a6c55ed525d8bd8b11cd35cf807f3423e19309022751a492ba19ded79cfbb6d7f4
 DIST certbot-3.0.1.gh.tar.gz 2325233 BLAKE2B 247505fb500c829de875aa0886f27727de4ccc4f474dd13957b524b84af99e6ee5d1e86f09577422932a498ec9fda24ae36377d117365531ad1f8eddb0148272 SHA512 7aec63ec7705f4e13acb7cef5d770f103222ddf3dca30760c42cd3aeb0531d630111518960c299d89bccba4134b544a329fa02659fac5f977c9ca0321b2d1e2e
 DIST certbot-3.1.0.gh.tar.gz 2299990 BLAKE2B 596f11d4ebb161ee6ba67f4f150a77e081399f11f4e4652923c94297661149c9cb889afc51b46b6111847820823d90edc3a7f1e14c451122f88e6e777bf48795 SHA512 efd0b0c1540a6e3b631fa80eac65c9e8b31b1e5e1242f56d3723ca7e1b1b2121dfe1bf8e122fe9a9b994460553f1fa085b11d1369b3160f5c51c939b2cccd638
+DIST certbot-3.2.0.gh.tar.gz 2309823 BLAKE2B 30ff3f40dc4d7724ad7b9a5eaf48f15fa579d49902dd23d21d8b2d36a4371da05f8c9417b0b2bf49a12565ba9dec180a9d805f22e0e8d1342ae5ea64b43d5219 SHA512 8fc3753dcdc954e143da31a0308269b99abadcdefc008c54c2cabac14a3bf99e757f1007349806a7dabf4a8fe19fd3a365ddea85c1dbeb3b453ae91503ea2288

diff --git a/app-crypt/acme/acme-3.2.0.ebuild b/app-crypt/acme/acme-3.2.0.ebuild
new file mode 100644
index 000000000000..b941c20ff340
--- /dev/null
+++ b/app-crypt/acme/acme-3.2.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+PARENT_PN="certbot"
+PARENT_P="${PARENT_PN}-${PV}"
+
+if [[ "${PV}" == *9999 ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/certbot/certbot.git"
+	EGIT_SUBMODULES=()
+	EGIT_CHECKOUT_DIR="${WORKDIR}/${PARENT_P}"
+else
+	SRC_URI="
+		https://github.com/certbot/certbot/archive/v${PV}.tar.gz
+			-> ${PARENT_P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="An implementation of the ACME protocol"
+HOMEPAGE="
+	https://github.com/certbot/certbot/
+	https://pypi.org/project/acme/
+	https://letsencrypt.org/
+"
+
+S="${WORKDIR}/${PARENT_P}/${PN}"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+BDEPEND="
+	test? (
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+# See certbot/setup.py for acme >= dep
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-43.0.0[${PYTHON_USEDEP}]
+	>=dev-python/josepy-1.13.0[${PYTHON_USEDEP}]
+	<dev-python/josepy-2[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-25.0.0[${PYTHON_USEDEP}]
+	dev-python/pyrfc3339[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2019.3[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.3.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}