[gentoo-commits] repo/gentoo:master commit in: app-misc/fastfetch/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     f178e7ebf895c894ba47265243e47847661f446f
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 16 08:47:12 2025 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Thu Jan 16 17:00:28 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f178e7eb

app-misc/fastfetch: add 2.34.1

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 app-misc/fastfetch/Manifest                |   1 +
 app-misc/fastfetch/fastfetch-2.34.1.ebuild | 126 +++++++++++++++++++++++++++++
 2 files changed, 127 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index fd2c74d8246d..be13c7c4d833 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,2 +1,3 @@
 DIST fastfetch-2.30.1.tar.gz 1144835 BLAKE2B f44e0d8b74f124a1978403c0af61450eae4f668c0ed8e3d56505ede715366c90ad8099ae652a9afbb1c57ed2af01a930834a53ca6e871d6ad8078ce0179970f0 SHA512 626eaea5cb4ea3c61b44d24acf836734e7a04e8a3cf78bd0c8c3d4dcaf28bc165501906f97cc1423aadf8d822539e82251b65f3089780232dc214d07ce6aba7a
 DIST fastfetch-2.33.0.tar.gz 1161845 BLAKE2B 1a31aa0b7651c27ecff34067360c136ad5c0dddac60e5bc2c4ae749194d63c49df3bc92de91e5a3249b8bcd1f640b62025a01d7f6b89b96991ad1623ca079bb5 SHA512 f9d824f908e36e3dc1b7784f2da818d764be6bbc6baa77d6b26ea6776acb5f101c4c39267fa42d1c9ae735c9889badc7b3a65170d81308de852a178e50140154
+DIST fastfetch-2.34.1.tar.gz 1168310 BLAKE2B 2b3e617cd2c7b2168ad9844ba907aa533b500cf90b19762c180555967605ed3ba83030e07893adee9ec2f30887ace3f63840fdc62cbad00c7c9d1d9bd9021952 SHA512 026b71c8d6ad5d5683ededf173d4cb2e936b3e934c7f27227fa7c5f665b9628717e90413626a4fab25fa5f5fde50cae6cdeb75621d6a2cac1ca6368c943293de

diff --git a/app-misc/fastfetch/fastfetch-2.34.1.ebuild b/app-misc/fastfetch/fastfetch-2.34.1.ebuild
new file mode 100644
index 000000000000..a6fd045ed767
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.34.1.ebuild
@@ -0,0 +1,126 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm elf gnome imagemagick opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.10.0
+	sys-apps/hwdata
+	sys-libs/zlib
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	elf? ( virtual/libelf:= )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? (
+		media-libs/libglvnd[X?]
+		X? ( x11-libs/libX11 )
+	)
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	opengl? ( X? ( x11-base/xorg-proto ) )
+	xcb? ( x11-base/xorg-proto )
+	xrandr? ( x11-base/xorg-proto )
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	chafa? ( imagemagick )
+"
+
+pkg_pretend() {
+	if use X && ! use opengl; then
+		einfo 'USE="X" adds GLX support for USE="opengl"'
+		einfo 'This build with USE="X -opengl" will not include any extra X support.'
+	fi
+}
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local glx=no
+	if use opengl && use X; then
+		glx=yes
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+		-DINSTALL_LICENSE=no
+		-DBUILD_FLASHFETCH=no
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_ELF=$(usex elf)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=${glx}
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}