[gentoo-commits] repo/proj/guru:master commit in: app-text/komikku/

["David Roman" <davidroman96@gmail.com>]

commit:     95b4da2780877852fdd69583ead85c43c433fe17
Author:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
AuthorDate: Sat Feb 15 13:21:31 2025 +0000
Commit:     David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Sat Feb 15 13:21:31 2025 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=95b4da27

app-text/komikku: add 1.70.0

Signed-off-by: Takuya Wakazono <pastalian46 <AT> gmail.com>

 app-text/komikku/Manifest              |  1 +
 app-text/komikku/komikku-1.70.0.ebuild | 94 ++++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
index c632d9cab..bff0fdacc 100644
--- a/app-text/komikku/Manifest
+++ b/app-text/komikku/Manifest
@@ -1 +1,2 @@
 DIST komikku-1.69.0.tar.gz 5004815 BLAKE2B 64b88ed7968738906aa50de70518e8a7cbfe35c1ff68714b79f1f03fbbfb02cd38479b8bfe76d79e8f1a7071c91dfbda8ebae8e97931ebcad4f0d838084a8e59 SHA512 785ea9e8ec9a2e7e1de0222907f9f0b783cf01d2a230db182f211a5d56ded58d9caaa25358aa878977574430a86961213b65b2df8aa8dcbd1cd12ed08a34ec74
+DIST komikku-1.70.0.tar.gz 5006221 BLAKE2B 640712432ba6eae9f022ba8a530c72c7cf4e2b39451e7d2296129c8a349fbe9ee411c28415e7b835c6f148c105436933f4bdab639d4d82fed88af6bd4523ae21 SHA512 8b0926e446a6b8127018b3ff35607ce9a9fd65acb86fec1159e69b2d4e1f81997b55b013a36ba0dcf9bfe9d15b9d5f896138a446f89201dc3d23c79e04dc68fe

diff --git a/app-text/komikku/komikku-1.70.0.ebuild b/app-text/komikku/komikku-1.70.0.ebuild
new file mode 100644
index 000000000..e67fb5861
--- /dev/null
+++ b/app-text/komikku/komikku-1.70.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils xdg
+
+DESCRIPTION="Manga reader for GNOME"
+HOMEPAGE="https://apps.gnome.org/Komikku/"
+SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="test"
+# Depend on a random server that may or may not be accessible.
+#PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.12:4
+	>=gui-libs/libadwaita-1.6:1[introspection]
+	net-libs/webkit-gtk:6[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	x11-libs/libnotify[introspection]
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/colorthief[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/piexif[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pillow-heif[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest-steps[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	emake setup
+	emake develop
+	emake test
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}