* [gentoo-commits] repo/gentoo:master commit in: dev-python/qscintilla/
@ 2025-01-19 13:48 Andreas Sturmlechner
0 siblings, 0 replies; 4+ messages in thread
From: Andreas Sturmlechner @ 2025-01-19 13:48 UTC (permalink / raw
To: gentoo-commits
commit: 3073e3ed8a8fb4763f692dc69415aaea94010bda
Author: Sergey Torokhov <torokhov-s-a <AT> yandex <DOT> ru>
AuthorDate: Fri Jan 17 18:47:43 2025 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Jan 19 13:47:59 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3073e3ed
dev-python/qscintilla: 2.14.1-r2, add PYTHON_COMPAT=python3_13
Signed-off-by: Sergey Torokhov <torokhov-s-a <AT> yandex.ru>
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild | 4 ++--
1 file changed, 2 insertions(+), 2 deletions(-)
diff --git a/dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild b/dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild
index 0e1a5a97c5f8..de90727fa909 100644
--- a/dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild
+++ b/dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
-PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_COMPAT=( python3_{10..13} )
inherit multibuild python-r1 qmake-utils out-of-source-utils
DESCRIPTION="Python bindings for QScintilla"
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-python/qscintilla/
@ 2025-01-28 18:57 Andreas Sturmlechner
0 siblings, 0 replies; 4+ messages in thread
From: Andreas Sturmlechner @ 2025-01-28 18:57 UTC (permalink / raw
To: gentoo-commits
commit: 225c42fac105d6bc4761d681c379afe0111c31c8
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 28 18:56:36 2025 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jan 28 18:56:36 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=225c42fa
dev-python/qscintilla: Switch IUSE +qt5/qt6 to qt5/+qt6
Majority of revdeps now requests Qt6.
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild b/dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild
index de90727fa909..0c5a43772d03 100644
--- a/dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild
+++ b/dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild
@@ -17,7 +17,7 @@ S=${WORKDIR}/${MY_P}/Python
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 ~arm64 ~ppc64 x86"
-IUSE="debug +qt5 qt6"
+IUSE="debug qt5 +qt6"
REQUIRED_USE="|| ( qt5 qt6 ) ${PYTHON_REQUIRED_USE}"
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-python/qscintilla/
@ 2025-02-19 20:17 Andreas Sturmlechner
0 siblings, 0 replies; 4+ messages in thread
From: Andreas Sturmlechner @ 2025-02-19 20:17 UTC (permalink / raw
To: gentoo-commits
commit: 7e9dd2e9e0605d270a5b4abc58dd96f32cbd0697
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 19 16:54:02 2025 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Feb 19 20:16:27 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7e9dd2e9
dev-python/qscintilla: Drop IUSE qt5, qt6; Qt6-only now
Blocking =x11-libs/qscintilla-2.14.1-r0 (no Qt6 option) in order to be
able to depend on ~x11-libs/qscintilla-${PV}:=[qt6(+)]
Bug: https://bugs.gentoo.org/948062
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
dev-python/qscintilla/qscintilla-2.14.1-r3.ebuild | 76 +++++++++++++++++++++++
1 file changed, 76 insertions(+)
diff --git a/dev-python/qscintilla/qscintilla-2.14.1-r3.ebuild b/dev-python/qscintilla/qscintilla-2.14.1-r3.ebuild
new file mode 100644
index 000000000000..43b8bd0a0a6c
--- /dev/null
+++ b/dev-python/qscintilla/qscintilla-2.14.1-r3.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit python-r1 qmake-utils out-of-source-utils
+
+DESCRIPTION="Python bindings for QScintilla"
+HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/ https://pypi.org/project/QScintilla/"
+
+MY_PN=QScintilla
+MY_P=${MY_PN}_src-${PV/_pre/.dev}
+SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${MY_PN}/${PV}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}/Python
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 ~ppc64 x86"
+IUSE="debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# no tests
+RESTRICT="test"
+
+DEPEND="${PYTHON_DEPS}
+ dev-python/pyqt6[gui,printsupport,widgets,${PYTHON_USEDEP}]
+ dev-qt/qtbase:6[gui,widgets]
+ ~x11-libs/qscintilla-${PV}:=[qt6(+)]
+"
+RDEPEND="${DEPEND}
+ !=x11-libs/qscintilla-2.14.1-r0
+ >=dev-python/pyqt6-sip-13.5:=[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ >=dev-python/pyqt-builder-1.10[${PYTHON_USEDEP}]
+ >=dev-python/sip-6.2[${PYTHON_USEDEP}]
+ dev-qt/qtbase:6
+"
+
+src_prepare() {
+ default
+ mv pyproject{-qt6,}.toml || die
+}
+
+src_configure() {
+ configuration() {
+ local myconf=(
+ sip-build
+ --verbose
+ --build-dir="${BUILD_DIR}"
+ --scripts-dir="$(python_get_scriptdir)"
+ --qmake="$(qt6_get_bindir)"/qmake
+ --no-make
+ $(usev debug '--debug --qml-debug --tracing')
+ )
+ echo "${myconf[@]}"
+ "${myconf[@]}" || die
+
+ run_in_build_dir eqmake6 -recursive PyQt6-${MY_PN}.pro
+ }
+ python_foreach_impl configuration
+}
+
+src_compile() {
+ python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+ installation() {
+ emake INSTALL_ROOT="${D}" install
+ python_optimize
+ }
+ python_foreach_impl run_in_build_dir installation
+}
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-python/qscintilla/
@ 2025-02-19 20:17 Andreas Sturmlechner
0 siblings, 0 replies; 4+ messages in thread
From: Andreas Sturmlechner @ 2025-02-19 20:17 UTC (permalink / raw
To: gentoo-commits
commit: dce10b664d0cc8f8b826dc905fcb9b4c1d138fb8
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 19 16:58:45 2025 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Feb 19 20:16:27 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dce10b66
dev-python/qscintilla: drop 2.14.1-r2
Closes: https://bugs.gentoo.org/948062
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild | 112 ----------------------
1 file changed, 112 deletions(-)
diff --git a/dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild b/dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild
deleted file mode 100644
index 0c5a43772d03..000000000000
--- a/dev-python/qscintilla/qscintilla-2.14.1-r2.ebuild
+++ /dev/null
@@ -1,112 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..13} )
-inherit multibuild python-r1 qmake-utils out-of-source-utils
-
-DESCRIPTION="Python bindings for QScintilla"
-HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/ https://pypi.org/project/QScintilla/"
-
-MY_PN=QScintilla
-MY_P=${MY_PN}_src-${PV/_pre/.dev}
-SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${MY_PN}/${PV}/${MY_P}.tar.gz"
-S=${WORKDIR}/${MY_P}/Python
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="amd64 ~arm64 ~ppc64 x86"
-IUSE="debug qt5 +qt6"
-
-REQUIRED_USE="|| ( qt5 qt6 ) ${PYTHON_REQUIRED_USE}"
-
-# no tests
-RESTRICT="test"
-
-DEPEND="${PYTHON_DEPS}
- qt5? (
- >=dev-python/pyqt5-5.15.5[gui,printsupport,widgets,${PYTHON_USEDEP}]
- dev-qt/qtcore:5
- dev-qt/qtgui:5
- dev-qt/qtprintsupport:5
- dev-qt/qtwidgets:5
- )
- qt6? (
- dev-python/pyqt6[gui,printsupport,widgets,${PYTHON_USEDEP}]
- dev-qt/qtbase:6[gui,widgets]
- )
- ~x11-libs/qscintilla-${PV}:=[qt5(+)?,qt6(-)?]
-"
-RDEPEND="${DEPEND}
- qt5? ( >=dev-python/pyqt5-sip-12.9:=[${PYTHON_USEDEP}] )
- qt6? ( >=dev-python/pyqt6-sip-13.5:=[${PYTHON_USEDEP}] )
-"
-BDEPEND="
- >=dev-python/pyqt-builder-1.10[${PYTHON_USEDEP}]
- >=dev-python/sip-6.2[${PYTHON_USEDEP}]
- qt5? ( dev-qt/qtcore:5 )
- qt6? ( dev-qt/qtbase:6 )
-"
-
-pkg_setup() {
- MULTIBUILD_VARIANTS=( $(usev qt5) $(usev qt6) )
-}
-
-src_configure() {
- my_src_configure() {
- case ${MULTIBUILD_VARIANT} in
- qt5)
- configuration() {
- local myconf=(
- sip-build
- --verbose
- --build-dir="${BUILD_DIR}"
- --scripts-dir="$(python_get_scriptdir)"
- --qmake="$(qt5_get_bindir)"/qmake
- --no-make
- $(usev debug '--debug --qml-debug --tracing')
- )
- echo "${myconf[@]}"
- "${myconf[@]}" || die
-
- run_in_build_dir qmake5 -recursive ${MY_PN}.pro
- }
- mv pyproject{-${MULTIBUILD_VARIANT},}.toml || die
- python_foreach_impl configuration
- ;;
- qt6)
- configuration() {
- local myconf=(
- sip-build
- --verbose
- --build-dir="${BUILD_DIR}"
- --scripts-dir="$(python_get_scriptdir)"
- --qmake="$(qt6_get_bindir)"/qmake
- --no-make
- $(usev debug '--debug --qml-debug --tracing')
- )
- echo "${myconf[@]}"
- "${myconf[@]}" || die
-
- run_in_build_dir qmake6 -recursive ${MY_PN}.pro
- }
- mv pyproject{-${MULTIBUILD_VARIANT},}.toml || die
- python_foreach_impl configuration
- ;;
- esac
- }
- multibuild_foreach_variant my_src_configure
-}
-
-src_compile() {
- multibuild_foreach_variant python_foreach_impl run_in_build_dir default
-}
-
-src_install() {
- installation() {
- emake INSTALL_ROOT="${D}" install
- python_optimize
- }
- multibuild_foreach_variant python_foreach_impl run_in_build_dir installation
-}
^ permalink raw reply related [flat|nested] 4+ messages in thread
end of thread, other threads:[~2025-02-19 20:17 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2025-01-19 13:48 [gentoo-commits] repo/gentoo:master commit in: dev-python/qscintilla/ Andreas Sturmlechner
-- strict thread matches above, loose matches on Subject: below --
2025-01-28 18:57 Andreas Sturmlechner
2025-02-19 20:17 Andreas Sturmlechner
2025-02-19 20:17 Andreas Sturmlechner
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox