[gentoo-commits] repo/gentoo:master commit in: llvm-core/llvm-toolchain-symlinks/

["Michał Górny" <mgorny@gentoo.org>]

commit:     766cb241f185bf1e35a505bbe685ad6b02ff55b8
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Feb  1 07:59:06 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Feb  1 08:05:37 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=766cb241

llvm-core/llvm-toolchain-symlinks: main is now 21*

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../llvm-toolchain-symlinks-21.ebuild              | 48 ++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/llvm-core/llvm-toolchain-symlinks/llvm-toolchain-symlinks-21.ebuild b/llvm-core/llvm-toolchain-symlinks/llvm-toolchain-symlinks-21.ebuild
new file mode 100644
index 000000000000..d0685cb7ad8d
--- /dev/null
+++ b/llvm-core/llvm-toolchain-symlinks/llvm-toolchain-symlinks-21.ebuild
@@ -0,0 +1,48 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib
+
+DESCRIPTION="Symlinks to use LLVM on binutils-free system"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:LLVM"
+S=${WORKDIR}
+
+LICENSE="public-domain"
+SLOT="${PV}"
+IUSE="multilib-symlinks +native-symlinks"
+
+RDEPEND="
+	llvm-core/llvm:${SLOT}
+"
+
+src_install() {
+	use native-symlinks || return
+
+	local tools=(
+		addr2line ar dlltool nm objcopy objdump ranlib readelf size
+		strings strip windres
+		# https://bugs.gentoo.org/936068
+		cxxfilt:c++filt
+	)
+	local chosts=( "${CHOST}" )
+	if use multilib-symlinks; then
+		local abi
+		for abi in $(get_all_abis); do
+			chosts+=( "$(get_abi_CHOST "${abi}")" )
+		done
+	fi
+
+	local chost t
+	local dest=/usr/lib/llvm/${SLOT}/bin
+	dodir "${dest}"
+	for t in "${tools[@]}"; do
+		dosym "llvm-${t%:*}" "${dest}/${t#*:}"
+	done
+	for chost in "${chosts[@]}"; do
+		for t in "${tools[@]}"; do
+			dosym "llvm-${t%:*}" "${dest}/${chost}-${t#*:}"
+		done
+	done
+}