[gentoo-commits] repo/gentoo:master commit in: dev-python/pyopengl-accelerate/

["Michał Górny" <mgorny@gentoo.org>]

commit:     acb105fd38d279ca6144cfbd729f97b11da2f3e1
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 20 05:30:54 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jan 20 05:34:15 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=acb105fd

dev-python/pyopengl-accelerate: Bump to 3.1.9

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pyopengl-accelerate/Manifest            |  1 +
 .../pyopengl-accelerate-3.1.9.ebuild               | 56 ++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/dev-python/pyopengl-accelerate/Manifest b/dev-python/pyopengl-accelerate/Manifest
index 2207d15fd9f2..34069827b4da 100644
--- a/dev-python/pyopengl-accelerate/Manifest
+++ b/dev-python/pyopengl-accelerate/Manifest
@@ -1 +1,2 @@
 DIST pyopengl-release-3.1.8.gh.tar.gz 3599436 BLAKE2B 7f33345d68d66d3cc81278eaa5f54298694f41f40583ee08a1f9f677705fb4414b6b2afbcd7b9345199b5f573478bfeba050e185b6534cbb19b45cb25c241b47 SHA512 d95014a36bd889fa014043e4640ba7f319bb996cb56e5f7086ee05d39c53d3928512d52b0ce181d7c144775a4da7eff7403cada0f91f23f56a699a1b023e00e6
+DIST pyopengl_accelerate-3.1.9.tar.gz 21799 BLAKE2B cf0a69d55dd1971fcd91d147e71035e3a59c55dbbf10eb2ae6d5e8e78ac932632a4867c4762ea56be5e79afa0c25b4e3d313557e6b3e1f4fcc3553df12096fce SHA512 a6e4dc2ee88f2133e02384113fa7947f9a30bd2b0dff5905c29fe46b346ba7e61b2d4dc2d598901524f46560025026d5163f750be0a2b58864b3863fa7179fcf

diff --git a/dev-python/pyopengl-accelerate/pyopengl-accelerate-3.1.9.ebuild b/dev-python/pyopengl-accelerate/pyopengl-accelerate-3.1.9.ebuild
new file mode 100644
index 000000000000..83ad094ff1d6
--- /dev/null
+++ b/dev-python/pyopengl-accelerate/pyopengl-accelerate-3.1.9.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Accelerate module for PyOpenGL"
+HOMEPAGE="
+	https://pyopengl.sourceforge.net/
+	https://github.com/mcfletch/pyopengl/
+	https://pypi.org/project/PyOpenGL-accelerate/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="numpy"
+
+DEPEND="
+	numpy? (
+		dev-python/numpy:=[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/pyopengl[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	if ! use numpy; then
+		cat > "${T}"/numpy.py <<-EOF || die
+			raise ImportError("building numpy extension disabled")
+		EOF
+	fi
+}
+
+python_compile() {
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	cd "${T}" || die
+	epytest "${S}"/tests
+}