[gentoo-commits] repo/gentoo:master commit in: dev-ada/langkit/

["Alfredo Tupone" <tupone@gentoo.org>]

commit:     b240dfb08ac78760a7e86458c8df625962880629
Author:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 27 19:42:52 2025 +0000
Commit:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
CommitDate: Mon Jan 27 19:43:24 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b240dfb0

dev-ada/langkit: add 25.0.0

Signed-off-by: Alfredo Tupone <tupone <AT> gentoo.org>

 dev-ada/langkit/Manifest              |   1 +
 dev-ada/langkit/langkit-25.0.0.ebuild | 108 ++++++++++++++++++++++++++++++++++
 2 files changed, 109 insertions(+)

diff --git a/dev-ada/langkit/Manifest b/dev-ada/langkit/Manifest
index f8aac2b278ff..fd2f0e851f70 100644
--- a/dev-ada/langkit/Manifest
+++ b/dev-ada/langkit/Manifest
@@ -1 +1,2 @@
 DIST langkit-24.0.0.tar.gz 1282265 BLAKE2B 63aa3eb05be6ea590c3f4d0478cdfa0ee217606607c73b4c172c5b89d8a2a5d815efbf2bcd23b84548ececd11ffa1f89ebcbc5d411845b7a3834d6f7e16aa0b1 SHA512 b26a83cd7e57d8821d09e5e1aeaa2fa5837ab2f3901a006cfd49b059a3cfc98d7ea236dc39a2e24365196bd45c2124396795fd46fdaf4d7cb41aabb45ff85326
+DIST langkit-25.0.0.tar.gz 1560623 BLAKE2B ef03755397e85fde9b968dced7cf6bc72e85c21b6baef41160e527840caf32e0ea573d52f66c4b82ce9fa7e2dd0120286e06a3f3525e0acad5f9f11037be29b9 SHA512 27ffecb9b6c5568ebdba4864d9c5ef7e511718083fe087e3af60cfe8cc994b6ea7353cc745bc33395d33e169aaaf6916d991fa4941774932904df3e9b455f1dc

diff --git a/dev-ada/langkit/langkit-25.0.0.ebuild b/dev-ada/langkit/langkit-25.0.0.ebuild
new file mode 100644
index 000000000000..70ad90d9779b
--- /dev/null
+++ b/dev-ada/langkit/langkit-25.0.0.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+ADA_COMPAT=( gcc_12 gcc_13 gcc_14 )
+
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 ada multiprocessing
+
+DESCRIPTION="A Python framework to generate language parsers"
+HOMEPAGE="https://www.adacore.com/community"
+SRC_URI="https://github.com/AdaCore/${PN}/archive/refs/tags/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+shared static-libs static-pic"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	${ADA_REQUIRED_USE}
+	|| ( shared static-libs static-pic )"
+RESTRICT="test"
+
+RDEPEND="${PYTHON_DEPS}
+	${ADA_DEPS}
+	dev-ada/AdaSAT[${ADA_USEDEP},shared?,static-libs?,static-pic?]
+	dev-ada/e3-core[${PYTHON_USEDEP}]
+	dev-ada/gnatcoll-bindings:=[${ADA_USEDEP},gmp,iconv(+),shared?,static-libs?,static-pic?]
+	dev-ada/gnatcoll-core:=[${ADA_USEDEP},shared?,static-libs?,static-pic?]
+	dev-ada/prettier-ada:=[${ADA_USEDEP},shared?,static-libs?,static-pic?]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/funcy[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/mypy[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/types-docutils[${PYTHON_USEDEP}]
+	dev-python/types-gdb[${PYTHON_USEDEP}]"
+BDEPEND="${RDEPEND}"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	cd testsuite/tests
+
+	# missing gprbuild option to build libraries static/relocatable
+	rm -r {langkit_support,adalog,misc/link_two_libs} || die
+	rm -r misc/standalone || die
+
+	# other failures
+	rm -r misc/docstrings_lkt_roles || die
+}
+
+python_compile_all() {
+	build () {
+		rm -f langkit/support/obj/dev/*lexch
+		gprbuild -j$(makeopts_jobs) -p -v \
+			-XLIBRARY_TYPE=$1 -P langkit/support/langkit_support.gpr -XBUILD_MODE=dev \
+			-cargs:Ada ${ADAFLAGS} -cargs:C ${CFLAGS} || die "gprbuild failed"
+	}
+	if use shared; then
+		build relocatable
+	fi
+	if use static-libs; then
+		build static
+	fi
+	if use static-pic; then
+		build static-pic
+	fi
+	gprbuild -j$(makeopts_jobs) -p -v \
+		-P sigsegv_handler/langkit_sigsegv_handler.gpr -XBUILD_MODE=dev \
+		-cargs:Ada ${ADAFLAGS} -cargs:C ${CFLAGS} || die "gprbuild failed"
+}
+
+python_test_all() {
+	export GPR_PROJECT_PATH="${S}"/langkit/support
+	${EPYTHON} ./manage.py make --no-langkit-support || die
+	eval $(./manage.py setenv)
+	${EPYTHON} ./manage.py test -v \
+		--disable-ocaml \
+		--disable-gdb \
+		--disable-tear-up-builds \
+		--restricted-env \
+		--jobs $(makeopts_jobs) \
+		|& tee langkit.testOut
+	grep -qw FAIL langkit.testOut && die
+}
+
+python_install_all() {
+	build () {
+		gprinstall -v -P langkit/support/langkit_support.gpr -p -XBUILD_MODE=dev \
+			--prefix="${D}"/usr --build-var=LIBRARY_TYPE \
+			--build-var=LANGKIT_SUPPORT_LIBRARY_TYPE \
+			--sources-subdir=include/langkit_support \
+			-XLIBRARY_TYPE=$1 --build-name=$1 || die
+	}
+	if use static-libs; then
+		build static
+	fi
+	if use static-pic; then
+		build static-pic
+	fi
+	if use shared; then
+		build relocatable
+	fi
+	gprinstall -v -P sigsegv_handler/langkit_sigsegv_handler.gpr -p -XBUILD_MODE=dev \
+		--prefix="${D}"/usr || die
+}