[gentoo-commits] repo/gentoo:master commit in: gui-libs/gtksourceview/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     fd1c405a6a8a6ac5f2249d3483417adeefad0e2d
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 16 15:16:08 2025 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Thu Jan 16 16:51:19 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fd1c405a

gui-libs/gtksourceview: add 5.14.2

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 gui-libs/gtksourceview/Manifest                    |  1 +
 gui-libs/gtksourceview/gtksourceview-5.14.2.ebuild | 74 ++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/gui-libs/gtksourceview/Manifest b/gui-libs/gtksourceview/Manifest
index 0fc457c1606c..fd0228c7a4d6 100644
--- a/gui-libs/gtksourceview/Manifest
+++ b/gui-libs/gtksourceview/Manifest
@@ -1,2 +1,3 @@
 DIST gtksourceview-5.10.0.tar.xz 1255564 BLAKE2B a105d118716f8e61beb4bb17b8e64dacdc42f1fcfac805a9b517431a4db4da92aea82ba7b042556bc222d8a6406cbe00281c5513c6e55b7517048dae17cf83a5 SHA512 c8fb377c0f65fff35fe764c98d40a399b2f3982bfb7e25512b50f4f3c31b226d4775e136fc4be682b2e44a3b643cefd01d195c9a61f5c3ca81d15bef0093e47a
 DIST gtksourceview-5.12.1.tar.xz 1265500 BLAKE2B a9200d97cda514c62a181e3d07a0c71719710299d06e1cbc29c6b7817eb6167e7b7bdc64f32121fc54bd7093a918600c0fba70b5cb4b93906f6aaf80fd6521ed SHA512 64c347df505c640feb2d5885a3fa047a3a5dc6bf86b031ec9f8eec5544bc9d996ca3bfd41aea78ebfa9171a206a64d88773d53f1bc8d0f2171429c1ee788cd40
+DIST gtksourceview-5.14.2.tar.xz 1263508 BLAKE2B 049be85f6dca2f8209efb1ec2aa66908261b9f3e44df02734cc12f6bceca7e192f2e5773cbc71f39edb1319613ef95104407fa743c8e8512d33c00d0520a57a0 SHA512 cbdfaf3db9873302e2d38adb3fd63515b713139fb195a6135367b57f024094a6ecf581b046efbdc6417690455c88bc89b49dad4f36ec32ccddf7218ecfe87652

diff --git a/gui-libs/gtksourceview/gtksourceview-5.14.2.ebuild b/gui-libs/gtksourceview/gtksourceview-5.14.2.ebuild
new file mode 100644
index 000000000000..8fa41056cb10
--- /dev/null
+++ b/gui-libs/gtksourceview/gtksourceview-5.14.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala virtualx xdg
+
+DESCRIPTION="A text widget implementing syntax highlighting and other features"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gtksourceview"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="gtk-doc +introspection sysprof +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.72:2
+	>=gui-libs/gtk-4.6:4[introspection?]
+	>=dev-libs/libxml2-2.6:2
+	introspection? ( >=dev-libs/gobject-introspection-1.70.0:= )
+	>=dev-libs/fribidi-0.19.7
+	media-libs/fontconfig
+	x11-libs/pango[introspection?]
+	>=dev-libs/libpcre2-10.21:=[-recursion-limit(-)]
+	sysprof? ( dev-util/sysprof-capture:4 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dinstall-tests=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc documentation)
+		$(meson_use sysprof)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# Tests fail in test-regex with libpcre2[recursion-limit] - https://gitlab.gnome.org/GNOME/gtksourceview/-/issues/255
+	# Ensured OK via USE dep, as it would mean issues in real usage for syntax highlighting as well
+	virtx meson_src_test --timeout-multiplier=5
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /usr/share/${PN}-5/language-specs
+	newins "${FILESDIR}"/5-gentoo.lang gentoo.lang
+
+	if use gtk-doc ; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}