[gentoo-commits] repo/gentoo:master commit in: net-p2p/qbittorrent/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     a9f0b164f2c0df3304af6e8f5ffa388c85cf401d
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 28 19:44:36 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Feb  2 09:11:18 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a9f0b164

net-p2p/qbittorrent: drop 4.6.7

Closes: https://github.com/gentoo/gentoo/pull/39198
Bug: https://bugs.gentoo.org/942569
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 net-p2p/qbittorrent/Manifest                 |   2 -
 net-p2p/qbittorrent/qbittorrent-4.6.7.ebuild | 145 ---------------------------
 2 files changed, 147 deletions(-)

diff --git a/net-p2p/qbittorrent/Manifest b/net-p2p/qbittorrent/Manifest
index 7f28815e77c6..a68fed030794 100644
--- a/net-p2p/qbittorrent/Manifest
+++ b/net-p2p/qbittorrent/Manifest
@@ -1,5 +1,3 @@
-DIST qbittorrent-4.6.7.tar.xz 4539016 BLAKE2B 8565fdc298e5085b10b52442874ce2d9b9f253ba57bb2d1bef065d603847e5d3d838197ea2077aa80cc3db56aea4b1100fad2d7a0398fa13128d4a064286afc6 SHA512 3664c89f91a3443c74a5c76da8f66ab595bf4f48cbba2421a287d4f8bf780e06605cd0a6fa9598a5ab09e876a46d31b2f85461ef65f17410df1914acd9d37262
-DIST qbittorrent-4.6.7.tar.xz.asc 849 BLAKE2B e63d1fc1c8c6b9a70551bd717a2614b8548bd93656b578f4289d720c2784508ca90971f995fa6c8b6dc26ed6a7f976d294e44d4e384bb3de30791f26ff930017 SHA512 820e329921d23409560fa2a2f3e714b233154783da5bb8fdcf7ed70c90df69d5140d8159f8d52dc1a9b5cc32306580a08e56c02b55f0e2b00c16cbf9f6982baa
 DIST qbittorrent-5.0.1.tar.xz 4539900 BLAKE2B c10c183750929da0a1c365668472495afcdc8e677e2cfc8693ade0bb5ad97c522eeb2a0f4ad81d4e997419ad58a596ad6ad0185273d2c0f2c920f1e7239a3326 SHA512 a7bbfb762f60bea9cb0fa3870753171fb6f946790da0e4125fa11d6c1cd6a7548307c506e9947e0676d0c66ee7cdbaefa80a513c436d2e0d0c6383bc390c12d2
 DIST qbittorrent-5.0.1.tar.xz.asc 849 BLAKE2B 881abc7bfb0b65da82e2f5fdaca4ee152b7dafcd11e425416244e682f94af8f68b6f365cc36361909179d9d867047a532efae54dc5454c371cef7b05c7dc8830 SHA512 a75860dcc9e1fc9162c7460b56723586d6ed434f01c2d4e628884e5146ef59d904c864eeff80753d374c2eeb86d59c90a954518b3a2b68d279787313fcfd8a96
 DIST qbittorrent-5.0.2.tar.xz 4544624 BLAKE2B 6e651f3aa4254344a9f41cf507154062ee829d34b7dff553d4745594a5d5f73e71af30bc525adb460c56e8e76afe73d1630dd5b9e8dfae75e0222501a0dde897 SHA512 1834a3bce051c1c707c4cf7282241a2985a4d090c69cc62d634033b3c85cac2421a16d510041e5961c31202ae8f304d726c320819591bc4a093d6fd39c80b517

