[gentoo-commits] repo/gentoo:master commit in: dev-libs/libp11/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     3fc478d9f72c58bbe53a557ba072bb48f8d2be47
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Thu Feb 20 19:00:26 2025 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sun Feb 23 22:16:52 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3fc478d9

dev-libs/libp11: add 0.4.13

Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/40677
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 dev-libs/libp11/Manifest             |  1 +
 dev-libs/libp11/libp11-0.4.13.ebuild | 53 ++++++++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/dev-libs/libp11/Manifest b/dev-libs/libp11/Manifest
index fcc7ee29886a..5ecb26482acb 100644
--- a/dev-libs/libp11/Manifest
+++ b/dev-libs/libp11/Manifest
@@ -1 +1,2 @@
 DIST libp11-0.4.12.tar.gz 516414 BLAKE2B a816749984753a1916dd58860c51b49d316946b59eb3bc839f6a21dcff14de48d7a4937f55fc7ad96a26b914591854d5cf11a1fbac2d5f2f5e04c833973c0e42 SHA512 674cfca2c9eaf162262204c94f9d59d3095dabbc348c1842e758b897e1a5bd4ba08b2d589ec3b2a2d1343a8760eab253e7008dc09ef5b499e2f16385efe5c8cc
+DIST libp11-0.4.13.tar.gz 531147 BLAKE2B ea31e56966cc22e6a6dad2d4923bd89ad110f537172af1dca912d8449df8a6a118ceca45912e7c3d38979dd3e591a9fb110091fd5474b41d6159d489b7c9ba37 SHA512 7936e5e3e37b424caff2ce95b416e67d6bf082676c5a3efb23651d414eacdbdbc1f5e11b05097b500a9d0ca5a97e628f54dd7d1e5ba2a7b5e3a36b3b7b75b5ed

diff --git a/dev-libs/libp11/libp11-0.4.13.ebuild b/dev-libs/libp11/libp11-0.4.13.ebuild
new file mode 100644
index 000000000000..7c7b1abc892a
--- /dev/null
+++ b/dev-libs/libp11/libp11-0.4.13.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Abstraction layer to simplify PKCS#11 API"
+HOMEPAGE="https://github.com/opensc/libp11/wiki"
+SRC_URI="https://github.com/OpenSC/${PN}/releases/download/${P}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/openssl-3.0.0:=[bindist(+)]
+	!~dev-libs/openssl-3.2.0
+	!=dev-libs/openssl-3.2.1-r0
+	!=dev-libs/openssl-3.0.13-r1
+	!=dev-libs/openssl-3.0.13-r0
+	!~dev-libs/openssl-3.0.12
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/softhsm )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+	test? ( >=dev-libs/opensc-0.23.0-r2 )
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local args=(
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_enable doc api-doc)
+	)
+	econf "${args[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}