[gentoo-commits] repo/gentoo:master commit in: dev-python/pypdf/

["Michał Górny" <mgorny@gentoo.org>]

commit:     8514ee7fcec5bb8522ec2ce31877297ce1960fa8
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 27 06:30:09 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jan 27 07:28:49 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8514ee7f

dev-python/pypdf: Bump to 5.2.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pypdf/Manifest           |  1 +
 dev-python/pypdf/pypdf-5.2.0.ebuild | 64 +++++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/dev-python/pypdf/Manifest b/dev-python/pypdf/Manifest
index 388af37959eb..55ad60a5de43 100644
--- a/dev-python/pypdf/Manifest
+++ b/dev-python/pypdf/Manifest
@@ -1,2 +1,3 @@
 DIST pypdf-5.1.0.gh.tar.gz 8026822 BLAKE2B 068490ced3dd97d7c08fe87620b68a7363900ea4b9875b52ea525263ba9240b9ce07f1e98c2fe13167c8f9aa58f9a4280b4eb2ef899ef54efa58a8c1ce02f38c SHA512 2c13b0622fcad1faaee41e82489d12f9f2006822487412eda6108bbec68b37bfc2e94510f29eb0f3a9af788c5d99142fd64f28ed3e464ff17dbecad0442dfd2e
+DIST pypdf-5.2.0.gh.tar.gz 8032194 BLAKE2B e7e9a3f5d4bb8ad5ae2158c3d00961f0b00fb12a04ea31649a24a3fb672367766b447c4aa84b06ecf3df8c32ea545f1efe6c52f786aabb3170d11c6e3ef3dde2 SHA512 8112dcf0fe5a2be97bbf940c417eff718a1fc7827fdacc7e2c1768263306441d422a2e3c84c83c757182cb595dc12ad17b2424284f8e0ec1697cfc37fc630492
 DIST pypdf-sample-files-8c405ece5eff12396a34a1fae3276132002e1753.gh.tar.gz 11748093 BLAKE2B c5989200893b28a3c2062bb024a5cfc6f3389dc259ec129857979fa43469e1274559612b4d555499e2c7e16cf34be07825229932bf4d147fa6d7324d043e97d5 SHA512 c9771129b7668a2fd1fa79bb859ae9213f3d60341cf1b9937ff0eaab0de9bf4c35adcb7b896e93329038dc0f3809a0c697c523f8fe41b43030b0b029a88058e3

diff --git a/dev-python/pypdf/pypdf-5.2.0.ebuild b/dev-python/pypdf/pypdf-5.2.0.ebuild
new file mode 100644
index 000000000000..e788da0bac63
--- /dev/null
+++ b/dev-python/pypdf/pypdf-5.2.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+SAMPLE_COMMIT=8c405ece5eff12396a34a1fae3276132002e1753
+DESCRIPTION="Python library to work with PDF files"
+HOMEPAGE="
+	https://pypi.org/project/pypdf/
+	https://github.com/py-pdf/pypdf/
+"
+SRC_URI="
+	https://github.com/py-pdf/pypdf/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://github.com/py-pdf/sample-files/archive/${SAMPLE_COMMIT}.tar.gz
+			-> ${PN}-sample-files-${SAMPLE_COMMIT}.gh.tar.gz
+	)
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		>=dev-python/pillow-8.0.0[jpeg,jpeg2k,tiff,zlib,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_unpack() {
+	default
+	if use test; then
+		mv "sample-files-${SAMPLE_COMMIT}"/* "${S}"/sample-files/ || die
+	fi
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on -Werror
+		# https://github.com/py-pdf/pypdf/pull/3083
+		tests/test_filters.py::test_ccitparameters
+		tests/test_generic.py::test_name_object
+		tests/test_reader.py::test_decode_permissions
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o addopts= -m "not enable_socket"
+}