[gentoo-commits] repo/gentoo:master commit in: dev-python/opentelemetry-api/

["Michał Górny" <mgorny@gentoo.org>]

commit:     6bbb0c750c79519536fb3744331b9711a84cc759
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Feb  5 06:44:28 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Feb  5 08:05:46 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6bbb0c75

dev-python/opentelemetry-api: Bump to 1.30.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/opentelemetry-api/Manifest              |  1 +
 .../opentelemetry-api-1.30.0.ebuild                | 61 ++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-python/opentelemetry-api/Manifest b/dev-python/opentelemetry-api/Manifest
index 68742ea9263e..cf4696cb6b02 100644
--- a/dev-python/opentelemetry-api/Manifest
+++ b/dev-python/opentelemetry-api/Manifest
@@ -1 +1,2 @@
 DIST opentelemetry-python-1.29.0.gh.tar.gz 1178849 BLAKE2B f26914c14025e77486df0c587318f96c4b27bd2caeacc877091300fc054f4670a642ca6fcafa909b986a97168ab004d4a969a05571ee38ab7797b3b38f4cc91f SHA512 92c90e6a684d8cfab3bba4d72612ccf53ae54cdd9784e3434b25adc3730fe114f21fd7aa21da80edf6e0e7c80b39c64ee31fb16f68b04809289bbf5d49d4ca2e
+DIST opentelemetry-python-1.30.0.gh.tar.gz 1189401 BLAKE2B 10a52a24625ee80f0b68e7fad05f770098be75c21ccf0230a786a1ffc4b3fb23daf251dc129bab840d22ff2ac9a6bab1c84e55c644abcd1b475dc7a5872447a5 SHA512 cd74100aa60639b3722f2747bd19dae42bffbfca4007837a6cf8db61a408c59601064c9718782b9f6ebeee7a30a454e03a09950b2b00845d642f6452a894674b

diff --git a/dev-python/opentelemetry-api/opentelemetry-api-1.30.0.ebuild b/dev-python/opentelemetry-api/opentelemetry-api-1.30.0.ebuild
new file mode 100644
index 000000000000..ccacff2cff89
--- /dev/null
+++ b/dev-python/opentelemetry-api/opentelemetry-api-1.30.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P="opentelemetry-python-${PV}"
+DESCRIPTION="OpenTelemetry Python API"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://pypi.org/project/opentelemetry-api/
+	https://github.com/open-telemetry/opentelemetry-python/
+"
+SRC_URI="
+	https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/${PN}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/deprecated-1.2.6[${PYTHON_USEDEP}]
+	dev-python/importlib-metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# Unnecessary restriction
+	sed -i -e '/importlib-metadata/s:, <= [0-9.]*::' pyproject.toml || die
+}
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	for dep in opentelemetry-semantic-conventions opentelemetry-sdk \
+		tests/opentelemetry-test-utils
+	do
+		pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}