[gentoo-commits] repo/gentoo:master commit in: dev-dotnet/dotnet-sdk-bin/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     57c185c3022064d26b580cb724ddfcb7473c6fa2
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Tue Feb  4 11:55:33 2025 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Tue Feb  4 12:52:26 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=57c185c3

dev-dotnet/dotnet-sdk-bin: bump to 9.0.102

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-dotnet/dotnet-sdk-bin/Manifest                 |   6 +
 .../dotnet-sdk-bin/dotnet-sdk-bin-9.0.102.ebuild   | 171 +++++++++++++++++++++
 2 files changed, 177 insertions(+)

diff --git a/dev-dotnet/dotnet-sdk-bin/Manifest b/dev-dotnet/dotnet-sdk-bin/Manifest
index 78ec035e6a60..f17854647789 100644
--- a/dev-dotnet/dotnet-sdk-bin/Manifest
+++ b/dev-dotnet/dotnet-sdk-bin/Manifest
@@ -34,3 +34,9 @@ DIST dotnet-sdk-9.0.101-linux-musl-arm.tar.gz 204932960 BLAKE2B ff45915cc58e2c5a
 DIST dotnet-sdk-9.0.101-linux-musl-arm64.tar.gz 205372709 BLAKE2B 7dc36729384f4b701c89a57de5deb99f3382abc7b644ff896a8b606bf73f122461a12ac1ab12ca9472dfa3bc214a9c332d7123ff03a7fa51405e533c85f7341f SHA512 6a6d6a6d6dfbdacb48374c0ac9bdb1c93781f3970c8778b0bee1f159a22b00176868264e605331fef833cb9fed829b4ffd414276d0d1140a8b0e257195c2f374
 DIST dotnet-sdk-9.0.101-linux-musl-x64.tar.gz 210448851 BLAKE2B 36ff6a5d671950d44a39456f2812004074697e8990e4576fa00480cd826c85671a12710c4eaadd846b0c738220efd4e1c03e07529b0bb468b5352f368001ceee SHA512 3f4e14fb7b52dfb57b1e31cb5973e6e0a338f7f030f12b3082d3b55f12f9587ddf4926a7c5fcf86b7671397e44f8e5c20fb949d70e9a7dd0dc27be73a548dffc
 DIST dotnet-sdk-9.0.101-linux-x64.tar.gz 210346874 BLAKE2B 3695630974f5f8bde4a3b2071072e4afbb848446db0161c061ed59e11b56073af38493256cfdea41cc6692a040dd180cc9af4302af55789a491e72f96741c0f5 SHA512 91b37efd64242e5f1f3c2025d183eb34e17f3a9271c5602f29ddf794845eee103723ef955ed869788ebf5a731e8ddc69328799c92c64cb118e1328d259a6ad01
