[gentoo-commits] proj/kde:master commit in: kde-plasma/plasma-firewall/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     f59d4f61b583045a212b00196c97acbc7a91eb98
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 23 18:52:39 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Jan 23 18:52:39 2025 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=f59d4f61

kde-plasma/plasma-firewall: drop 6.2.90

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../plasma-firewall/plasma-firewall-6.2.90.ebuild  | 60 ----------------------
 1 file changed, 60 deletions(-)

diff --git a/kde-plasma/plasma-firewall/plasma-firewall-6.2.90.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-6.2.90.ebuild
deleted file mode 100644
index 044321085f..0000000000
--- a/kde-plasma/plasma-firewall/plasma-firewall-6.2.90.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_TEST="forceoptional"
-PYTHON_COMPAT=( python3_{10..13} )
-KFMIN=6.10.0
-QTMIN=6.8.1
-inherit ecm plasma.kde.org python-single-r1 xdg
-
-DESCRIPTION="Plasma frontend for Firewalld or UFW"
-HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
-
-LICENSE="GPL-2+"
-SLOT="6"
-KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
-IUSE="firewalld +ufw"
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
-
-DEPEND="
-	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,xml]
-	>=dev-qt/qtdeclarative-${QTMIN}:6
-	>=kde-frameworks/kauth-${KFMIN}:6
-	>=kde-frameworks/kcmutils-${KFMIN}:6
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-"
-RDEPEND="${DEPEND}
-	${PYTHON_DEPS}
-	firewalld? ( net-firewall/firewalld )
-	ufw? ( net-firewall/ufw )
-"
-BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
-
-src_prepare() {
-	ecm_src_prepare
-	# this kind of cmake magic doesn't work for us at all.
-	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
-		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
-		-DBUILD_UFW_BACKEND=$(usex ufw)
-	)
-	ecm_src_configure
-}
-
-pkg_postinst () {
-	xdg_pkg_postinst
-
-	if ! has_version sys-apps/systemd; then
-		ewarn "${PN} is not functional without sys-apps/systemd at this point."
-		ewarn "See also: https://bugs.gentoo.org/778527"
-	fi
-}