[gentoo-commits] repo/gentoo:master commit in: net-libs/qxmpp/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     98e96f3c8b9e01657255152b81d010fd8f09a1ab
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 31 12:40:35 2025 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Jan 31 12:40:35 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=98e96f3c

net-libs/qxmpp: add 1.9.3, use qt6

Closes: https://bugs.gentoo.org/914916
Closes: https://bugs.gentoo.org/947725
Closes: https://bugs.gentoo.org/647294
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 net-libs/qxmpp/Manifest           |  1 +
 net-libs/qxmpp/qxmpp-1.9.3.ebuild | 54 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 55 insertions(+)

diff --git a/net-libs/qxmpp/Manifest b/net-libs/qxmpp/Manifest
index 10cdd928d23a..8ef16de17d83 100644
--- a/net-libs/qxmpp/Manifest
+++ b/net-libs/qxmpp/Manifest
@@ -1 +1,2 @@
 DIST qxmpp-1.5.5.tar.gz 606405 BLAKE2B 999dfcaa601f1d79df97febcd63bfcdcce87de9c0e68db6c1253407c89414003f326011a9a5e366031f78ddae084d06f04851ab3f4573ee53c59567770ae0edc SHA512 39774655fdb87dc54f32f7a018d4964c9ff8e9bebedd9cc94e6ad41288bd67365eec524525de09c5a3d2ea274e418fc6d5497ac2c1927946154cadaf7fc0d655
+DIST qxmpp-1.9.3.tar.gz 725634 BLAKE2B 1212596e53ccf92bc83d9676a2e8e6c773b92e40cfa71daccb52da647245a8b0ddef5789c6a1586089fac9aab0560f70853d7db3f570291b0718e0f6f8c3ba09 SHA512 80a81c9d13c8155fc1d219f52c38d0370192acf51f2ebcff52c7ecd1d342e60e188d5eb19a7bc961f9e3bc5aeea77ecc1efd2bbe59e36988954c18bb210285cd

diff --git a/net-libs/qxmpp/qxmpp-1.9.3.ebuild b/net-libs/qxmpp/qxmpp-1.9.3.ebuild
new file mode 100644
index 000000000000..e847bd3c9cc5
--- /dev/null
+++ b/net-libs/qxmpp/qxmpp-1.9.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="A cross-platform C++ XMPP client library based on the Qt framework"
+HOMEPAGE="https://github.com/qxmpp-project/qxmpp"
+SRC_URI="https://github.com/${PN}-project/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1 CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc gstreamer omemo test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qtbase:6[network,ssl,xml]
+	dev-qt/qt5compat:6
+	gstreamer? ( media-libs/gstreamer )
+	omemo? (
+		app-crypt/qca:2[qt6(+)]
+		net-libs/libomemo-c
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( app-text/doxygen )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DQT_VERSION_MAJOR=6
+		-DBUILD_DOCUMENTATION=$(usex doc)
+		-DBUILD_EXAMPLES=OFF
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_INTERNAL_TESTS=$(usex test)
+		-DBUILD_OMEMO=$(usex omemo)
+		-DWITH_QCA=$(usex omemo)
+		-DWITH_GSTREAMER=$(usex gstreamer)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# require network connection, bug #623708
+		-E "tst_(qxmpptransfermanager|qxmppiceconnection)"
+	)
+
+	cmake_src_test
+}