diff --git a/net-p2p/qbittorrent/qbittorrent-4.6.7.ebuild b/net-p2p/qbittorrent/qbittorrent-4.6.7.ebuild
deleted file mode 100644
index d003502d13d5..000000000000
--- a/net-p2p/qbittorrent/qbittorrent-4.6.7.ebuild
+++ /dev/null
@@ -1,145 +0,0 @@
-# Copyright 2023-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake edo multibuild systemd verify-sig xdg
-
-DESCRIPTION="BitTorrent client in C++ and Qt"
-HOMEPAGE="https://www.qbittorrent.org"
-
-if [[ ${PV} == *9999 ]]; then
-	EGIT_REPO_URI="https://github.com/qbittorrent/qBittorrent.git"
-	inherit git-r3
-else
-	SRC_URI="
-		https://downloads.sourceforge.net/qbittorrent/${P}.tar.xz
-		verify-sig? ( https://downloads.sourceforge.net/qbittorrent/${P}.tar.xz.asc )
-	"
-	KEYWORDS="amd64 ~arm ~arm64 ~ppc64 ~riscv x86"
-
-	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-qbittorrent )"
-	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/qBittorrent.asc
-fi
-
-LICENSE="GPL-2"
-SLOT="0"
-IUSE="+dbus +gui qt6 systemd test webui"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="|| ( gui webui )
-	dbus? ( gui )
-"
-
-RDEPEND="
-	>=dev-libs/openssl-1.1.1:=
-	>=net-libs/libtorrent-rasterbar-1.2.19:=
-	>=sys-libs/zlib-1.2.11
-	qt6? ( >=dev-qt/qtbase-6.2:6[network,ssl,sql,sqlite,xml] )
-	!qt6? (
-		dev-qt/qtcore:5
-		dev-qt/qtnetwork:5[ssl]
-		dev-qt/qtsql:5[sqlite]
-		dev-qt/qtxml:5
-	)
-	gui? (
-		!qt6? (
-			dev-qt/qtgui:5
-			dev-qt/qtsvg:5
-			dev-qt/qtwidgets:5
-			dbus? ( dev-qt/qtdbus:5 )
-		)
-		qt6? (
-			>=dev-qt/qtbase-6.2:6[dbus?,gui,widgets]
-			>=dev-qt/qtsvg-6.2:6
-		)
-	)
-	webui? (
-		acct-group/qbittorrent
-		acct-user/qbittorrent
-	)
-"
-DEPEND="
-	${RDEPEND}
-	>=dev-libs/boost-1.71
-	test? (
-		!qt6? ( dev-qt/qttest:5 )
-	)"
-BDEPEND+="
-	!qt6? ( dev-qt/linguist-tools:5 )
-	qt6? ( >=dev-qt/qttools-6.2:6[linguist] )
-	virtual/pkgconfig"
-
-DOCS=( AUTHORS Changelog CONTRIBUTING.md README.md )
-
-src_prepare() {
-	MULTIBUILD_VARIANTS=()
-	use gui && MULTIBUILD_VARIANTS+=( gui )
-	use webui && MULTIBUILD_VARIANTS+=( nogui )
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	my_src_configure() {
-		local mycmakeargs=(
-			# musl lacks execinfo.h
-			-DSTACKTRACE=$(usex !elibc_musl)
-			# More verbose build logs are preferable for bug reports
-			-DVERBOSE_CONFIGURE=ON
-			-DQT6=$(usex qt6)
-			-DWEBUI=$(usex webui)
-			-DTESTING=$(usex test)
-		)
-
-		if [[ ${MULTIBUILD_VARIANT} == "gui" ]]; then
-			# We do this in multibuild, see bug #839531 for why.
-			# Fedora has to do the same thing.
-			mycmakeargs+=(
-				-DGUI=ON
-				-DDBUS=$(usex dbus)
-				-DSYSTEMD=OFF
-			)
-		else
-			mycmakeargs+=(
-				-DGUI=OFF
-				-DDBUS=OFF
-			)
-
-			use systemd && mycmakeargs+=(
-				# The systemd service calls qbittorrent-nox, which is only
-				# installed when GUI=OFF.
-				-DSYSTEMD=ON
-				-DSYSTEMD_SERVICES_INSTALL_DIR="$(systemd_get_systemunitdir)"
-			)
-		fi
-
-		cmake_src_configure
-	}
-
-	multibuild_foreach_variant my_src_configure
-}
-
-src_compile() {
-	multibuild_foreach_variant cmake_src_compile
-}
-
-src_test() {
-	my_src_test() {
-		# cmake does not detect tests by default, if you use enable_testing
-		# in a subdirectory instead of the root CMakeLists.txt
-		cd "${BUILD_DIR}"/test || die
-		edo ctest .
-	}
-
-	multibuild_foreach_variant my_src_test
-}
-
-src_install() {
-	multibuild_foreach_variant cmake_src_install
-	einstalldocs
-
-	if use webui; then
-		newconfd "${FILESDIR}/${PN}.confd" "${PN}"
-		newinitd "${FILESDIR}/${PN}.initd" "${PN}"
-	fi
-}