[gentoo-commits] repo/gentoo:master commit in: app-i18n/fcitx-chinese-addons/

["Yixun Lan" <dlan@gentoo.org>]

commit:     9337c44db4895bc61c5809bb036a7aa9911964b5
Author:     Yongxiang Liang <tanekliang <AT> gmail <DOT> com>
AuthorDate: Sat Jan 25 07:10:25 2025 +0000
Commit:     Yixun Lan <dlan <AT> gentoo <DOT> org>
CommitDate: Fri Feb  7 23:57:03 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9337c44d

app-i18n/fcitx-chinese-addons: add 5.1.8

Signed-off-by: Yongxiang Liang <tanekliang <AT> gmail.com>
Signed-off-by: Yixun Lan <dlan <AT> gentoo.org>

 app-i18n/fcitx-chinese-addons/Manifest             |  1 +
 .../fcitx-chinese-addons-5.1.8.ebuild              | 62 ++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/app-i18n/fcitx-chinese-addons/Manifest b/app-i18n/fcitx-chinese-addons/Manifest
index f3a06daeac7f..f7cbbd11a7c7 100644
--- a/app-i18n/fcitx-chinese-addons/Manifest
+++ b/app-i18n/fcitx-chinese-addons/Manifest
@@ -1 +1,2 @@
 DIST fcitx5-chinese-addons-5.1.7_dict.tar.zst 1014942 BLAKE2B fb386dad971b2a8751202733ef593b72d35f9ab8a266f13e6839ea25010cf54e45c287e10d285a02d268f16b5b8f7a3dc6f6f20ffcc79759d8c1ef1136a29cb5 SHA512 fe04699672f034bde328049a19f23b9dbea75a980e706fcaf95138294b8aaaee54eb9ec5c696c343d5e4ce4788216821ad3eb45cd669d94d2f3b67551ae7360f
+DIST fcitx5-chinese-addons-5.1.8_dict.tar.zst 1009572 BLAKE2B 63014424ca758cce38b2bc24c08c9add503e73c1e94e574cbae5d051753c6bca134bc88f4e096c264a3731b556f748e8af9496f78d5348956aa5cc78cbb843a1 SHA512 0fc8d3daf608781b573bfb5239988ae07f251558fc1d963f99962eb33a35d374f4a3e146f5c7bec1c403fa268495075cb3805f6478788fa79220377c72a98ea9

diff --git a/app-i18n/fcitx-chinese-addons/fcitx-chinese-addons-5.1.8.ebuild b/app-i18n/fcitx-chinese-addons/fcitx-chinese-addons-5.1.8.ebuild
new file mode 100644
index 000000000000..8a30945075c0
--- /dev/null
+++ b/app-i18n/fcitx-chinese-addons/fcitx-chinese-addons-5.1.8.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="fcitx5-chinese-addons"
+
+inherit cmake unpacker xdg
+
+DESCRIPTION="Addons related to Chinese, including IME previous bundled inside fcitx4."
+HOMEPAGE="https://github.com/fcitx/fcitx5-chinese-addons"
+SRC_URI="https://download.fcitx-im.org/fcitx5/${MY_PN}/${MY_PN}-${PV}_dict.tar.zst"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~riscv ~x86"
+IUSE="+data +gui webengine +cloudpinyin +qt5 qt6 lua +opencc test"
+REQUIRED_USE="
+	webengine? ( gui )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=app-i18n/fcitx-5.1.12:5
+	>=app-i18n/libime-1.1.7:5[data?]
+	>=dev-libs/boost-1.61:=
+	cloudpinyin? ( net-misc/curl )
+	lua? ( app-i18n/fcitx-lua:5 )
+	opencc? ( app-i18n/opencc:= )
+	gui? (
+		qt5? (
+			dev-qt/qtconcurrent:5
+			app-i18n/fcitx-qt:5[qt5,-onlyplugin]
+			webengine? ( dev-qt/qtwebengine:5[widgets] )
+		)
+		qt6? (
+			dev-qt/qtbase:6[concurrent]
+			app-i18n/fcitx-qt:5[qt6,-onlyplugin]
+			webengine? ( dev-qt/qtwebengine:6[widgets] )
+		)
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	kde-frameworks/extra-cmake-modules:0
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_BROWSER=$(usex webengine)
+		-DENABLE_CLOUDPINYIN=$(usex cloudpinyin)
+		-DENABLE_DATA=$(usex data)
+		-DENABLE_GUI=$(usex gui)
+		-DENABLE_OPENCC=$(usex opencc)
+		-DENABLE_TEST=$(usex test)
+		-DUSE_WEBKIT=no
+		-DUSE_QT6=$(usex qt6)
+	)
+	cmake_src_configure
+}