[gentoo-commits] repo/proj/guru:dev commit in: dev-python/dateparser/

["Takuya Wakazono" <pastalian46@gmail.com>]

commit:     1a57e978bb399e301c5d90ac3ca898765e20639d
Author:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
AuthorDate: Thu Feb  6 13:02:00 2025 +0000
Commit:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
CommitDate: Thu Feb  6 13:02:00 2025 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=1a57e978

dev-python/dateparser: add 1.2.1

Closes: https://bugs.gentoo.org/922955
Signed-off-by: Takuya Wakazono <pastalian46 <AT> gmail.com>

 dev-python/dateparser/Manifest                |  1 +
 dev-python/dateparser/dateparser-1.2.1.ebuild | 61 +++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-python/dateparser/Manifest b/dev-python/dateparser/Manifest
index 44c8fffea..1dd5921b2 100644
--- a/dev-python/dateparser/Manifest
+++ b/dev-python/dateparser/Manifest
@@ -1 +1,2 @@
 DIST dateparser-1.2.0.tar.gz 307260 BLAKE2B b4611dfc4fccaf5f129e4d9aa3debe4a6d4242a44896305b909e6c34728ba153be92659b2f0c3a5da028d3863789d9c3a4236676087346b5f3f4aeb1f57b7a1e SHA512 74d5975f515dee096d83d10b72e5dc66ab197d50f24c129560ffb87eef4abd1422d8236555496d1ab1c0bfb832729e9c0d3ea2ca2c9c49da19963f0f2c1c1eb4
+DIST dateparser-1.2.1.tar.gz 309924 BLAKE2B 09b7cf4148edea37bb80d1734b2f5a3ddac7965e6d46bc1775f2f0807d3421c80bd3927dd62135a80adc99451a85a2961b61335784d191cfdd1fdc51b3d81298 SHA512 85e1c5cabb8acebd63ec60c0913ac89b362b64edfbe5af06bcd5968ed7be6383d4035ec9f45afadc0d10fc95a3f538702285d75365c4f8e4522ac9643f4ed4da

diff --git a/dev-python/dateparser/dateparser-1.2.1.ebuild b/dev-python/dateparser/dateparser-1.2.1.ebuild
new file mode 100644
index 000000000..7866770ea
--- /dev/null
+++ b/dev-python/dateparser/dateparser-1.2.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Date parsing library designed to parse dates from HTML pages"
+HOMEPAGE="
+	https://pypi.org/project/dateparser/
+	https://github.com/scrapinghub/dateparser
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/regex[${PYTHON_USEDEP}]
+	dev-python/tzlocal[${PYTHON_USEDEP}]
+"
+BDEPEND="test? (
+	dev-libs/fastText[python,${PYTHON_USEDEP}]
+	dev-python/convertdate[${PYTHON_USEDEP}]
+	dev-python/hijridate[${PYTHON_USEDEP}]
+	dev-python/langdetect[${PYTHON_USEDEP}]
+	dev-python/parameterized[${PYTHON_USEDEP}]
+)"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+
+python_test() {
+	# Need to set TZ when testing with gentoo docker images.
+	# Their /etc/{timezone,localtime} are inconsistent, which causes
+	# to tests to fail.
+	local -x TZ=UTC
+
+	local EPYTEST_IGNORE=(
+		# tests that require network
+		tests/test_dateparser_data_integrity.py
+	)
+	local EPYTEST_DESELECT=(
+		# tests that require network
+		tests/test_language_detect.py::CustomLangDetectParserTest::test_custom_language_detect_fast_text_{0,1}
+	)
+
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "calendars support" "dev-python/hijridate dev-python/convertdate"
+	optfeature "fasttext support" "dev-libs/fastText[python]"
+	optfeature "langdetect support" dev-python/langdetect
+}