From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1709793-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 528FC15813A
	for <garchives@archives.gentoo.org>; Thu, 16 Jan 2025 16:55:25 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 09366E081E;
	Thu, 16 Jan 2025 16:55:21 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 59384E0821
	for <gentoo-commits@lists.gentoo.org>; Thu, 16 Jan 2025 16:55:20 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 0995434315D
	for <gentoo-commits@lists.gentoo.org>; Thu, 16 Jan 2025 16:55:19 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id A7B2C25DB
	for <gentoo-commits@lists.gentoo.org>; Thu, 16 Jan 2025 16:55:15 +0000 (UTC)
From: "Pacho Ramos" <pacho@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Pacho Ramos" <pacho@gentoo.org>
Message-ID: <1737046287.669712a68f96d18df1d9df3e814b776b39337d30.pacho@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-crypt/gcr/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-crypt/gcr/Manifest app-crypt/gcr/gcr-4.3.0.ebuild
X-VCS-Directories: app-crypt/gcr/
X-VCS-Committer: pacho
X-VCS-Committer-Name: Pacho Ramos
X-VCS-Revision: 669712a68f96d18df1d9df3e814b776b39337d30
X-VCS-Branch: master
Date: Thu, 16 Jan 2025 16:55:15 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 00fa9a4f-0131-44d2-b4dd-c1e30289c659
X-Archives-Hash: 8c4666055153f7a11585848da5621e17

commit:     669712a68f96d18df1d9df3e814b776b39337d30
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Wed Aug 14 01:47:05 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Thu Jan 16 16:51:27 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=669712a6

app-crypt/gcr: Bump to 4.3.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/38138
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 app-crypt/gcr/Manifest         |  1 +
 app-crypt/gcr/gcr-4.3.0.ebuild | 94 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/app-crypt/gcr/Manifest b/app-crypt/gcr/Manifest
index 520f875e448e..2b8ace4defde 100644
--- a/app-crypt/gcr/Manifest
+++ b/app-crypt/gcr/Manifest
@@ -1,2 +1,3 @@
 DIST gcr-3.41.1.tar.xz 1030368 BLAKE2B 9d254b7f2ad864c45200e58b685db97c1ffbc83d29ba8cbda94d30ec565aa3dc5a2535305dc63b3264131b68ec9e48f37ac30d5ba08d0ce156f3b6091cd62dc1 SHA512 dd70d41636ede863d05824b26823a8f572902f7a9b6f09b0c70586ef0d4c046864e6956130b9231850a515a9fbfcd56faf20354c1cf8f697f005827c048a2325
 DIST gcr-4.2.1.tar.xz 719392 BLAKE2B a9134258f6daa59de4924f6bac01499d3bf87aae5e9d9ff5c69b2289ba0e82ef4c3f93a1ca7b1b007815e51e0c56f10a8abc616b31518dfa83581e8ffc5b3309 SHA512 fbb1664f6e276e35296aec46dab53ff308d031cae2f25b7d1ff5abdb56c5bd3764927d38b997d2ccbd260975f445d71619b2487327786c30b5f34d5e8865ff25
+DIST gcr-4.3.0.tar.xz 726488 BLAKE2B 9981c6d6cf1b4d7d83b1771439a2fab84360e6a1ab28d73dcbd4d6aab831e1fb69a10d3e073f8735c4842f58f2b4e189fd624b78d3007867cfc7fda767e1d15f SHA512 3f252de55e07d47a49c03b714e323ceb00d82e010fe1bb606073e3188bf8bef84359a322ed6fe843620fa5d108e825dd7e9a60136c8a0e802b8f2178aa87b164

diff --git a/app-crypt/gcr/gcr-4.3.0.ebuild b/app-crypt/gcr/gcr-4.3.0.ebuild
new file mode 100644
index 000000000000..20c2d3eddc06
--- /dev/null
+++ b/app-crypt/gcr/gcr-4.3.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gcr"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="4/gcr-4.4-gck-2.2" # subslot = soname and soversion of libgcr and libgck
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="gnutls gtk gtk-doc +introspection systemd test +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.68.0:2
+	!gnutls? ( >=dev-libs/libgcrypt-1.2.2:0= )
+	gnutls? ( >=net-libs/gnutls-3.8.5:0 )
+	>=app-crypt/p11-kit-0.19.0
+	>=app-crypt/libsecret-0.20
+	systemd? ( sys-apps/systemd:= )
+	gtk? ( gui-libs/gtk:4[introspection?] )
+	>=sys-apps/dbus-1
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+	!<app-crypt/gcr-3.41.1-r1
+"
+RDEPEND="${DEPEND}"
+PDEPEND="app-crypt/gnupg"
+BDEPEND="
+	gtk? ( dev-libs/libxml2:2 )
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	test? ( app-crypt/gnupg )
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	filter-lto # https://gitlab.gnome.org/GNOME/gcr/-/issues/43
+	local emesonargs=(
+		$(meson_use introspection)
+		$(meson_use gtk gtk4)
+		$(meson_use gtk-doc gtk_doc)
+		-Dgpg_path="${EPREFIX}"/usr/bin/gpg
+		-Dssh_agent=true
+		$(meson_feature systemd)
+		$(meson_use vala vapi)
+	)
+	if use gnutls; then
+		emesonargs+=( -Dcrypto=gnutls )
+	else
+		emesonargs+=( -Dcrypto=libgcrypt )
+	fi
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/{gck-2,gcr-4} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}