[gentoo-commits] repo/proj/guru:master commit in: app-text/komikku/

["David Roman" <davidroman96@gmail.com>]

commit:     061880483ce7d41b439aa95b23030dd7c3e3cb9c
Author:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
AuthorDate: Mon Feb  3 11:13:28 2025 +0000
Commit:     David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Mon Feb  3 11:20:13 2025 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=06188048

app-text/komikku: add 1.69.0

Signed-off-by: Takuya Wakazono <pastalian46 <AT> gmail.com>

 app-text/komikku/Manifest              |  1 +
 app-text/komikku/komikku-1.69.0.ebuild | 94 ++++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
index a33f9274d..1d34bcd9a 100644
--- a/app-text/komikku/Manifest
+++ b/app-text/komikku/Manifest
@@ -1,2 +1,3 @@
 DIST komikku-1.57.0.tar.gz 4962367 BLAKE2B f778fdcf1c33f9d1393a6dc2139c812717fe73763eac4cb181a94969eb693fc723b88dbfcb7166764f6d8ccd6ae49ec6788fccc962398760acd549a9a5ded04a SHA512 0b6dc2b4ce3537a8069e48606ea9e835234260500736a78e3966374fa6e5c0c2f48dbeeca76d4ca701e606381195310bb24f38ef1977fb8610138e510ea7150e
 DIST komikku-1.67.0.tar.gz 4967214 BLAKE2B 54d4530fddefc2b2dbfe4683b369a41081468e7af730014a9a0d2c23d42e0ad929a65cbb59e610d681371a6e6ce5853fb21ac03b3792ccdf062469e5ef28bd33 SHA512 e5efa79a300a8dabb7a07e438bc2f3ade3c331ff0976b146875841f0ad569970f96acd2a4dae2f1f4d970345314e548021cca5d77577e04b7d66c24f27e2e15c
+DIST komikku-1.69.0.tar.gz 5004815 BLAKE2B 64b88ed7968738906aa50de70518e8a7cbfe35c1ff68714b79f1f03fbbfb02cd38479b8bfe76d79e8f1a7071c91dfbda8ebae8e97931ebcad4f0d838084a8e59 SHA512 785ea9e8ec9a2e7e1de0222907f9f0b783cf01d2a230db182f211a5d56ded58d9caaa25358aa878977574430a86961213b65b2df8aa8dcbd1cd12ed08a34ec74

diff --git a/app-text/komikku/komikku-1.69.0.ebuild b/app-text/komikku/komikku-1.69.0.ebuild
new file mode 100644
index 000000000..e67fb5861
--- /dev/null
+++ b/app-text/komikku/komikku-1.69.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils xdg
+
+DESCRIPTION="Manga reader for GNOME"
+HOMEPAGE="https://apps.gnome.org/Komikku/"
+SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="test"
+# Depend on a random server that may or may not be accessible.
+#PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.12:4
+	>=gui-libs/libadwaita-1.6:1[introspection]
+	net-libs/webkit-gtk:6[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	x11-libs/libnotify[introspection]
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/colorthief[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/piexif[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pillow-heif[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest-steps[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	emake setup
+	emake develop
+	emake test
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}