[gentoo-commits] repo/proj/guru:master commit in: app-text/typst/

["David Roman" <davidroman96@gmail.com>]

commit:     6f45f522e4f783bd8cbf6a02467b4ec6ba65d55b
Author:     Marco Rebhan <me <AT> dblsaiko <DOT> net>
AuthorDate: Thu Feb 20 00:02:01 2025 +0000
Commit:     David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Thu Feb 20 00:03:23 2025 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=6f45f522

app-text/typst: add 9999

Signed-off-by: Marco Rebhan <me <AT> dblsaiko.net>

 app-text/typst/typst-9999.ebuild | 57 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/app-text/typst/typst-9999.ebuild b/app-text/typst/typst-9999.ebuild
new file mode 100644
index 000000000..c16115f2d
--- /dev/null
+++ b/app-text/typst/typst-9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cargo shell-completion
+inherit git-r3
+
+DESCRIPTION="A markup-based typesetting system for the sciences"
+HOMEPAGE="https://typst.app"
+EGIT_REPO_URI="https://github.com/typst/typst.git"
+
+LICENSE="Apache-2.0"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD Boost-1.0
+	CC0-1.0 ISC MIT MPL-2.0 Unicode-3.0 Unicode-DFS-2016 ZLIB
+"
+SLOT="0"
+
+RDEPEND="
+	>=dev-libs/openssl-1.0.2o-r6:0=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-vcs/git
+"
+
+QA_FLAGS_IGNORED="usr/bin/typst"
+
+DOCS=( README.md )
+
+src_unpack() {
+	git-r3_src_unpack
+	cargo_live_src_unpack
+}
+
+src_compile() {
+	export GEN_ARTIFACTS="artifacts/"
+
+	cargo_src_compile
+}
+
+src_install() {
+	local ARTIFACTSDIR='crates/typst-cli/artifacts'
+	cargo_src_install --path "${S}/crates/typst-cli"
+	doman "${ARTIFACTSDIR}/${PN}"*.1
+	dozshcomp "${ARTIFACTSDIR}/_${PN}"
+	dofishcomp "${ARTIFACTSDIR}/${PN}.fish"
+	newbashcomp "${ARTIFACTSDIR}/${PN}.bash" "${PN}"
+
+	einstalldocs
+}
+
+src_test() {
+	cargo_src_test --workspace
+}