+DIST dotnet-sdk-9.0.102-linux-arm.tar.gz 205235672 BLAKE2B 359e8c18382874b7b0910f4a97eca3141f9ab806c427b971b45df8a7a73d4b93936dac01a5e7e45fa5857d476ed6afa89c2471e7f4b95f5c47c98dbab3abf50f SHA512 2c4c69d46c3e57ed990518a9d82963665d835c66a57da54b9d21e22c2a20e8018020dcb190eef54dfe68c001fcce385361eb2bd29896311a1683599ff9e6a777
+DIST dotnet-sdk-9.0.102-linux-arm64.tar.gz 205648559 BLAKE2B 858500dfc5d13f862a20cb5d68af8f36a949d293098a8d196c9c026f8a9369506c21b8724082cba5bc5eecd6903e97c46e9083408762dcb59d1c098e6bd93559 SHA512 cb78931dcbb948a504891f112f11215f2792d169f0a0b53eaa81c03fc4ba78d31a91c60a41809ae6e2ddcae8640085a159e492035cedfda68d265bbeb4bf8b2e
+DIST dotnet-sdk-9.0.102-linux-musl-arm.tar.gz 205458058 BLAKE2B d6db6f5725a3fb7e99ba38c96a9f0e4da70bb3b9ebb455665922fd8bab3f0a0add75f1e5a3c43393e53a87a0a9e4bce71d98d13148872d8bbed14be2c1cc5c07 SHA512 e363e3d4edca93830d18bcebd41e01bf2856b095ae70e1a24b0533abb0a507e4c1f1542ff3046c285689318dac7e2b5c71a166bcb5933a8ab68d800bf3eedf03
+DIST dotnet-sdk-9.0.102-linux-musl-arm64.tar.gz 205773161 BLAKE2B 0a939d986d15dbc215785529faef8aaca045026469e4cc5ead736cdb764e67882e91b08626d33452ecbd0c95f7834574c9d2685a34c3de491b8b4c96e9e53b8f SHA512 5da98e46c280e21c3734a0c9081e7ddb78ad62775a51a129b42a6f021330d263a875da2f44a7aafe8156e7c9ae0f9bb21b502057692b360f2afe0882f0e61132
+DIST dotnet-sdk-9.0.102-linux-musl-x64.tar.gz 210712549 BLAKE2B b9eaed3f609a75704e8707b69643b0539e2d10ecd69443f8e6feb6197315fe993de8c14a2543f58ac64c91480e0acff2e20647f7dacc46c830d12b517dbd4663 SHA512 60e091854d17da9a6011569f0a4819eac72ce6fe06d01757feeb83ad56c17645fa438257631ecbbf6ee94ac3a973eff9ad4d3e12deadda3eb41c1b69ca8d5308
+DIST dotnet-sdk-9.0.102-linux-x64.tar.gz 210604728 BLAKE2B fb95b1694a2e54bb05f323d546c4077b8e574ba39ffe8b3bdf33d72fa6e45b2dd13d38eb52b08ddcf1fe143fa596a3ca1647b980f8de7e43fea316b8b6eca1a7 SHA512 f093507ef635c3f8e572bf7b6ea7e144b85ccf6b7c6f914d3f182f782200a6088728663df5c9abe0638c9bd273fde3769ec824a6516f5fce734c4a4664ce3099

diff --git a/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-9.0.102.ebuild b/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-9.0.102.ebuild
new file mode 100644
index 000000000000..1986abec12bc
--- /dev/null
+++ b/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-9.0.102.ebuild
@@ -0,0 +1,171 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+SDK_SLOT="$(ver_cut 1-2)"
+RUNTIME_SLOT="${SDK_SLOT}.0"
+
+DESCRIPTION=".NET is a free, cross-platform, open-source developer platform"
+HOMEPAGE="https://dotnet.microsoft.com/
+	https://github.com/dotnet/dotnet/"
+SRC_URI="
+amd64? (
+	elibc_glibc? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-x64.tar.gz
+	)
+	elibc_musl? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-x64.tar.gz
+	)
+)
+arm? (
+	elibc_glibc? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm.tar.gz
+	)
+	elibc_musl? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm.tar.gz
+	)
+)
+arm64? (
+	elibc_glibc? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm64.tar.gz
+	)
+	elibc_musl? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm64.tar.gz
+	)
+)
+"
+S="${WORKDIR}"
+
+LICENSE="MIT"
+SLOT="${SDK_SLOT}/${RUNTIME_SLOT}"
+# See bug https://bugs.gentoo.org/932377
+KEYWORDS="~amd64 ~arm ~arm64"
+
+# STRIP="llvm-strip" corrupts some executables when using the patchelf hack,
+# bug https://bugs.gentoo.org/923430
+RESTRICT="splitdebug strip"
+
+CURRENT_NUGETS_DEPEND="
+	~dev-dotnet/dotnet-runtime-nugets-${RUNTIME_SLOT}
+"
+EXTRA_NUGETS_DEPEND="
+	~dev-dotnet/dotnet-runtime-nugets-6.0.36
+	~dev-dotnet/dotnet-runtime-nugets-7.0.20
+	~dev-dotnet/dotnet-runtime-nugets-8.0.12
+"
+NUGETS_DEPEND="
+	${CURRENT_NUGETS_DEPEND}
+	${EXTRA_NUGETS_DEPEND}
+"
+
+RDEPEND="
+	app-crypt/mit-krb5:0/0
+	dev-libs/icu
+	dev-util/lttng-ust:0/2.12
+	sys-libs/zlib:0/1
+"
+BDEPEND="
+	dev-util/patchelf
+"
+IDEPEND="
+	app-eselect/eselect-dotnet
+"
+PDEPEND="
+	${NUGETS_DEPEND}
+"
+
+QA_PREBUILT="*"
+
+MUSL_BAD_LINKS=(
+	apphost
+	createdump
+	dotnet
+	libSystem.Globalization.Native.so
+	libSystem.IO.Compression.Native.so
+	libSystem.Native.so
+	libSystem.Net.Security.Native.so
+	libSystem.Security.Cryptography.Native.OpenSsl.so
+	libclrgc.so
+	libclrjit.so
+	libcoreclr.so
+	libcoreclrtraceptprovider.so
+	libdbgshim.so
+	libhostfxr.so
+	libhostpolicy.so
+	libmscordaccore.so
+	libmscordbi.so
+	libnethost.so
+	singlefilehost
+)
+MUSL_BAD_SONAMES=(
+	libc.musl-aarch64.so.1
+	libc.musl-armv7.so.1
+	libc.musl-x86_64.so.1
+)
+
+src_prepare() {
+	default
+
+	# Fix musl libc SONAME links, bug https://bugs.gentoo.org/894760
+	if use elibc_musl ; then
+		local musl_bad_link
+		local musl_bad_link_path
+		local musl_bad_soname
+
+		for musl_bad_link in "${MUSL_BAD_LINKS[@]}" ; do
+			while read -r musl_bad_link_path ; do
+				# Skip if file either does not end with ".so" or is not executable.
+				# Using "case" here for easier matching in case we have to add
+				# a special exception.
+				case "${musl_bad_link_path}" in
+					*.so )
+						:
+						;;
+					* )
+						if [[ ! -x "${musl_bad_link_path}" ]] ; then
+							continue
+						fi
+						;;
+				esac
+
+				einfo "Fixing musl libc link for ${musl_bad_link_path}"
+
+				for musl_bad_soname in "${MUSL_BAD_SONAMES[@]}" ; do
+					patchelf --remove-needed "${musl_bad_soname}" "${musl_bad_link_path}" || die
+				done
+
+				patchelf --add-needed libc.so "${musl_bad_link_path}" || die
+			done < <(find . -type f -name "${musl_bad_link}")
+		done
+	fi
+
+	# Remove static libraries, bug https://bugs.gentoo.org/825774
+	find ./packs -type f -name "libnethost.a" -delete || die
+}
+
+src_install() {
+	local dest="opt/${PN}-${SDK_SLOT}"
+	dodir "${dest%/*}"
+
+	# Create a magic workloads file, bug #841896
+	local featureband="$(( $(ver_cut 3) / 100 * 100 ))"       # e.g. 404 -> 400
+	local workloads="metadata/workloads/${SDK_SLOT}.${featureband}"
+
+	mkdir -p "${S}/${workloads}" || die
+	touch "${S}/${workloads}/userlocal" || die
+
+	mv "${S}" "${ED}/${dest}" || die
+	mkdir "${S}" || die
+
+	fperms 0755 "/${dest}"
+	dosym "../../${dest}/dotnet" "/usr/bin/dotnet-bin-${SDK_SLOT}"
+}
+
+pkg_postinst() {
+	eselect dotnet update ifunset
+}
+
+pkg_postrm() {
+	eselect dotnet update ifunset
+}