[gentoo-commits] repo/gentoo:master commit in: dev-python/python-box/

["Michał Górny" <mgorny@gentoo.org>]

commit:     a1140a2db124559b3dbfd4c65d17b934427786a0
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 17 03:49:51 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Jan 17 03:49:51 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a1140a2d

dev-python/python-box: Bump to 7.3.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/python-box/Manifest                |  1 +
 dev-python/python-box/python-box-7.3.2.ebuild | 58 +++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/python-box/Manifest b/dev-python/python-box/Manifest
index e08449a8f39e..7c1c3ccbd5a7 100644
--- a/dev-python/python-box/Manifest
+++ b/dev-python/python-box/Manifest
@@ -1,2 +1,3 @@
 DIST Box-7.3.0.gh.tar.gz 87791 BLAKE2B eba82f4fa083f2f7725547254143d86d034d1dbf0ad540eb4cef8eb387846053a44a7b7dc6b94878a124f98336cade4c6a64c89beb779e5db6008393b721ecc9 SHA512 9425dc339abac6649f9e78b279720ce191559e1629eb4451fc1a63495df1d5c64bf20a339407bbfc6f8e64d9def4accf312087958880a5300c83369ee9d6ceb4
 DIST Box-7.3.1.gh.tar.gz 88055 BLAKE2B a222af827b9774d482b335ec4854429ace81144d11622dcc55cbd648e6c550d086fc6dbcba885a882a56cc9d4d43808b0bdc65ebd641984f109b797172426c78 SHA512 cf6ddc38fad160ee651f19da5d1b24ce7e396590de490aa0874de139888128a1c673228acbe5a3a1b68deeabbe372c3be20f5b2bfc1c576bf1f827d8a042707d
+DIST Box-7.3.2.gh.tar.gz 88125 BLAKE2B c5f1fb1aa0ebad873869e401ebf74ba9dd99dde79585248f2f91c11d0f8bbf673447b2a521e209452c706e7d3fc8eee0b1e80e37f48ca5d9f7742fb9edadee5d SHA512 82baa150fbc7fbc4659b4395f6329daffc1fcfbf773112c05ba114316468e46fb0757f607a15c69ad94c5d9e0dfcfa6fed294debb70fd93063458345e7f295e4

diff --git a/dev-python/python-box/python-box-7.3.2.ebuild b/dev-python/python-box/python-box-7.3.2.ebuild
new file mode 100644
index 000000000000..fd6da46c3478
--- /dev/null
+++ b/dev-python/python-box/python-box-7.3.2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+MY_P=Box-${PV}
+DESCRIPTION="Python dictionaries with advanced dot notation access"
+HOMEPAGE="
+	https://github.com/cdgriffith/Box/
+	https://pypi.org/project/python-box/
+"
+SRC_URI="
+	https://github.com/cdgriffith/Box/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+native-extensions"
+
+RDEPEND="
+	dev-python/msgpack[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	native-extensions? (
+		dev-python/cython[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	if ! use native-extensions; then
+		# a cheap hack, extensions are auto-disabled if Cython.Build
+		# is not importable
+		> Cython.py || die
+	fi
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	rm -rf box || die
+	epytest
+}